/* AMX Mod X script.
*
* This file is provided as is (no warranties).
*
* (c) 2002-2003, OLO
* Modified by shadow
* Modified again by Bo0m!
* Modified again by Zefir!
* For use alongside with the Cerberus Plugin. :)
*
*****************************************************************************
* Changelog:
*
*
* 11 may 2009 - v1.1:
* - add cvar
*     amx_hpk_loss -> lowest average loss to be kicked


/// High/Low ping kicker
amx_hpk_ping 60
amx_hpk_min_ping 0
amx_hpk_loss 10
amx_hpk_check 8
amx_hpk_tests 5
amx_hpk_delay 60
amx_hpk_redirect_ip "193.41.218.19"
amx_hpk_low_redirect_ip ""
amx_hpk_immunity 1


*/

#pragma dynamic 1024

#include <amxmodx>
#include <amxmisc>
#include <cerberus>

new const PLUGIN[]  = "Cerberus High/Low Ping Kicker"
new const VERSION[] = "1.1"
new const AUTHOR[]  = "Zefir"

// Feel free to change this flag
#define HPK_IMMUNE ADMIN_IMMUNITY

// PCvars
new hpk_ping, hpk_max_ping, hpk_min_ping, hpk_loss, hpk_check, hpk_tests
new hpk_delay, hpk_redirect_ip, hpk_low_redirect_ip, hpk_immunity, hpk_ban_time

new g_Ping[MAX_PLAYERS + 1]
new g_Loss[MAX_PLAYERS + 1]
new g_Samples[MAX_PLAYERS + 1]
new g_PlayerCache[MAX_PLAYERS << 1]

public plugin_init() {

    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_dictionary("cerb_hpk.txt")

    hpk_ping = register_cvar("amx_hpk_ping","100")
    hpk_max_ping = register_cvar("amx_hpk_critical_ping","1000")
    hpk_min_ping = register_cvar("amx_hpk_min_ping","0")
    hpk_loss = register_cvar("amx_hpk_loss","20")
    hpk_check = register_cvar("amx_hpk_check","12")
    hpk_tests = register_cvar("amx_hpk_tests","5")
    hpk_delay = register_cvar("amx_hpk_delay","60")
    hpk_redirect_ip = register_cvar("amx_hpk_redirect_ip","")
    hpk_low_redirect_ip = register_cvar("amx_hpk_low_redirect_ip","")
    hpk_immunity = register_cvar("amx_hpk_immunity","1")
    hpk_ban_time = register_cvar("amx_hpk_ban_time","300")
}

public plugin_cfg() {
    if (get_pcvar_num(hpk_check) < 5) set_pcvar_num(hpk_check,5)
    if (get_pcvar_num(hpk_tests) < 3) set_pcvar_num(hpk_tests,3)
}

public cerb_init() {
    cerb_set_kick_info(REASON_HIGH_PING, "CERB_REASON_HIGH_PING", hpk_redirect_ip)
    cerb_set_kick_info(REASON_LOW_PING, "CERB_REASON_LOW_PING", hpk_low_redirect_ip)
    cerb_set_kick_info(REASON_HIGH_LOSS, "CERB_REASON_HIGH_LOSS", hpk_redirect_ip)
}

public client_dropped(id)
    remove_task(id)

public client_connect(id)
    checkReconnect(id)


public client_putinserver(id) {    
    g_Ping[id] = 0
    g_Samples[id] = 0

    if ( !cerb_is_user_bot(id) && !checkReconnect(id))
    {
        g_PlayerCache[cerb_get_reconnect_cache_id(id)] = 0
        new param[1]
        param[0] = id
        set_task( 15.0 , "showWarn" , id , param , 1 )
    
        if (get_pcvar_num(hpk_delay) != 0) {
            set_task( float(get_pcvar_num(hpk_delay)), "taskSetting", id, param , 1)
        }
        else {        
            set_task( float(get_pcvar_num(hpk_check)) , "checkPing" , id , param , 1 , "b" )
        }
    }
}

