Склад маленьких плагинов

/**
*	Simple weapon menu with unique usability.
*
*	Home post:
*	  https://c-s.net.ua/forum/index.php?act=find...&pid=638283
*	
*	Last update:
*	  8/26/2014
*/

/*	Copyright 2014  Safety1st

	Weapon Menu Hardcoded is free software;
	you can redistribute it and/or modify
	it under the terms of the GNU General Public License as published by
	the Free Software Foundation; either version 2 of the License, or
	(at your option) any later version.

	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
	GNU General Public License for more details.

	You should have received a copy of the GNU General Public License
	along with this program; if not, write to the Free Software
	Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
*/

#include <amxmodx>
#include <cstrike>
#include <fun>

#define PLUGIN "Weapon Menu Hardcoded"
#define VERSION "0.6b"
#define AUTHOR "Safety1st"

enum _:ItemTypes {
	MENUITEM[80],	// the longest possible menu string without escape tokens
	WPN_ID,
	BPAMMO
}

/*------------------ EDIT ME ------------------*/

#define ACCESS_FLAG ADMIN_BAN | ADMIN_LEVEL_H  // flag 'n' by default
const giAllowedRound = 3           // round when ALL items become available

#define ITEMS_COUNT 4              // EXACTLY as rows quantity below, 8 items MAX if equipment item is enabled otherwise 9
new const ITEMS[ITEMS_COUNT][ItemTypes] = {
	// format: menu item name, weapon id to give (see amxconst.inc for constants), backpack ammo amount
	{   "AK47",   CSW_AK47, 90 },
	{   "M4A1",   CSW_M4A1, 90 },
	{   "GALIL",   CSW_GALIL, 90 },
	{   "FAMAS",   CSW_FAMAS, 90 },
	{   "M249",   CSW_M249, 200 },
	{    "AWP",    CSW_AWP, 30 },
	{ "Deagle", CSW_DEAGLE, 35 }
}

//#define CHECK_SHIELD              // uncomment this if you have shields on server
#define EQUIPMENT_ITEM "Equipment"  // comment to disable item; full pack costs $2000

/*------ NOTHING TO EDIT BELOW THIS POINT ------*/

#if defined EQUIPMENT_ITEM || defined CHECK_SHIELD
#include <fakemeta>
#include <hamsandwich>
#endif

new giCounter	// round counter

// macro; %1 - variable being modified, %2 - player id
#define CheckFlag(%1,%2)  (%1 &   (1 << (%2 & 31)))
#define SetFlag(%1,%2)    (%1 |=  (1 << (%2 & 31)))
#define ClearFlag(%1,%2)  (%1 &= ~(1 << (%2 & 31)))
new gbIsUsed	// whether menu was used or not

#define CSW_SHIELD 2
new const gszWeaponName[][] = {
	"", 	// dummy name to match weapon order
	"weapon_p228",
	"weapon_shield",	// just used an unassigned slot ;)
	"weapon_scout",
	"weapon_hegrenade",
	"weapon_xm1014",
	"weapon_c4",
	"weapon_mac10",
	"weapon_aug",
	"weapon_smokegrenade",
	"weapon_elite",
	"weapon_fiveseven",
	"weapon_ump45",
	"weapon_sg550",
	"weapon_galil",
	"weapon_famas",
	"weapon_usp",
	"weapon_glock18",
	"weapon_awp",
	"weapon_mp5navy",
	"weapon_m249",
	"weapon_m3",
	"weapon_m4a1",
	"weapon_tmp",
	"weapon_g3sg1",
	"weapon_flashbang",
	"weapon_deagle",
	"weapon_sg552",
	"weapon_ak47",
	"weapon_knife",
	"weapon_p90"
}

const PRIMARY_WEAPONS_BIT_SUM = 1<<CSW_SCOUT|1<<CSW_XM1014|1<<CSW_MAC10|1<<CSW_AUG|1<<CSW_UMP45
	|1<<CSW_SG550|1<<CSW_GALIL|1<<CSW_FAMAS|1<<CSW_AWP|1<<CSW_MP5NAVY|1<<CSW_M249|1<<CSW_M3
	|1<<CSW_M4A1|1<<CSW_TMP|1<<CSW_G3SG1|1<<CSW_SG552|1<<CSW_AK47|1<<CSW_P90

const SECONDARY_WEAPONS_BIT_SUM = 1<<CSW_P228|1<<CSW_ELITE|1<<CSW_FIVESEVEN|1<<CSW_USP|1<<CSW_GLOCK18|1<<CSW_DEAGLE

const KEY_EXIT = 10

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )

	register_clcmd( "say /weaponmenu", "MenuCommand" )

	register_event( "HLTV", "Event_NewRound", "a", "1=0", "2=0" )
	register_event( "TextMsg", "Event_NewGame", "a", "2=#Game_will_restart_in", "2=#Game_Commencing" )

	register_menucmd( register_menuid( "WeaponMenu" ), MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_7|MEN
U_KEY_8|MENU_KEY_9|MENU_KEY_0, "MenuHandler" )
}

public Event_NewRound() {
	gbIsUsed = 0
	giCounter++
}

public Event_NewGame() {
	giCounter = 0
}

