Ping Control 0.1.5. Обновлённая версия от 01.04.2014 от trollface (Оптимизированный Ping Control ожил)

[pawn]#include <amxmodx>

#define ACCESS_LEVEL_IMMUNITY ADMIN_RESERVATION // Уровень доступа позволяющий пропускать проверку на пинг.
#define MAX_ALLOWED_PING 150 // Максимально допустимый пинг, превышение этого значения выкидывает игрока с сервера.
#define MAX_ALLOWED_LOSS 101 // Максимально допустимая потеря пакетов loss, превышение этого значения выкидывает игрока с сервера (101 = отключено по умолчанию, т.к. потеря пакетов не может быть больше 100).
#define MAX_WARNING_CHECK 3 // Количество предупреждений после которых последует наказание.
#define INTERVAL_CHECK 10.0 // Интервал между проверками, чем меньше значение, тем больше нагрузка на сервер.
#define CHECK_COUNT 3 // Количество проверок определенного игрока, после 3-х проверок игрока не будет проверять (снижаем еще максимальнее и без того итак маленькую нагрузку xD )

#pragma semicolon 1

#define MAX_PLAYERS 32
#define TASK_PING_CHECK 242984

#define BIT_VALID(%1,%2) (%1 & (1 << (%2 & 31)))
#define BIT_ADD(%1,%2) %1 |= (1 << (%2 & 31))
#define BIT_SUB(%1,%2) %1 &= ~(1 << (%2 & 31))

new g_iBitClientValid, g_iWarning[MAX_PLAYERS + 1];
new g_iMaxPlayers, g_iCountCheck[MAX_PLAYERS + 1];

public plugin_init()
{
   register_plugin("Ping Control", "0.1.5", "Freedo.m | neygomon");
   g_iMaxPlayers = get_maxplayers();
   set_task(INTERVAL_CHECK, "PingCheck", TASK_PING_CHECK, _, _, "b");
}

public client_putinserver(id)
{
   if(get_user_flags(id) & ACCESS_LEVEL_IMMUNITY || is_user_bot(id) || is_user_hltv(id)) return;
   g_iWarning[id] = 0;
   g_iCountCheck[id] = 0;
   BIT_ADD(g_iBitClientValid, id);
}

public client_disconnect(id) BIT_SUB(g_iBitClientValid, id);

public PingCheck()
{
   static i, iPing, iLoss;
   for(i=1; i <= g_iMaxPlayers; i++)
   {
      if(BIT_VALID(g_iBitClientValid, i) && get_user_ping(i, iPing, iLoss))
      {
         if(g_iCountCheck[i] < CHECK_COUNT)
         {
            if(iPing > MAX_ALLOWED_PING || iLoss > MAX_ALLOWED_LOSS)
            {
               if(++g_iWarning[i] >= MAX_WARNING_CHECK)
               {
                  //log_to_file("ping_control.log", "Ping: %d | Loss: %d", iPing, iLoss);
                  static name[32];
                  get_user_name(i, name, charsmax(name));
                  #if AMXX_VERSION_NUM < 183
                     client_print(0, print_chat, "[PingControl] %s был удален с сервера за плохое соединение!", name);
                  #else
                     client_print_color(0, 0, "^1[^4PingControl^1] ^3%s ^1был удален с сервера за плохое соединение!", name);
                  #endif
                  server_cmd("kick #%d ^"Вы были кикнуты из-за плохого соединения^"", get_user_userid(i));            
                
               }
            }  
            else if(g_iWarning[i]) g_iWarning[i]--;
            g_iCountCheck[i]++;
         }  
      }
   }
}[/pawn]