public showWarn(param[]) {
    if (get_pcvar_num(hpk_ping))
        client_print( param[0] ,print_chat,"[HPK] Players with ping higher than %d will be kicked!", get_pcvar_num(hpk_ping) )
    if (get_pcvar_num(hpk_max_ping))
        client_print( param[0] ,print_chat,"[HPK] Players with ping higher than %d will be kicked immediately!", get_pcvar_num(hpk_max_ping) )
    if (get_pcvar_num(hpk_min_ping))
        client_print( param[0] ,print_chat,"[HPK] Players with ping lowest than %d will be kicked!", get_pcvar_num(hpk_min_ping) )
    if (get_pcvar_num(hpk_loss))
        client_print( param[0] ,print_chat,"[HPK] Players with loss higher than %d will be kicked!", get_pcvar_num(hpk_loss) )
}

public taskSetting(param[]) {
//    new name[32]
//    get_user_name(param[0],name,31)
    set_task( float(get_pcvar_num(hpk_check)) , "checkPing" , param[0] , param , 1 , "b" )
}

public checkPing(param[]) {

    if (get_pcvar_num(hpk_tests) < 3)
        set_pcvar_num(hpk_tests, 3)

    new id = param[ 0 ]
    new i = cerb_get_reconnect_cache_id(id)

    static max_ping, critical_ping, min_ping, max_loss
    max_ping = get_pcvar_num(hpk_ping)
    critical_ping = get_pcvar_num(hpk_max_ping)
    min_ping = get_pcvar_num(hpk_min_ping)
    max_loss = get_pcvar_num(hpk_loss)

    if ( get_user_flags(id) & HPK_IMMUNE && get_pcvar_num(hpk_immunity) == 1 ) {
        remove_task(id)
        client_print(id, print_chat, "[HPK] Ping checking disabled due to immunity...")
        return PLUGIN_CONTINUE
    }

    new ping, loss

    get_user_ping(id, ping, loss)

    if (critical_ping && ping > critical_ping) {
        g_PlayerCache[i] = REASON_HIGH_PING
        cerb_kick(0, id, REASON_HIGH_PING)
        return PLUGIN_CONTINUE
    }

    g_Ping[ id ] += ping
    g_Loss[ id ] += loss
    ++g_Samples[ id ]

    if (g_Samples[ id ] > get_pcvar_num(hpk_tests)) {
        if (max_ping && g_Ping[id] / g_Samples[id] > max_ping) {
            g_PlayerCache[i] = REASON_HIGH_PING
            cerb_kick(0, id, REASON_HIGH_PING)
        }

        if (min_ping && g_Ping[id] / g_Samples[id] < min_ping) {
            g_PlayerCache[i] = REASON_LOW_PING
            cerb_kick(0, id, REASON_LOW_PING)
        }

        if (max_loss && g_Loss[id] / g_Samples[id] > max_loss) {
            g_PlayerCache[i] = REASON_HIGH_LOSS
            cerb_kick(0, id, REASON_HIGH_LOSS)
        }
    }

    return PLUGIN_CONTINUE
}

public checkReconnect(id) {
    if(!cerb_is_user_authorized(id) || !cerb_is_user_connected(id))
        return PLUGIN_CONTINUE

    new ban_time = get_pcvar_num(hpk_ban_time)
    new r_time = cerb_get_reconnect_time(id)

    if(!ban_time || cerb_is_user_bot(id) || cerb_is_user_hltv(id) || r_time < 0 || r_time > ban_time)
        return PLUGIN_CONTINUE

    new i = cerb_get_reconnect_cache_id(id)

    if (g_PlayerCache[i] == REASON_HIGH_PING
    ||  g_PlayerCache[i] == REASON_LOW_PING
    ||  g_PlayerCache[i] == REASON_HIGH_LOSS)
    {
        cerb_kick(0, id, g_PlayerCache[i])
        return PLUGIN_HANDLED
    }

    return PLUGIN_CONTINUE
}