Frag game

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "And the Winner with Most Headshot Is..."
#define VERSION "1.5"
#define AUTHOR "Luqqas' alias lucas_7_94"

new g_mostheadshots[33], cvar_logs

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_event("DeathMsg", "Event_DeathMsg", "a", "3=1")
    register_event("30", "event_intermission", "a")
    
    cvar_logs = register_cvar("amx_headshots_logs", "0")
    register_cvar("Best Player Headshot", AUTHOR, FCVAR_SERVER | FCVAR_PROTECTED)
}

public client_disconnect(id)
{
    g_mostheadshots[id] = 0
}

public event_intermission()
{
    set_task(0.1, "BestHeadPlayer")
}

public BestHeadPlayer()
{
    new iPlayers[32], iNum
    get_players(iPlayers, iNum)
    
    if (!iNum)
    {
        return;
    }
    
    new iBestPlayerHeadshot = iPlayers[0]
    
    for(new i = 1, id; i < iNum; i++)
    {
        id = iPlayers[i]
        
        if (g_mostheadshots[id] > g_mostheadshots[iBestPlayerHeadshot])
        {
            iBestPlayerHeadshot = id
        }
    }
    
    static szName[32]
    get_user_name(iBestPlayerHeadshot, szName, charsmax(szName))
    
    client_print(0, print_chat, "[AMXX] Победителем этой карты стал %s, сделав (%d) хедшотов.", szName, g_mostheadshots[iBestPlayerHeadshot])
    if (get_pcvar_num(cvar_logs))
    {
        static mapname[32]
        get_mapname(mapname, sizeof mapname - 1)
        log_to_file("best_headshot.log", "Map %s | Best Player: %s | Headshot's: %d", mapname, szName, g_mostheadshots[iBestPlayerHeadshot])
    }
    //return PLUGIN_HANDLED
}

public Event_DeathMsg() // Thanks Asd' (Fraan') From the help in this code :)
{
    new iAttack = read_data(1)
    new iVictim = read_data(2)
    new iHead = read_data(3)
    
    if(iVictim && iHead)
    {
        g_mostheadshots[iAttack]++
    }
}