SISA, это понятно, но я оставил так, как сделал автор. Маленько неправильно пост ssx прочел.
Rusich, у тебя ловится не SpawnPost, а SpawnPre.
Код:

RegisterHam( Ham_Spawn, "player", "HamSpawnPlayer" ) ;

===>
Код:

RegisterHam( Ham_Spawn, "player", "HamSpawnPlayer", 1 ) ;

Удалить:
Код:

register_clcmd( "vipmenu", "ClientCmd__OpenVipMenu" ) ;

Заменить:
Код:

public HamSpawnPlayer( iPlayer )
{
	if( ~get_user_flags( iPlayer ) & FLAG_ACCESS || !is_user_alive( iPlayer ) )
		return HAM_IGNORED ;

	set_task( 2.0, "GiveItems", iPlayer ) ;

	return HAM_IGNORED ;
}
  
public GiveItems( iPlayer )
{
	fm_give_item( iPlayer, "weapon_hegrenade" ) ;
	fm_give_item( iPlayer, "weapon_flashbang" ) ;
	fm_give_item( iPlayer, "weapon_flashbang" ) ;
	fm_give_item( iPlayer, "weapon_smokegrenade" ) ;
	fm_set_user_armor( iPlayer, 100 ) ;
}

===>
Код:

public HamSpawnPlayer( iPlayer )
{
	if( !is_user_alive( iPlayer ) || ~get_user_flags( iPlayer ) & FLAG_ACCESS )
		return HAM_IGNORED ;
	
	ClientCmd__OpenVipMenu( iPlayer ) ;

	set_task( 2.0, "GiveItems", iPlayer ) ;

	return HAM_IGNORED ;
}
  
public GiveItems( iPlayer )
{
	if(is_user_alive( iPlayer ))
	{
		fm_give_item( iPlayer, "weapon_hegrenade" ) ;
		fm_give_item( iPlayer, "weapon_flashbang" ) ;
		fm_give_item( iPlayer, "weapon_flashbang" ) ;
		fm_give_item( iPlayer, "weapon_smokegrenade" ) ;
		fm_set_user_armor( iPlayer, 100 ) ;
	}
}

energydance,
Код:

public PlayerMark(id)
{
    if(g_iEnt[id] < 1)
    {
        g_iEnt[id] = engfunc(EngFunc_CreateNamedEntity, giCachedStringInfoTarget)
        if(g_iEnt[id] > 0)
        {
            set_pev( g_iEnt[id], pev_movetype, MOVETYPE_FOLLOW)
            set_pev( g_iEnt[id], pev_aiment, id)
            engfunc( EngFunc_SetModel, g_iEnt[id], MODEL_MARK)
        }
    }
    if (g_iEnt[id] > 0)
    {
        new modelID = get_model_id(id)
        set_pev(g_iEnt[id], pev_body, modelID)
    }
}

===>
Код:

public PlayerMark(id)
{
	if(is_user_alive(id) && ~get_user_flags(id) & ADMIN_IMMUNITY)
	{
		if(g_iEnt[id] < 1)
		{
			g_iEnt[id] = engfunc(EngFunc_CreateNamedEntity, giCachedStringInfoTarget)
			if(g_iEnt[id] > 0)
			{
				set_pev( g_iEnt[id], pev_movetype, MOVETYPE_FOLLOW)
				set_pev( g_iEnt[id], pev_aiment, id)
				engfunc( EngFunc_SetModel, g_iEnt[id], MODEL_MARK)
			}
		}
		if (g_iEnt[id] > 0)
		{
			new modelID = get_model_id(id)
			set_pev(g_iEnt[id], pev_body, modelID)
		}
	}
}

Код:

//Uncomment line below if you want messages to be disabled by default (aka players have to type /inrorank to enable them)
//#define DISABLED_BY_DEFAULT
 
#include <amxmodx>
#include <csx>
 
#define MAX_PLAYERS 32
new bool:g_RestartAttempt[MAX_PLAYERS+1]
 
new g_oldrank[MAX_PLAYERS+1]
 
#if defined DISABLED_BY_DEFAULT
new bool:disabled[MAX_PLAYERS+1] = {true, ...}
#else
new bool:disabled[MAX_PLAYERS+1]
#endif
 
new inforank
 
