Склад маленького кода

/**
*	Last update:
*	  7/15/2014
*
*	Credits:
*	- to Exolent[jNr] for menu overlapping fix
*	- to ConnorMcLeod for 'Menu Close Fix' plugin
*/

#include <amxmodx>
#include <cstrike>
#include <fakemeta>

#define PLUGIN  "Menu Obeying BuyZone sample"
#define VERSION "0.3"
#define AUTHOR  "Safety1st"

const m_iMenu = 205

#define cs_get_user_menu(%0) get_pdata_int( %0, m_iMenu )

#define MAX_PLAYERS 32
new giMenu[MAX_PLAYERS + 1]

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )

	register_clcmd( "shopmenu", "ShowMenuCmd" )
	// ...
	register_event( "StatusIcon", "CloseOpenedMenu", "b", "1=0", "2=buyzone" )
}

public ShowMenuCmd(id) {
	// check access
	// ...

	if( cs_get_user_buyzone(id) )
		ShowMenu(id)
	else
		client_print( id, print_chat, "Sorry, you are not in buyzone." )

	return PLUGIN_HANDLED
}

ShowMenu(id) {
	new iMenu = menu_create( "Shop Menu Title", "MenuHandler" )
	// ...

#if AMXX_VERSION_NUM < 183
	set_pdata_int( id, m_iMenu, 0 )
#endif
	menu_display( id, iMenu )
	giMenu[id] = iMenu
}

public client_putinserver(id) {
	giMenu[id] = -1 	// no menu
}

public MenuHandler( id, menu, item ) {
	giMenu[id] = -1

	if( item == MENU_EXIT ) {
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}

	// ...

	return PLUGIN_HANDLED
}

public CloseOpenedMenu(id) {
	const Menu_Buy		= 4
	const Menu_BuyItem	= 10
	if( Menu_Buy <= cs_get_user_menu(id) <= Menu_BuyItem ) {
		/* Player is viewing old-style buy menu. Client forces menu to close automatically
			by sending 'menuselect 10' command. Our menu if exist would be closed too.
			VGUI buy menu has id = 14 and could not overlap old-style menu.
			There is nothing to worry about. More info about menu ids is here:
			  forums.alliedmods.net/showthread.php?t=130708 */
		return
	}

	new iOldMenu, iNewMenu
	player_menu_info( id, iOldMenu, iNewMenu )
	if( iNewMenu != -1 && iNewMenu == giMenu[id] ) {
		/* don't take into account active 'old-style' AMXX menu for safety
		   because we don't know for sure whether that menu has overlapped our menu and vice versa */
		menu_cancel(id) 	// force client to choose MENU_EXIT to destroy our menu
		show_menu( id, 0, "^n", 1 ) 	// show empty menu to hide our menu on player's screen
	}
}

/**
*	Method to change player speed for certain weapons
*
*	Credits:
*	- to Leonidddd for helping with forwards relative to setting speed
*	- to Asmodai for the idea how setting speed during freezetime and after death could be easily detected
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

/*---------------EDIT ME------------------*/
#define MAX_CLIENTS   32
#define CUSTOM_SPEED  400.0 	// 400.0 is the max possible value without changing cl_<>speed client cvars
/*----------------------------------------*/

#define PLUGIN "Set Custom Speed per Weapon (sample)"
#define VERSION "0.1b"
#define AUTHOR "Safety1st"

new giSpeed[MAX_CLIENTS + 1]

const SPEED_OFF = 0
const SPEED_ON  = 1

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )

	RegisterForwards4SettingSpeed()

	register_clcmd( "say /speed", "ToggleSpeedCmd" )
}

RegisterForwards4SettingSpeed() {
	// just for convenience (function could be easily collapsed)

	new szItemName[][] = {
		"weapon_p228",
		//"weapon_shield",	// it is not a weapon in common sense
		"weapon_scout",
		"weapon_hegrenade",
		"weapon_xm1014",
		"weapon_c4",
		"weapon_mac10",
		"weapon_aug",
		"weapon_smokegrenade",
		"weapon_elite",
		"weapon_fiveseven",
		"weapon_ump45",
		"weapon_sg550",
		"weapon_galil",
		"weapon_famas",
		"weapon_usp",
		"weapon_glock18",
		"weapon_awp",
		"weapon_mp5navy",
		"weapon_m249",
		"weapon_m3",
		"weapon_m4a1",
		"weapon_tmp",
		"weapon_g3sg1",
		"weapon_flashbang",
		"weapon_deagle",
		"weapon_sg552",
		"weapon_ak47",
		"weapon_knife",
		"weapon_p90"
	}

	for( new j; j < sizeof szItemName; j++ )
		RegisterHam( Ham_CS_Item_GetMaxSpeed, szItemName[j] , "CS_Item_GetMaxSpeed_Pre", .Post = 0 )
}

public client_putinserver(id) {
	giSpeed[id] = SPEED_OFF
}

