Ping Kicker New

#include <amxmodx>

#define MAX_PING 99 // Если пинг меньше этого значения, игрок не будет кикнут
//#define PUNISH_BAN // Уберите в начале строки //, чтобы метод наказания был бан
#define TIME_BAN 5 // Длительность бана за высокий пинг

#define SetBit(%0,%1) ((%0) |= (1 << (%1)))
#define ClearBit(%0,%1) ((%0) &= ~(1 << (%1)))
#define IsSetBit(%0,%1) ((%0) & (1 << (%1)))
#define InvertBit(%0,%1) ((%0) ^= (1 << (%1)))
#define IsNotSetBit(%0,%1) (~(%0) & (1 << (%1)))

new g_iMaxPlayers, g_iUsersInGame, g_bitsUserConnected;

public plugin_init()
{
    register_plugin("Ping Kicker", "0.1a", "Sanlerus");
    g_iMaxPlayers = get_maxplayers();
}

public client_putinserver(pPlayer)
{
    g_iUsersInGame++;
    SetBit(g_bitsUserConnected, pPlayer);
    if(g_iUsersInGame == g_iMaxPlayers) set_task(1.0, "CheckPlayers");
}

public client_disconnect(pPlayer)
{
    if(IsNotSetBit(g_bitsUserConnected, pPlayer)) return;
    g_iUsersInGame--;
    ClearBit(g_bitsUserConnected, pPlayer);
}

public CheckPlayers()
{
    if(g_iUsersInGame != g_iMaxPlayers) return;
    new iPlayer, iPing, iLoss, pPlayer, iMaxPing;
    for(iPlayer = 1; iPlayer <= g_iMaxPlayers; iPlayer++)
    {
        get_user_ping(iPlayer, iPing, iLoss);
        if(!iMaxPing || iMaxPing < iPing)
        {
            pPlayer = iPlayer;
            iMaxPing = iPing;
        }
    }
    if(iMaxPing > MAX_PING)
    {
        #if defined PUNISH_BAN
        server_cmd("amx_ban #%d %d ^"У Тебя самый высокий пинг^"", get_user_userid(pPlayer), TIME_BAN);
        #else
        server_cmd("kick #%d ^"У Вас самый высокий пинг %d^"", get_user_userid(pPlayer),iMaxPing);
        #endif
    }
}