public plugin_init() {
   register_plugin("Info Rank", "1.0", "connor")
   register_dictionary("inforank.txt")
 
   inforank = register_cvar("amx_inforank", "1")
 
   register_event("TextMsg", "eRestartAttempt", "a", "2=#Game_will_restart_in")
   register_event("ResetHUD", "eResetHUD", "be")
 
   register_clcmd("say /inforank","switchCmd", 0, "- enable/disable info rank messages")
   register_clcmd("say_team /inforank","switchCmd", 0, "- enable/disable info rank messages")
   register_clcmd("fullupdate", "fullupdateCmd")
}
 
public fullupdateCmd() {
   return PLUGIN_HANDLED_MAIN
}
 
public eRestartAttempt() {
   if(!get_pcvar_num(inforank))
      return
 
   new players[MAX_PLAYERS], num
   get_players(players, num, "a")
   for (new i; i < num; ++i)
      g_RestartAttempt[players[i]] = true
}
 
public eResetHUD(id) {
   if (g_RestartAttempt[id]) {
      g_RestartAttempt[id] = false
      return
   }
    
   if(!get_pcvar_num(inforank))
      return
 
   if(disabled[id])
      return
 
   event_player_spawn(id)
}
  
public event_player_spawn(id) {
 
   new osef[8]
   new rank = get_user_stats(id, osef, osef)
   new maxrank = get_statsnum()
    
   if(g_oldrank[id] == 0)
      g_oldrank[id] = rank
    
   new diff = g_oldrank[id] - rank
   g_oldrank[id] = rank
    
   new mess[192]
   if(diff > 0) {      
      formatex(mess, 191, "^4%L", id, "IR_GOOD", diff)
      client_print_color(id, print_team_default, mess)
   }
   else if(diff < 0) {
      formatex(mess, 191, "%L", id, "IR_BAD", abs(diff))
      client_print_color(id, print_team_red, mess)
   }
   formatex(mess, 191, "%L", id, "IR_RANK", rank, maxrank)
   client_print_color(id, print_team_grey, mess)
}
 
public switchCmd(id) {
   if(!get_pcvar_num(inforank))
      return PLUGIN_CONTINUE
 
   if(disabled[id]) {
      disabled[id] = false
      client_cmd(id, "setinfo _ir 1")
      client_print(id, print_chat, "%L", id, "IR_ENABLE")
   }
   else {
      disabled[id] = true
      client_cmd(id, "setinfo _ir 0")
      client_print(id, print_chat, "%L", id, "IR_DISABLE")
   }
   return PLUGIN_CONTINUE
}
 
public client_authorized(id) {
   new osef[8]
   g_oldrank[id] = get_user_stats(id, osef, osef)
 
   new enable[2]
   get_user_info(id, "_ir", enable, 1)
   if(!enable[0])
      return
 
   if(enable[0]=='1')
      disabled[id] = false
   else
      disabled[id] = true
}
 
public client_disconnect(id) {
   g_oldrank[id] = 0
 
#if defined DISABLED_BY_DEFAULT
   disabled[id] = true
#else
   disabled[id] = false
#endif
}

Код:

