Исходник Statustext

#include <amxmisc>
#include <fakemeta>

new Float:gLastAimDetail[33]
new gMsgStatusText
new gMsgStatusValue
new Cmessage[64]

public plugin_init ()
{
    register_plugin ( "aim makeserver.ru", "1.0", "Eg@r4$il{" )
    gMsgStatusText = get_user_msgid ( "StatusText" )
    gMsgStatusValue = get_user_msgid ( "StatusValue" )
    register_cvar ( "amx_statustext_text", "www.makeserver.ru - Hacked by Makzz" )
    register_cvar ( "amx_statustext_enable", "1" )
    get_cvar_string ( "amx_statustext_text", Cmessage, 63 )
    if ( get_cvar_num ( "amx_statustext_enable" ) )
    {
        register_forward ( FM_PlayerPreThink, "fwdPlayerPreThink" )
    }
}

public fwdPlayerPreThink ( id )
{
    if ( is_user_alive ( id ) )
    {
        static Float:fGmTime
        fGmTime = get_gametime ()
        if ( gLastAimDetail[id] < fGmTime )
        {
            new iTgt, iBody
            get_user_aiming ( id, iTgt, iBody, 3000 )
            if ( is_user_alive ( iTgt ) )
            {
                new szMessage[256]
                if ( get_user_team ( id ) == get_user_team ( iTgt ) )
                {
                    formatex ( szMessage, 255, "Friend: %%p2 - Health: %i%s", pev ( iTgt, pev_health ), "%%" )
                }
                else
                {
                    formatex ( szMessage, 255, "Enemy: %%p2" )
                }
                message_begin ( MSG_ONE_UNRELIABLE, gMsgStatusText, _, id )
                write_byte ( 0 )
                write_string ( szMessage )
                message_end ()
                
                message_begin ( MSG_ONE_UNRELIABLE, gMsgStatusValue, _, id )
                write_byte ( 2 )
                write_short ( iTgt )
                message_end ()
            }
            else
            {
                message_begin ( MSG_ONE_UNRELIABLE, gMsgStatusText, _, id )
                write_byte ( 0 )
                write_string ( Cmessage )
                message_end ()
            }
            
            gLastAimDetail[id] = floatadd ( 0.2, fGmTime )
        }
    }
    
    return FMRES_IGNORED
}