steam bonus

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Wellcome Steam"
#define VERSION "0.1"
#define AUTHOR "Fintok!"

// Для отключения ненужной функции закомментируйте строку ниже

#define MONEY 2500	// Авто. выдача доп. денг игроку
#define HEALTH 25	// Авто. выдача доп. жизней игроку
#define ARMOR 25	// Авто. выдача доп. брони игроку
#define GRENADE		// Авто. выдача гранат игроку

new bool: g_bRandom = false	// Выдача случайного кол-ва... (см. выше) [true = вкл. | false = выкл]

#define CheckFlag(%1,%2) (%1 & (1 << (%2 & 31)))
#define SetFlag(%1,%2) (%1 |= (1 << (%2 & 31)))
#define ClearFlag(%1,%2) (%1 &= ~(1 << (%2 & 31)))
new g_bIsSteam

#define TASK_WELLCOME 23436

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	RegisterHam(Ham_Spawn, "player", "fw_PlayerRespawn_Post", 1)
}

public client_putinserver(id)
{
	if(is_user_bot(id) || is_user_hltv(id))
		return

	is_user_steam(id) ? SetFlag(g_bIsSteam, id) : ClearFlag(g_bIsSteam, id)

	if(CheckFlag(g_bIsSteam, id))
		set_task(3.0, "WelcomeTask", id+TASK_WELLCOME)
}

public WelcomeTask(id)
{
	id -= TASK_WELLCOME

	new szName[32]
	get_user_name(id, szName, charsmax(szName))

	print_chatcolor(0, "[^3AMXX^1] Урааа! К нам зашел ^3STEAM^1 игрок!")
	print_chatcolor(0, "[^3AMXX^1] Приветствуем, ^4%s!", szName)
}

public fw_PlayerRespawn_Post(id)
{
	if(!is_user_alive(id) || !CheckFlag(g_bIsSteam, id))
		return

	give_item(id, "item_assaultsuit")
	give_item(id, "item_thighpack")

#if defined MONEY
	new money = cs_get_user_money(id)
	cs_set_user_money(id, ((money += g_bRandom ? random_num(100, 5000) : MONEY) > 16000) ? 16000 : money)
#endif

#if defined HEALTH
	new health = get_user_health(id)
	set_user_health(id, ((health += g_bRandom ? random_num(25, 100) : HEALTH) > 255) ? 255 : health)
#endif

#if defined ARMOR
	new armor = get_user_armor(id)
	set_user_armor(id, ((armor += g_bRandom ? random_num(25, 100) : ARMOR) > 255) ? 255 : armor)
#endif

#if defined GRENADE
	give_item(id, "weapon_hegrenade")
	give_item(id, "weapon_flashbang")
	give_item(id, "weapon_flashbang")
	give_item(id, "weapon_smokegrenade")
#endif
}

public client_disconnect(id)
{
	if(task_exists(id+TASK_WELLCOME))
		remove_task(id+TASK_WELLCOME)
}

stock is_user_steam(id)
{
	static dp_pointer

	if(dp_pointer || (dp_pointer = get_cvar_pointer("dp_r_id_provider")))
	{
		server_cmd("dp_clientinfo %d", id)
		server_exec()
		return (get_pcvar_num(dp_pointer) == 2) ? 1 : 0
	}
	return 0
}

stock print_chatcolor(const id, const input[], any:...)
{
	static msg[191]
	vformat(msg, charsmax(msg), input, 3)
		   
	replace_all(msg, charsmax(msg), "!g", "^4") // Green Color
	replace_all(msg, charsmax(msg), "!y", "^1") // Default Color
	replace_all(msg, charsmax(msg), "!team", "^3") // Team Color
	replace_all(msg, charsmax(msg), "!team2", "^0") // Team2 Color

	new count = 1, players[32], player

	if(id) players[0] = id; else get_players(players, count, "ch")
	{
		for(new i = 0; i < count; i++)
		{
			player = players[i]

			if(is_user_connected(player))
			{
				message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, player)
				write_byte(player)
				write_string(msg)
				message_end()
			}
		}
	}
}

   print_chatcolor(0, "[^3AMXX^1] Урааа! К нам зашел ^3STEAM^1 игрок!")
   print_chatcolor(0, "[^3AMXX^1] Приветствуем, ^4%s!", szName)