public ToggleSpeedCmd(id) {
	giSpeed[id] ^= 1	// just 'toggle' another mode: 1 to 0 or 0 to 1

	switch( giSpeed[id] ) {
		case SPEED_ON : SetSpeed( id, CUSTOM_SPEED )
		default : {
			// reset speed back to normal (specific for current active weapon)
			const m_pActiveItem = 373
			new Float:flSpeed = 240.0	// just used the default value that CS does itself
			new iActiveItem = get_pdata_cbase( id, m_pActiveItem )
			if( iActiveItem != FM_NULLENT )
				ExecuteHamB( Ham_CS_Item_GetMaxSpeed, iActiveItem, flSpeed )
			SetSpeed( id, flSpeed )
		}
	}
}

SetSpeed( id, Float:speed ) {
	/* to prevent setting custom speed during freezetime and for observers.
	   there is no need to check for observers if custom speed could be activated by alive players only */
	#define SPEED_FREEZETIME  1.0
	#define SPEED_OBSERVER	900.0

	static Float:flSpeed
	pev( id, pev_maxspeed, flSpeed )
	switch( flSpeed ) {
		case SPEED_FREEZETIME, SPEED_OBSERVER : return
	}

	set_pev( id, pev_maxspeed, speed )
}

public CS_Item_GetMaxSpeed_Pre( weapon ) {
	const m_pPlayer = 41
	const XO_WEAPON = 4

	static iPlayer
	iPlayer = get_pdata_cbase( weapon, m_pPlayer, XO_WEAPON )

	if( giSpeed[iPlayer] ) {
		SetHamReturnFloat( CUSTOM_SPEED )
		return HAM_SUPERCEDE
	}

	return HAM_IGNORED
}

/**
*	Credits:
*	- to Leonidddd for helping with forwards relative to setting speed
*	- to Asmodai for the idea how setting speed during freezetime and after death could be easily detected
*	- to PRoSToTeM@ for method to hook Ham_CS_Player_ResetMaxSpeed on AMXX below 1.8.3-dev
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

/*---------------EDIT ME------------------*/
#define MAX_CLIENTS   32
#define CUSTOM_SPEED  400.0 	// 400.0 is the max possible value without changing cl_<>speed client cvars
/*----------------------------------------*/

#define PLUGIN "Set Custom Speed Global (sample)"
#define VERSION "0.1b"
#define AUTHOR "Leonidddd / Safety1st"

new giSpeed[MAX_CLIENTS + 1]

const SPEED_OFF = 0
const SPEED_ON  = 1

#if !defined Ham_CS_Player_ResetMaxSpeed
#define Ham_CS_Player_ResetMaxSpeed Ham_Item_PreFrame
#endif

public plugin_init() {
	register_plugin( PLUGIN, VERSION, AUTHOR )

	RegisterHam( Ham_CS_Player_ResetMaxSpeed, "player", "Fwd_Ham_ResetMaxSpeed_Post", .Post = 1 )

	register_clcmd( "say /speed", "ToggleSpeedCmd" )
}

public client_putinserver(id) {
	giSpeed[id] = SPEED_OFF
}

public ToggleSpeedCmd(id) {
	giSpeed[id] ^= 1	// just 'toggle' another mode: 1 to 0 or 0 to 1

	switch( giSpeed[id] ) {
		case SPEED_ON : SetCustomSpeed(id)
		default : {
			// reset speed back to normal (specific for current active weapon)
			ExecuteHamB( Ham_CS_Player_ResetMaxSpeed, id )
		}
	}
}

SetCustomSpeed(id) {
	// to prevent setting custom speed during freezetime and for observers
	#define SPEED_FREEZETIME  1.0
	#define SPEED_OBSERVER	900.0

	static Float:flSpeed
	pev( id, pev_maxspeed, flSpeed )
	switch( flSpeed ) {
		case SPEED_FREEZETIME, SPEED_OBSERVER : return
	}

	set_pev( id, pev_maxspeed, CUSTOM_SPEED )
}

public Fwd_Ham_ResetMaxSpeed_Post(id) {
	if( giSpeed[id] )
		SetCustomSpeed(id)

	return HAM_IGNORED
}

/**
*    Demonstration of 2 menu features: 'translation' and long items.
*/

#include <amxmodx />

#define PLUGIN "Menu Features Test"
#define VERSION "0.1"
#define AUTHOR "Safety1st"

public plugin_init() {
    register_plugin( PLUGIN, VERSION, AUTHOR )

    register_clcmd( "menu_test", "MenuCommand" )
}

public MenuCommand(id) {
    new szMenu[512]     // it is maximum allowed menu size
    new iLen = formatex( szMenu, charsmax(szMenu), "\yMenu Test:^n^n" )

    #define ITEMS 3
    static const szMenuItem[ITEMS][] = {
        "Sample bind USE key: \y+use",
        "Sample bind TEST key: \y+test",
        "Собака серая Собака белая | \wСобака серая Собака белая2 | \wСобака серая Собака белая3 | \yСобака жёлтая"
    }

    for( new i; i < sizeof szMenuItem; i++ )
        iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\y%d. \w%s^n", i + 1, szMenuItem[i] )

    const MENU_KEYS = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_7|MEN
U_KEY_8|MENU_KEY_9|MENU_KEY_0
    show_menu( id, MENU_KEYS, szMenu )

    return PLUGIN_HANDLED
}