Простейшие функции наказания

#include <amxmodx>
#include <amxmisc>
#define PLUGIN "opengl punish"
#define VERSION "0.1"
#define AUTHOR "kanagava"

forward client_opengl_detected(id) // Объявляем forward - функция которая будет вызвана дургим плагином
forward ogl32_client_cheat_detected(id, cheat) // Объявляем forward - функция которая будет вызвана дургим плагином
forward ogl32_client_protector_detected(id) // Объявляем forward - функция которая будет вызвана дургим плагином
new bool:protector[33]


public plugin_init()
	register_plugin(PLUGIN, VERSION, AUTHOR) //Регистрируем плагин


public client_opengl_detected(id) //эта функция будет вызвана при обнаружении opengl32.dll у игрока
{
	new uname[32],uip[32],usteam[32]
	
	get_user_name(id,uname,31) //Получаем имя игрока 
	get_user_authid(id,usteam,31) //Стимайди
	get_user_ip(id,uip,31,1) //Айпи
	
	client_print(0,print_chat,"Opengl Detected on Player %s",uname) //Оповещение в чат
	//server_cmd("addip 500.0 %s",uip) // Бан по айпи
	
	//Сюда вы можете вписать ваши HUD сообщения, колорчаты и прочую никому не нужную херню
}

public ogl32_client_cheat_detected(id, cheat) //эта функция будет вызвана при обнаружении чита у игрока
{
	new uname[32],uip[32],usteam[32]
	
	get_user_name(id,uname,31) //Получаем имя игрока 
	get_user_authid(id,usteam,31) //Стимайди
	get_user_ip(id,uip,31,1) //Айпи
	
	switch(cheat)
	{
		case 1: // Чит номер 1 (AIM HL1)
		{
			log_amx("AIM HL1 Detected on Player %s",uname) // запишем в лог
			client_print(0,print_chat,"AIM HL1 Detected on Player %s",uname) //Оповещение в чат
			//server_cmd("addip 500.0 %s",uip) // Бан по айпи
		}
		case 2: // Чит номер 2 (EHack)
		{
			log_amx("EHack Detected on Player %s",uname) // запишем в лог
			client_print(0,print_chat,"EHack Detected on Player %s",uname) //Оповещение в чат
			//server_cmd("addip 500.0 %s",uip) // Бан по айпи
		}
	}
	//Сюда вы можете вписать ваши HUD сообщения, колорчаты и прочую никому не нужную херню
}

public ogl32_client_protector_detected(id) //эта функция будет вызвана при обнаружении протоектора у игрока
{
	new uname[32],uip[32],usteam[32]
	
	get_user_name(id,uname,31) //Получаем имя игрока 
	get_user_authid(id,usteam,31) //Стимайди
	get_user_ip(id,uip,31,1) //Айпи
	
	client_print(0,print_chat,"Protector Detected on Player %s",uname) //Оповещение в чат
	protector[id] = true
	set_task(10.0, "slap_and_say", id, _, _, "b")
	set_task(3 * 60.0, "kick", id) // кик через 3 минуты
	//server_cmd("addip 500.0 %s",uip) // Бан по айпи
	//Сюда вы можете вписать ваши HUD сообщения, колорчаты и прочую никому не нужную херню
}

public client_connect(id)
{
	protector[id] = false
	remove_task(id)
}
public client_disconnect(id)
{
	protector[id] = false
	remove_task(id)
}

public slap_and_say(id)
{
	if(protector[id])
	{
		if(is_user_alive(id)) user_slap(id, 5, -1)
		client_print(id, print_chat, "Удалите protector.asi и protector.dll") // выведем в чат
		show_motd(id, "protector.txt", "Protector detected") // покажем мотд окно (если не заблокировано протектором)
		set_hudmessage(random_num(0,255), random_num(0,255), random_num(0,255), -1.0, 0.5, 1, 1.0, 5.0 ,0.01, 0.2,-1); // и худ покажем
		show_hudmessage(id,"Удалите protector.asi и protector.dll");
		set_hudmessage(random_num(0,255), random_num(0,255), random_num(0,255), -1.0, 0.4, 1, 1.0, 5.0 ,0.01, 0.2,-1); // или сразу 2!
		show_hudmessage(id,"Удалите protector.asi и protector.dll");
	}
	else
	{
		remove_task(id)
	}
	
	
}

public kick(id)
{
	server_cmd("kick #%d ^"Protector Detected^"", get_user_userid(id))
}

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <hamsandwich>

#define PLUGIN "protector punish"
#define VERSION "0.1"
#define AUTHOR "kanagava"

#define info "motd/protector.txt"

forward ogl32_client_protector_detected(id) // Объявляем forward - функция которая будет вызвана дургим плагином
new bool:protector[33]
new g_ScreenFade

new counter[33]


public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR) //Регистрируем плагин
	RegisterHam(Ham_Spawn, "player", "player_respawn", 1) //Регистрируем событие spawn игрока
	g_ScreenFade = get_user_msgid("ScreenFade"); 
}

public ogl32_client_protector_detected(id) //эта функция будет вызвана при обнаружении протоектора у игрока
{
	protector[id] = true
	if(is_user_alive(id)) player_respawn(id)
}

public client_connect(id)
{
	protector[id] = false
	remove_task(id)
}

public client_disconnect(id)
{
	protector[id] = false
	remove_task(id)
}

public player_respawn(id)
{
	if(protector[id])
	{
		screenfade(id)
		set_task(0.2, "show_string", id)
		counter[id] = 0
		entity_set_int(id, EV_INT_flags, entity_get_int(id, EV_INT_flags) | FL_FROZEN);
	}
}

public screenfade(id) //чей-то код с какого-то сайта...
{
    if(is_user_connected(id)) 
    { 
        message_begin(MSG_ONE, g_ScreenFade, _, id); 
        write_short(1 << 0); 
        write_short(1 << 0); 
        write_short(1 << 2); 
        write_byte(0); 
        write_byte(0); 
        write_byte(0); 
        write_byte(255); 
        message_end(); 
    } 
} 
 
public screenfade_off(id) 
{ 
    if(is_user_connected(id)) 
	{ 
        message_begin(MSG_ONE, g_ScreenFade, _, id); 
        write_short(1 << 12); 
        write_short(1 << 9); 
        write_short(1 << 0); 
        write_byte(0); 
        write_byte(0); 
        write_byte(0); 
        write_byte(0); 
        message_end(); 
    } 
}

public show_string(id)
{
	if(is_user_connected(id))
	{
		if(file_exists(info))
		{
			static str[256], len
			if(read_file(info, counter[id]++, str, 255, len))
			{
				set_hudmessage(random_num(150,255), random_num(150,255), random_num(150,255), -1.0, (0.15 * (counter[id]%5)), 0, 0.2, 5.0 ,0.2, 0.2,-1); // и худ покажем
				show_hudmessage(id,str);
				client_print(id, print_chat, str)
				//client_cmd(id, "echo %s", str)
				set_task(2.5, "show_string", id)
			}
			else
			{
				counter[id] = 0
				set_task(10.0, "kick",id)
				client_print(id, print_chat, "You will be kicked after 10 sec...")
				set_task(3.0, "screenfade_off",id)
				entity_set_int(id, EV_INT_flags, entity_get_int(id, EV_INT_flags) & ~FL_FROZEN);
			}
		}
	}
}

public kick(id)
{
	if(is_user_connected(id))
	{
		static name[32]
		get_user_name(id,name,31)
		client_print(0, print_chat,"Игрок %s наказан за протектор",name)
		server_cmd("kick #%d ^"Protector Detected^"", get_user_userid(id))
	}
}