if(get_user_flags(id) & ADMIN_BAN) // Флаг доступа для паутинки. ADMIN_BAN в users.ini флаг - r
{
    if(!canusehook[id-1] && !cmd_access(id,level,cid,1))
    {
        return PLUGIN_HANDLED
    }

===>
Код:

if(get_user_flags(id) & ADMIN_BAN && get_user_weapon(id) == CSW_KNIFE) // Флаг доступа для паутинки. ADMIN_BAN в users.ini флаг - r
{
    if(!canusehook[id-1] && !cmd_access(id,level,cid,1))
    {
        return PLUGIN_HANDLED
    }

Код:

if(!is_user_connected(id) || !is_user_alive(id))
{
    remove_hook(id)
}

===>
Код:

if(!is_user_connected(id) || !is_user_alive(id) || get_user_weapon(id) != CSW_KNIFE)
{
    remove_hook(id)
}

Fluffy,
Код:

/*
* Обновление 07.05.2015
* v1.2 -
	Исправлен баг с подсветкой экрана во время ослепления. Спасибо: admir, [WPMG]PRoSToTeM@
	Добавлен квар bs_play_sound:
		0 - без звука при убийстве
		1 - со звуком при убийстве
*/

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN	"Blue Screen"
#define VERSION	"1.2"
#define AUTHOR	"Stimul"

#define is_valid_player(%1)	(1 <= %1 <= g_iMaxPlayers)

#define MAX_CLIENTS	32

#define RED	0
#define GREEN	0
#define BLUE	255
#define ALFA	75

new Float:g_fTimeGlare[MAX_CLIENTS+1];

new g_iMsgScreenFade;
new g_iMaxPlayers;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_event("ScreenFade", "EventScreenFade", "b", "4=255", "5=255", "6=255");
	
	RegisterHam(Ham_Killed, "player", "fw_PlayerKilled_Post", true);
	
	g_iMsgScreenFade = get_user_msgid("ScreenFade");
	
	g_iMaxPlayers = get_maxplayers();
}

public EventScreenFade(id)
	g_fTimeGlare[id] = read_data(1) / 4096.0 + get_gametime();

public fw_PlayerKilled_Post(victim, attacker, corpse)
{
	if(is_valid_player(attacker) && victim != attacker)
	{
		if(get_gametime() >= g_fTimeGlare[attacker])
		{
			message_begin(MSG_ONE_UNRELIABLE, g_iMsgScreenFade, _, attacker);
			write_short(1<<10);
			write_short(1<<10);
			write_short(0x0000);
			write_byte(RED);
			write_byte(GREEN);
			write_byte(BLUE);
			write_byte(ALFA);
			message_end();
		}
	}
}

Blitzz, забыл добавить регистрацию команды.

Настройки:
Код:

#define SKULL6_COST	10000

register_clcmd("say /gs", "CmdGive")

[attachment=38994:asd.sma]

Урон без зума умножается на 0.96, с зумом - 0.6, изучай квары.

С тебя полтос.

[attachment=38993:asd.sma]

dandys, удали:
Код:

register_event("HLTV", "event_newround", "a", "1=0", "2=0")

Код:

public event_newround()
{
    new iPlayers[32], iNumber
    get_players(iPlayers, iNumber)
    
    for(new i = 0; i < iNumber; i++)
    {
        new id = iPlayers[i]
        
        if(is_user_alive(id) && is_user_connected(id))
            g_had_qb[i] = 0
    }
}

Пробуй, не тестировал:
Код:

#include <amxmodx>
#include <amxmisc>
#include <engine>

#define PLUGIN	"Voice Block"
#define VERSION	"1.0a"
#define AUTHOR	"Stimul"

#define MAX_CLIENTS	32

new g_iAdmins;

new bool:g_bIsAdmin[MAX_CLIENTS+1];

public plugin_init()
	register_plugin(PLUGIN, VERSION, AUTHOR);

public client_putinserver(id)
{
	if(is_user_admin(id))
	{
		g_bIsAdmin[id] = true;
		g_iAdmins++;
		
		new iPlayers[MAX_CLIENTS], iNum;
		get_players(iPlayers, iNum, "c");
		
		for(new i; i < iNum; i++)
			set_speak(iPlayers[i], SPEAK_NORMAL);
	}
	else
	{
		g_bIsAdmin[id] = false;
		set_speak(id, g_iAdmins ? SPEAK_NORMAL : SPEAK_MUTED);
	}
}

public client_disconnect(id)
{
	if(g_bIsAdmin[id])
	{
		g_iAdmins--;
		
		if(!g_iAdmins)
		{
			new iPlayers[MAX_CLIENTS], iNum;
			get_players(iPlayers, iNum, "c");
			
			for(new i; i < iNum; i++)
				set_speak(iPlayers[i], SPEAK_MUTED);
		}
	}
}

Andrey777best, классно покупать то, что находится в свободном доступе.

cache:http://amx-x.ru/viewtopic.php?f=44&t=23751 в строку браузера.

Код:

if(g_Msg[0] == '/'),

===>
Код:

if(g_Msg[0] == '/' || equal(g_Msg, "guns"))

Код:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fakemeta>

#define PLUGIN	"Block Voice"
#define VERSION	"1.0"
#define AUTHOR	"Stimul"

#define FRAGS	1	// Сколько фрагов должен набрать игрок, чтобы можно было говорить в микрофон

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_forward(FM_Voice_SetClientListening, "fw_Voice_SetClientListening");
}

public fw_Voice_SetClientListening(receiver, sender, listen)
{
	if(is_user_connected(receiver)
	&& is_user_connected(sender)
	&& receiver != sender
	&& get_user_frags(sender) < FRAGS)
	{
		engfunc(EngFunc_SetClientListening, receiver, sender, false);
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;
}