#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >

#define MAX_CLIENTS			32

#define m_LastHitGroup			75

new g_iKillCount[ MAX_CLIENTS +1 ];

new bool: g_bszFirstBlood;

new bool: g_bszSoundsEnable[ MAX_CLIENTS +1 char ];

new const SOUNDS_KILL[ ][ ] =
{
	"soundkills/firstkill.wav",
	"soundkills/doublekill.wav",
	"soundkills/tripplekill.wav",
	"soundkills/multikill.wav",
	"soundkills/crazy.wav",
	"soundkills/rampage.wav",
	"soundkills/headshot.wav"
};

public plugin_init( )
{
	register_plugin( "", "", "" );

	register_logevent( "LogEV_RoundStart", 2, "1=Round_Start" );

	register_clcmd( "say /sounds", "Command_Sounds" );
	register_clcmd( "say_team /sounds", "Command_Sounds" );

	RegisterHam( Ham_Killed, "player", "CPlayer__Killed_Post", .Post = 1 );
}

public plugin_precache( )
{
	for( new i = 0; i < sizeof SOUNDS_KILL; i++ )
		engfunc( EngFunc_PrecacheSound, SOUNDS_KILL[ i ] );
}

public LogEV_RoundStart( )
{
	g_bszFirstBlood = true;

	for( new iPlayers = MAX_CLIENTS; iPlayers > 0; iPlayers-- )
		g_iKillCount[ iPlayers ] = 0;
}

public Command_Sounds( iPlayer )
{
	g_bszSoundsEnable{ iPlayer } = !g_bszSoundsEnable{ iPlayer };
}

public CPlayer__Killed_Post( iVictim, iAttacker, iGib )
{
	if( iVictim == iAttacker || !is_user_connected( iAttacker ) )
		return;

	if( !g_bszSoundsEnable{ iAttacker } )
		return;

	g_iKillCount[ iAttacker ]++;

	if( get_pdata_int( iVictim, m_LastHitGroup ) == HIT_HEAD )
	{
		if( g_bszFirstBlood )
		{
			client_cmd( 0, "spk %s", SOUNDS_KILL[ 0 ] );

			g_bszFirstBlood = false;
		}
		else
			client_cmd( 0, "spk %s", SOUNDS_KILL[ 6 ] );

		return;
	}

	if( g_bszFirstBlood )
	{
		client_cmd( 0, "spk %s", SOUNDS_KILL[ 0 ] );

		g_bszFirstBlood = false;
	}
	else
	{
		switch( g_iKillCount[ iAttacker ] )
		{
			case 2: client_cmd( 0, "spk %s", SOUNDS_KILL[ 1 ] );
			case 3: client_cmd( 0, "spk %s", SOUNDS_KILL[ 2 ] );
			case 4: client_cmd( 0, "spk %s", SOUNDS_KILL[ 3 ] );
			case 5: client_cmd( 0, "spk %s", SOUNDS_KILL[ 4 ] );
			case 6:
			{
				client_cmd( 0, "spk %s", SOUNDS_KILL[ 5 ] );

				g_iKillCount[ iAttacker ] = 5;
			}
		}
	}
}

public client_putinserver( iPlayer )
{
	g_bszSoundsEnable{ iPlayer } = true;

	g_iKillCount[ iPlayer ] = 0;
}