Healthplus 1.0.4

hp_reality_heal "0" - Дает реалистичное здоровье и броню.

hp_add_hp "10" - Количество предоставленного здоровья .
hp_add_armor "10" - Количество данной брони .
hp_task "1.0" - Время выполнения Health & armor.
hp_max_hp "100" - Максимальное здоровье.
hp_max_armor "100" - Максимальная броня.
hp_stay_sec "7" - Время исчезновения Модели
hp_touch_team "any" - Команды, которые могут коснуться  ( "T" , "CT", "Any" )

#pragma semicolon 1

#include <amxmodx>
#include <reapi>

enum {
    TASKID_HEALTH = 1,
    TASKID_ARMORVALUE
};

new bool:cvar_reality,
    Float:g_float_cvars[6],
    cvar_touch[4],
    HookChain:PlayerSpawn,
    modelindex,
    ScreenFade;

public plugin_init() {
    register_plugin("Healthplus", "1.0.4", "PurposeLess");

    DisableHookChain((PlayerSpawn = RegisterHookChain(RG_CBasePlayer_Spawn, "@CBasePlayer_Spawn", .post=true)));
    RegisterHookChain(RG_CBasePlayer_Killed, "@CBasePlayer_Killed", .post=true);

    new cvar_reality_f = create_cvar("hp_reality_heal", "0", .has_min = true, .min_val = 0.0, .has_max = true, .max_val = 1.0);
    bind_pcvar_num(cvar_reality_f, cvar_reality);
    hook_cvar_change(cvar_reality_f, "@hp_reality_heal");

    bind_pcvar_float(create_cvar("hp_max_hp", "100"), g_float_cvars[0]);
    bind_pcvar_float(create_cvar("hp_max_armor", "100"), g_float_cvars[1]);
    bind_pcvar_float(create_cvar("hp_add_hp", "10", .has_min = true, .min_val = 1.0), g_float_cvars[2]);
    bind_pcvar_float(create_cvar("hp_add_armor", "10", .has_min = true, .min_val = 1.0), g_float_cvars[3]);
    bind_pcvar_float(create_cvar("hp_task", "1.0"), g_float_cvars[4]);
    bind_pcvar_float(create_cvar("hp_stay_sec", "7"), g_float_cvars[5]);
    bind_pcvar_string(create_cvar("hp_touch_team", "any"), cvar_touch, charsmax(cvar_touch));

    ScreenFade = get_user_msgid("ScreenFade");
}

public plugin_precache() {
    modelindex = precache_model("models/healthplus.mdl");
}

public plugin_cfg() {
    if(cvar_reality) {
        EnableHookChain(PlayerSpawn);
    }
}

@hp_reality_heal(pcvar, const old_value[], const new_value[]) {
    if(str_to_num(new_value)) {
        EnableHookChain(PlayerSpawn);
    }
    else {
        DisableHookChain(PlayerSpawn);

        for(new pPlayer = 1; pPlayer <= MaxClients; pPlayer++) {
            if(is_user_alive(pPlayer)) {
                RemoveTask(pPlayer);
            }
        }
    }
}

public client_disconnected(pPlayer) {
    if(cvar_reality) {
        RemoveTask(pPlayer);
    }
}

@CBasePlayer_Spawn(const pPlayer) {
    if(cvar_reality) {
        RemoveTask(pPlayer);
    }
}

@CBasePlayer_Killed(const pVictim, pAttacker, iGib) {
    if(cvar_reality) {
        RemoveTask(pVictim);
    }

    new Float:fOrigin[3];
    get_entvar(pVictim, var_origin, fOrigin);

    CreateHealth(fOrigin);
}

