Маленький плагин - корона на админа

Здравствуйте!
Скачал плагин, который выводит корону на админа. У игрока, которому присвоен флаг d (ADMIN_BAN), выводится корона - файл korona1.mdl.
В принципе всё работает, но в плагине есть глюк - когда с сервер покидает админ, то корона одевается следующему входящему игроку, несмотря не то, что он админом не является.

Реальный пример - на сервере 2 админа, корона одета на нас двоих - всё правильно. Но потом, второй админ выходит с сервера и заходит любой другой игрок, совсем не админ - а на нём корона!! В этот момент я проверяю командой amx_who, что админских флагов у того игрока нету - действительно нет, но корона на него выводится. И так будет пока не сменится карта.
Также если админа кикнет сервера, из-за того что он стоит AFK - тоже на следующего, случайно зашедшего игрока, оденется корона хотя он не админ!

Подскажите почему так происходит и поправьте плагин.

Код:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
  
#define PLUGIN  "SpineKoronaShield"
#define VERSION         "1.0"
#define AUTHOR  "CrAsH"
  
new iPlayerShield[33]
new const gModel[] = "models/korona1.mdl"
  
public plugin_init()
{
        register_plugin(PLUGIN, VERSION, AUTHOR)
  
        RegisterHam(Ham_Spawn, "player", "SpawnPlayer", 1)
}
  
public plugin_precache()
{
        precache_model( gModel )
}
  
public client_connect(id)
{
        iPlayerShield[id] = 0
}
  
public SpawnPlayer(id)
{
        if(!is_user_connected(id))
                return HAM_HANDLED
  
        if(!(get_user_flags(id) & ADMIN_BAN))
                return HAM_HANDLED
  
        if(!iPlayerShield[id])
        {
                iPlayerShield[id] = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))
  
                if(!pev_valid( iPlayerShield[id] ))
                        return HAM_HANDLED
  
                set_pev(iPlayerShield[id], pev_movetype, MOVETYPE_FOLLOW)
                set_pev(iPlayerShield[id], pev_aiment, id)
                set_pev(iPlayerShield[id], pev_rendermode, kRenderNormal)
                set_pev(iPlayerShield[id], pev_renderamt, 0.0)
  
                engfunc(EngFunc_SetModel, iPlayerShield[id], gModel)
        }
        return HAM_HANDLED
} 

Попробуй такой код:
Код:

public client_connect(id)
{
	if(iPlayerShield[id] && pev_valid(iPlayerShield[id]))
		engfunc(EngFunc_RemoveEntity,iPlayerShield[id])
	
	iPlayerShield[id] = 0
}

Это вместо

Код:

public client_connect(id)
{
        iPlayerShield[id] = 0
}

А строчку
iPlayerShield[id] = 0
внизу оставить или целиком функцию public client_connect(id) заменить на вашу??

Полностью замени функцию client_connect.
Вот на эту:
Код:

public client_connect(id)
{
	if(iPlayerShield[id] && pev_valid(iPlayerShield[id]))
		engfunc(EngFunc_RemoveEntity,iPlayerShield[id])
	
	iPlayerShield[id] = 0
}

Круто! Быстро вы соображаете.
Я доделал, только проверить не могу, нужно дождаться появления других админов.

Можешь скинуть саму модельку короны? Мне для теста другого плагина нужно.

Для чего каждый раз при спавне игрока выдавать ему модельку?
Я думаю лучше один раз ему выдать при входе на сервер.

на



yandex 'cs-portal' - найдется все.

С исправлением нормально работает, но луДше этот "тортик" одевать на игрока раунда.)

Вот корона http://rghost.ru/52934637

А не создаёт ли доработанный плагин дополнительную нагрузку, раз теперь в начале каждого
раунда выдаётся модель как заметил Fintok?

создает.

создание энтити не создает нагрузки, это все равно что достать оружие, которое энтити по сути, тем более для 1 админа.

Ну во первых он неправильно заметил. Там энтити создается только на первом спавне игрока.
А во вторых:

Код:

