Sign's Wallhack Blocker

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#define INV_CACHE   v_checkevery
#define VIS_CACHE   v_checkevery * 2 + 10
#define PRED_COEF   v_checkevery * 0.02 + 0.1

#define is_entity_in_pvs(%0,%1) engfunc(EngFunc_CheckVisibility, %0, %1)
#define is_user_flashed(%0)     get_pdata_int(%0, 518) > 200 && get_gametime() < get_pdata_float(%0, 515) + get_pdata_float(%0, 516)

new alive[33], team[33], tr_handle, p_checkevery, p_ignoreteam, v_checkevery, v_ignoreteam

new Float:offset_y[][] =
{
    {-17.0, -8.5, -8.5,-17.0},
    { 17.0,  8.5,  8.5, 17.0}
}

new Float:offset_z[][] =
{
    {-34.0,-17.0, 17.0, 34.0},
    {-17.0, -8.5, 17.0, 34.0}
}

public plugin_init()
{
    register_plugin("WH Blocker", "1.5", "Sign")

    register_forward(FM_AddToFullPack, "fw_addtofullpack")

    RegisterHam(Ham_Spawn, "player", "fw_alivehandle", 1)
    RegisterHam(Ham_Killed, "player", "fw_alivehandle", 1)

    p_checkevery = register_cvar("whb_checkevery", "1")
    p_ignoreteam = register_cvar("whb_ignoreteam", "1")
    tr_handle = create_tr2()
}

public fw_addtofullpack(es, e, ent, id, flags, player, set)
{
    if(player && id != ent && alive[id] && alive[ent] && (v_ignoreteam ? team[id] != team[ent] : true) && !is_entity_visible(id, ent, set))
    {
        forward_return(FMV_CELL, 0)

        return FMRES_SUPERCEDE
    }

    return FMRES_IGNORED
}

public fw_alivehandle(id)
{
    v_checkevery = clamp(get_pcvar_num(p_checkevery), 1, 10)
    v_ignoreteam = get_pcvar_num(p_ignoreteam)

    alive[id] = is_user_alive(id)
    team[id] = get_user_team(id)
}

public is_entity_visible(id, entity, set)
{
    static Float:p_origin[3], Float:e_origin[3], Float:v_plane[3], Float:v_temp[3], calls[33][33], cache[33][33], duck, i, j

    if(++calls[id][entity] < (cache[id][entity] ? VIS_CACHE : INV_CACHE))
    {
        return cache[id][entity]
    }

    calls[id][entity] = 0

    if(!is_entity_in_pvs(entity, set) || is_user_flashed(id))
    {
        return cache[id][entity] = 0
    }

    get_origin(id, p_origin, cache[id][entity])
    get_origin(entity, e_origin, cache[id][entity])

    xs_vec_sub(e_origin, p_origin, v_plane)
    xs_vec_normalize(v_plane, v_plane)

    pev(id, pev_v_angle, v_temp)
    angle_vector(v_temp, ANGLEVECTOR_FORWARD, v_temp)

    if(xs_vec_dot(v_plane, v_temp) < 0)
    {
        return cache[id][entity] = 0
    }

    pev(id, pev_view_ofs, v_temp)
    xs_vec_add(p_origin, v_temp, p_origin)

    pev(entity, pev_view_ofs, v_temp)
    xs_vec_add(e_origin, v_temp, v_temp)

    if(is_point_visible(p_origin, v_temp, id))
    {
        return cache[id][entity] = 1
    }

    vector_to_angle(v_plane, v_plane)
    angle_vector(v_plane, ANGLEVECTOR_RIGHT, v_plane)

    duck = !!(pev(entity, pev_button) & IN_DUCK)

    for(i = 0; i < 2; i++)
    {
        for(j = 0; j < 4; j++)
        {
            v_temp[0] = e_origin[0] + v_plane[0] * offset_y[i][j]
            v_temp[1] = e_origin[1] + v_plane[1] * offset_y[i][j]
            v_temp[2] = e_origin[2] + v_plane[2] * offset_y[i][j] + offset_z[duck][j]

            if(is_point_visible(p_origin, v_temp, id))
            {
                return cache[id][entity] = 1
            }
        }
    }

    return cache[id][entity] = 0
}

stock get_origin(id, Float:origin[3], visible)
{
    pev(id, pev_origin, origin)

    if(!visible)
    {
        static Float:velocity[3]

        pev(id, pev_velocity, velocity)

        if(velocity[0] || velocity[1] || velocity[2])
        {
            xs_vec_mul_scalar(velocity, PRED_COEF, velocity)
            xs_vec_add(origin, velocity, origin)
        }
    }
}

stock is_point_visible(Float:start[3], Float:point[3], ignore_ent)
{
    static Float:fraction

    engfunc(EngFunc_TraceLine, start, point, IGNORE_GLASS | IGNORE_MONSTERS, ignore_ent, tr_handle)
    get_tr2(tr_handle, TR_flFraction, fraction)

    return fraction == 1.0
}

public plugin_end()
{
    free_tr2(tr_handle)
}