CreateHealth(const Float:fOrigin[3]) {
    new pEntity = rg_create_entity("info_target");

    if(is_nullent(pEntity)) {
        server_print("NULLENT");
        return;
    }

    set_entvar(pEntity, var_origin, fOrigin);

    set_entvar(pEntity, var_modelindex, modelindex);
    set_entvar(pEntity, var_solid, SOLID_TRIGGER);
    set_entvar(pEntity, var_movetype, MOVETYPE_FLY);
    set_entvar(pEntity, var_renderfx, kRenderFxGlowShell);
    set_entvar(pEntity, var_rendercolor, {0.0,255.0,0.0});
    set_entvar(pEntity, var_renderamt, 7.0);
    set_entvar(pEntity, var_animtime, get_gametime() + 1.0);
    set_entvar(pEntity, var_framerate, 1.0);
    set_entvar(pEntity, var_sequence, 1);

    SetTouch(pEntity, "@SetTouch_Entity");
    SetThink(pEntity, "@SetThink_Entity");
    set_entvar(pEntity, var_nextthink, get_gametime() + g_float_cvars[5]);
}

@SetTouch_Entity(const pEntity, const pPlayer) {
    if(!is_user_alive(pPlayer) || !CheckPlayerTeam(pPlayer)) {
        return;
    }

    set_entvar(pEntity, var_flags, FL_KILLME);

    SetHealthArmorPub(pPlayer, "@heal_health", TASKID_HEALTH, var_health, g_float_cvars[0]);
    SetHealthArmorPub(pPlayer, "@heal_armor", TASKID_ARMORVALUE, var_armorvalue, g_float_cvars[1]);

    message_begin(MSG_ONE, ScreenFade, .player = pPlayer); {
        write_short(1<<14);
        write_short(1<<9);
        write_short(1<<11);
        write_byte(0);
        write_byte(255);
        write_byte(0);
        write_byte(35);
    }
    message_end();
}

@SetThink_Entity(const pEntity) {
    set_entvar(pEntity, var_gravity, -0.1);
    set_entvar(pEntity, var_movetype, MOVETYPE_TOSS);
    SetThink(pEntity, "@SetThink_Entity_Post");
    set_entvar(pEntity, var_nextthink, get_gametime() + 0.8);
}

@SetThink_Entity_Post(const pEntity) {
    set_entvar(pEntity, var_flags, FL_KILLME);
}

SetHealthArmorPub(const pPlayer, const taskname[], const TaskId, const EntVars:var, const Float:cvar) {
    if(!cvar) {
        return;
    }

    if(cvar_reality && !task_exists(pPlayer)) {
        set_task(g_float_cvars[4], taskname, pPlayer + TaskId, .flags = "b");
    }
    else {
        set_entvar(pPlayer, var, cvar);
    }
}

@heal_health(TaskId) {
    new id = TaskId - TASKID_HEALTH;

    new Float:health = get_entvar(id, var_health);
    health += g_float_cvars[2];

    if(health >= g_float_cvars[0]) {
        set_entvar(id, var_health, g_float_cvars[0]);
        remove_task(id + TASKID_HEALTH);
        return;
    }

    set_entvar(id, var_health, health);
}

@heal_armor(TaskId) {
    new id = TaskId - TASKID_ARMORVALUE;

    new Float:armorvalue = get_entvar(id, var_armorvalue);
    armorvalue += g_float_cvars[3];

    if(armorvalue >= g_float_cvars[1]) {
        set_entvar(id, var_armorvalue, g_float_cvars[1]);
        remove_task(id + TASKID_ARMORVALUE);
        return;
    }

    set_entvar(id, var_armorvalue, armorvalue);
}

RemoveTask(const pPlayer) {
    remove_task(pPlayer + TASKID_HEALTH);
    remove_task(pPlayer + TASKID_ARMORVALUE);
}

bool:CheckPlayerTeam(const pPlayer) {
    switch(cvar_touch[0]) {
        case 'C','c': {
            return bool:(get_member(pPlayer, m_iTeam) == TEAM_CT);
        }
        case 'T','t': {
            return bool:(get_member(pPlayer, m_iTeam) == TEAM_TERRORIST);
        }
    }
    return true;
}