if(!is_user_connected(id))
                return HAM_HANDLED
   
if(!(get_user_flags(id) & ADMIN_BAN))
                return HAM_HANDLED

извращение
что мешает сделать одно условие?

я еще сомневаюсь что нужны эти строки

set_pev(iPlayerShield[id], pev_rendermode, kRenderNormal)
set_pev(iPlayerShield[id], pev_renderamt, 0.0)

рендеринг по сути для спрайтов нужен, или подсветки модели, но если ее нет ...

serfreeman1337, Даже если энтити создаются только на первом спавне игрока, нагрузка все равно есть, потому что используется лишний модуль hamsandwich и каждый раунд отлавливается событие спауна игрока.

Вот так я думаю лучше будет
Код:

#include <amxmodx>
#include <fakemeta>
   
#define PLUGIN 	"SpineKoronaShield"
#define VERSION	"1.0"
#define AUTHOR 	"CrAsH & Fintok!"

new const gModel[] = "models/korona1.mdl"

new iEntity[33]
   
public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
}
   
public plugin_precache()
{
	precache_model(gModel)
}

public client_putinserver(id)
{
	if(is_user_connected(id) && !is_user_hltv(id) && !is_user_bot(id))
	{
		if(get_user_flags(id) & ADMIN_BAN)
		{
			static iInfoTarget 
			iInfoTarget = engfunc(EngFunc_AllocString, "info_target")

			iEntity[id] = engfunc(EngFunc_CreateNamedEntity, iInfoTarget)

			if(pev_valid(iEntity[id]))
			{
				set_pev(iEntity[id], pev_movetype, MOVETYPE_FOLLOW)
				set_pev(iEntity[id], pev_aiment, id)
				set_pev(iEntity[id], pev_owner, id)
				engfunc(EngFunc_SetModel, iEntity[id], gModel)
			}
		}
	}
}

public client_disconnect(id)
{
	if(!is_user_hltv(id) && !is_user_bot(id))
	{
		if(pev_valid(iEntity[id]))
			engfunc(EngFunc_RemoveEntity, iEntity[id])
	}
}

Ну если на то пошло:
Код:

#include <amxmodx>
#include <fakemeta>

#define PLUGIN    "SpineKoronaShield"
#define VERSION   "1.0"
#define AUTHOR    "CrAsH & Fintok!"

new const gModel[] = "models/korona1.mdl"

new iEntity[33]

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
}

public plugin_precache()
{
	precache_model(gModel)
}

public client_putinserver(id)
{
	if(is_user_connected(id) && !is_user_hltv(id) && !is_user_bot(id))
	{
		if(get_user_flags(id) & ADMIN_BAN)
		{
			static iInfoTarget
			
			if(!iInfoTarget)
				iInfoTarget = engfunc(EngFunc_AllocString, "info_target")
			
			if(pev_valid(iEntity[id]))
				set_pev(iEntity[id],pev_rendermode,kRenderNormal)
			else{
				iEntity[id] = engfunc(EngFunc_CreateNamedEntity,iInfoTarget)
				
				set_pev(iEntity[id], pev_movetype, MOVETYPE_FOLLOW)
				set_pev(iEntity[id], pev_aiment, id)
				set_pev(iEntity[id], pev_owner, id)
				engfunc(EngFunc_SetModel, iEntity[id], gModel)
			}
		}
	}
}

public client_disconnect(id)
{
	if(!is_user_hltv(id) && !is_user_bot(id))
	{
		if(pev_valid(iEntity[id]))
			set_pev(iEntity[id],pev_rendermode,kRenderTransAlpha)
	}
}

Зачем каждый раз создавать энтить при подключении когда его можно просто спрятать?

Fintok, serfreeman1337

Вы придавили авторитетом.
Какой из последних двух исходников выбрать, я не настолько разбираюсь в скриптинге, чтобы понять различия.
Скажите какой из двух исходников оптимальнее.

да ну просто set_entity_visibility 0 или pev + Nodraw

ТС не может выбрать из 2х исходников что лучше, а ты ему советы даешь...