public MenuCommand(id) {
	new szMenu[512] 	// it is maximum allowed menu size
	new iKeys
	new iLen = formatex( szMenu, charsmax(szMenu), "\yWeapon Menu:^n^n" )

	new iItemsDisabled
	if( !( get_user_flags(id) & ACCESS_FLAG ) || !is_user_alive(id) || CheckFlag( gbIsUsed, id ) || giCounter < giAllowedRound )
		iItemsDisabled = 1

	new i
	for( i = 0; i < sizeof ITEMS; i++ ) {
		if( iItemsDisabled )
			iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\d%d. %s^n", i + 1, ITEMS[i][MENUITEM] )
		else {
			iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\y%d. \w%s^n", i + 1, ITEMS[i][MENUITEM] )
			iKeys |= ( 1 << i )
		}
	}

#if defined EQUIPMENT_ITEM
	if( iItemsDisabled ) {
		iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\d%d. %s^n", i + 1, EQUIPMENT_ITEM )
	}
	else {
		iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\y%d. \w%s^n", i + 1, EQUIPMENT_ITEM )
		iKeys |= ( 1 << i )
	}
#endif

	formatex( szMenu[iLen], charsmax(szMenu) - iLen, "^n\y0. \wExit" )
	iKeys |=  MENU_KEY_0
	show_menu( id, iKeys, szMenu, .title = "WeaponMenu" )

	return PLUGIN_HANDLED
}

public MenuHandler( id, key ) {
	if( key == KEY_EXIT - 1 /* keys are numbered starting from 0 */ || !is_user_alive(id) )
		return PLUGIN_HANDLED

#if defined EQUIPMENT_ITEM
	const DEFAULT_ARMOR = 100
	const MAX_FLASHBANG = 2
	if( key == ITEMS_COUNT ) {
		// equipment item; used the most simple code
		cs_set_user_armor(id, DEFAULT_ARMOR, CS_ARMOR_VESTHELM )
		new weapons = pev( id, pev_weapons )
		if( ~weapons & 1<<CSW_HEGRENADE )
			give_item( id, "weapon_hegrenade" )
		if( ~weapons & 1<<CSW_SMOKEGRENADE )
			give_item( id, "weapon_smokegrenade" )
		if( ~weapons & 1<<CSW_FLASHBANG )
			give_item( id, "weapon_flashbang" )
		ExecuteHamB( Ham_GiveAmmo, id, MAX_FLASHBANG, "Flashbang", MAX_FLASHBANG )

		SetFlag( gbIsUsed, id )
		return PLUGIN_HANDLED
	}
#endif

	new iWeaponId = ITEMS[key][WPN_ID]

#if defined CHECK_SHIELD
	#if AMXX_VERSION_NUM < 183
	const m_boolsUserPrefsAndShield = 510
	const m_bHasShield = (1<<24)
	#else
	const m_bHasShield = 2043
	#endif

	new iRestoreData

	if( cs_get_user_shield(id) ) {
		if( 1<<iWeaponId & PRIMARY_WEAPONS_BIT_SUM )
			engclient_cmd( id, "drop", gszWeaponName[CSW_SHIELD] )
		else if( 1<<iWeaponId & SECONDARY_WEAPONS_BIT_SUM ) {
			// temporary set new info to be able to drop weapon
			#if AMXX_VERSION_NUM < 183
			iRestoreData = get_pdata_int( id, m_boolsUserPrefsAndShield )
			set_pdata_int( id, m_boolsUserPrefsAndShield, iRestoreData & ~m_bHasShield )
			#else
			iRestoreData = set_pdata_bool( id, m_bHasShield, false )
			#endif
		}
	}
#endif

	if( 1<<iWeaponId & SECONDARY_WEAPONS_BIT_SUM )
		DropWeapon( id, SECONDARY_WEAPONS_BIT_SUM )
	else if( 1<<iWeaponId & PRIMARY_WEAPONS_BIT_SUM )
		DropWeapon( id, PRIMARY_WEAPONS_BIT_SUM )

#if defined CHECK_SHIELD
	if( iRestoreData ) {
		#if AMXX_VERSION_NUM < 183
		set_pdata_int( id, m_boolsUserPrefsAndShield, iRestoreData | m_bHasShield )
		#else
		set_pdata_bool( id, m_bHasShield, true )
		#endif

		// due to weapon dropping we have deployed another weapon without a shield drawn ;) so redeploy it
		const m_pActiveItem = 373
		new iActiveItem = get_pdata_cbase( id, m_pActiveItem )
		if( iActiveItem )
			ExecuteHamB( Ham_Item_Deploy, iActiveItem )
	}
#endif

	give_item( id, gszWeaponName[iWeaponId] )
	cs_set_user_bpammo( id, iWeaponId, ITEMS[key][BPAMMO] )
	SetFlag( gbIsUsed, id )

	return PLUGIN_HANDLED
}

DropWeapon( id, weapons_bitsum ) {
	new iWeapons[32], iWeaponsNum, iWeaponId

	get_user_weapons( id, iWeapons, iWeaponsNum )

	for( new i = 0; i < iWeaponsNum; i++ ) {
		iWeaponId = iWeapons[i]

		if( 1<<iWeaponId & weapons_bitsum )
			engclient_cmd( id, "drop", gszWeaponName[iWeaponId] )
	}
}