Центр русификации модов/плагинов

#include <amxmodx>
#include <fakemeta>

#define MAX_DISTANCE 50
#define MENU_TIME 7
#define MENU_KEYS (1<<0)|(1<<1)|(1<<2)
#define BUTTON_IN_USE (1<<5)
#define TASK_ID 594753

new SOUND_MENU[] = "spk barney/thinking"
new SOUND_YES[] = "spk barney/yup"
new SOUND_NO[] = "spk barney/nope"
new SOUND_DONT[] = "spk barney/dontaskme"

new USE_SOUND[] = "common/wpn_denyselect.wav"
new WEAPON[] = "weapon_c4"

new g_stealer
new g_carrier
new bool:g_dontask
new bool:g_planting
new g_maxplayers

public plugin_init()
{
	register_plugin("Steal the Bomb", "1.4", "VEN")

	if (!engfunc(EngFunc_FindEntityByString, -1, "classname", "func_bomb_target"))
		return

	register_event("WeapPickup", "event_got_bomb", "be", "1=6")
	register_event("BarTime", "event_bar_time", "be")
	register_event("TextMsg", "clear", "bc", "2=#Game_bomb_drop")
	register_event("TextMsg", "clear", "a", "2=#Bomb_Planted")
	register_event("HLTV", "clear", "a", "1=0", "2=0")

	register_forward(FM_EmitSound, "forward_emit_sound")

	register_menucmd(register_menuid("Give the bomb?"), MENU_KEYS, "menu_give_bomb")

	g_maxplayers = get_maxplayers()
}

public forward_emit_sound(id, channel, sound[])
{
	if (id > g_maxplayers || !id || !equali(sound, USE_SOUND) || !g_carrier || g_planting || !is_user_alive(id) ||
	get_user_team(id) != 1 || !(pev(id, pev_button) & BUTTON_IN_USE) || task_exists(TASK_ID))
		return FMRES_IGNORED

	new id2, body, Float:distance = get_user_aiming(id, id2, body)
	if (id2 != g_carrier || !is_user_alive(id2) || distance > MAX_DISTANCE)
		return FMRES_IGNORED

	if (g_dontask)
	{
		client_cmd(id, SOUND_DONT)
		return FMRES_SUPERCEDE
	}

	g_stealer = id
	set_task(float(MENU_TIME), "task_bomb_drop", TASK_ID)

	client_cmd(id, SOUND_MENU)
	client_cmd(id2, SOUND_MENU)
	show_menu(id2, MENU_KEYS, "\yGive the bomb?^n^n\w1. Yes^n2. No^n3. No, don't ask me again^n", MENU_TIME)

	return FMRES_SUPERCEDE
}

public menu_give_bomb(id, key) 
{
	if (id != g_carrier || !check())
		return PLUGIN_HANDLED

	clear_task()

	switch (key)
	{
		case 0:
		{
			new stealer = g_stealer
			if (transfer())
				client_cmd(stealer, SOUND_YES)
		}
		case 1:
		{
			client_cmd(g_stealer, SOUND_NO)
		}
		case 2:
		{
			g_dontask = true
			client_cmd(g_stealer, SOUND_DONT)
		}
	}

	return PLUGIN_HANDLED
}

public task_bomb_drop()
{
	if (!g_planting && check())
		transfer()
}

bool:check()
{
	if (!is_user_alive(g_stealer) || !is_user_alive(g_carrier) || get_user_team(g_stealer) != 1)
		return false

	return true
}

bool:transfer()
{
	new stealer = g_stealer
	engclient_cmd(g_carrier, "drop", WEAPON)
	new c4 = engfunc(EngFunc_FindEntityByString, -1, "classname", WEAPON)
	if (!c4)
		return false

	new backpack = pev(c4, pev_owner)
	if (backpack <= g_maxplayers)
		return false

	new Float:origin[3]
	pev(stealer, pev_origin, origin)
	set_pev(backpack, pev_origin, origin)
	set_pev(backpack, pev_velocity, Float:{0.0, 0.0, -999999.0})

	return true
}

clear_task()
{
	if (task_exists(TASK_ID))
		remove_task(TASK_ID)
}

public event_got_bomb(id)
{
	g_carrier = id
}

public event_bar_time(id)
{
	if (id == g_carrier)
		g_planting = bool:read_data(1)
}

public clear()
{
	clear_task()
	g_stealer = 0
	g_carrier = 0
	g_dontask = false
	g_planting = false
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/