[CTS] Connect to server

#include < amxmodx >

/* СООБЩЯТЬ ИГРОКАМ, ЧТО УСТАНОВЛЕН ПЛАГИН ИЛИ НЕТ? В СЛУЧАЕ ОТКАЗА ЗАКОММЕНТИРОВАТЬ */
#define SAY_INFO

/* ВЫКЛЮЧИТЬ МЕНЮ У СТИМ? */
//#define STEAM_MENU_OFF

/* ПРЕФИКСЫ В ЧАТЕ И В МЕНЮ */
new const g_Prefix [ ][ ] =
{
	"\d[ CS-5.RU ]\r",
	"!g[!t CS-5.RU !g]!y"
};

/* НАЗВАНИЯ НАШИХ СЕРВЕРОВ */
new const g_ServerList [ ][ ] = 
{
	"\wМаксимальный \r[ Public ]",
	"\wМаксимальный \r[ Deathrun ]",
	"\wМаксимальный \r[ Surf ]",
	"\wМаксимальный \r[ JailBreak ]"
};

/* IP АДРЕСА НАШИХ СЕРВЕРОВ */
new const g_ServerIps [ ][ ] = 
{
	"193.26.217.159:27777",
	"193.26.217.159:27098",
	"193.26.217.159:27048",
	"193.26.217.159:27056"
};

public plugin_init( )
{ 
	register_plugin( "Connect to server", "1.2", "OverGame" )
	
	register_clcmd ( "server", "open_servers_list" )
	register_clcmd ( "say /server", "open_servers_list" )
	register_clcmd ( "say_team /server", "open_servers_list" )
	
#if defined SAY_INFO
	set_task ( 130.0, "print_informer", _, _, _, "b" )
#endif
}

#if defined SAY_INFO
	public print_informer ( )
	{
		ShowMsg ( 0, "%s Дорогой игрок, что бы перейти на другой сервер напишите!t /server", g_Prefix [ 1 ] )
	}
#endif

public open_servers_list ( id )
{
	
#if defined STEAM_MENU_OFF
	if ( is_user_steam ( id ) )
	{
		ShowMsg ( id, "%s Администрация запретила открытия меню у !tSTEAM!y игроков.", g_Prefix [ 1 ] )
		return PLUGIN_HANDLED
	}
#endif
	
	new s_MenuHint [ 255 ], g_Temp [ 10 ]
	formatex ( s_MenuHint, charsmax ( s_MenuHint ), "%s СПИСОК СЕРВЕРОВ^n\yВы играете на \r%s", g_Prefix [ 0 ], get_server_name ( ) )
	new menu = menu_create ( s_MenuHint, "oservers_list_hand" )
	
	for ( new i; i < sizeof ( g_ServerList ); i++ )
	{
		num_to_str ( i, g_Temp, charsmax ( g_Temp ) )
		menu_additem ( menu, g_ServerList [ i ], g_Temp, 0 )
	}
	
	menu_setprop ( menu, MPROP_BACKNAME, "Назад" )
	menu_setprop ( menu, MPROP_NEXTNAME, "Далее" )
	menu_setprop ( menu, MPROP_EXITNAME, "Выход" )
 
	menu_display ( id, menu, 0 )
	return PLUGIN_HANDLED
	
}

public oservers_list_hand ( id, menu, item )
{
	if ( item == MENU_EXIT )
	{
		menu_destroy ( menu )
		return PLUGIN_HANDLED
	}

	new s_Data [ 6 ], s_Name [ 64 ], i_Access, i_Callback
	menu_item_getinfo ( menu, item, i_Access, s_Data, charsmax ( s_Data ), s_Name, charsmax ( s_Name ), i_Callback )
	
	new key = str_to_num ( s_Data )
	
	client_cmd( id, "connect %s", g_ServerIps [ key ] )
	
	return PLUGIN_HANDLED
}

stock bool:is_user_steam ( id )
{
// Author Sh0oter
	static dp_pointer
	if ( dp_pointer || ( dp_pointer = get_cvar_pointer ( "dp_r_id_provider" ) ) )
	{
		server_cmd ( "dp_clientinfo %d", id )
		server_exec ( )
		return ( get_pcvar_num ( dp_pointer ) == 2 ) ? true : false
	}
	
	return false
}

stock ShowMsg ( const id, const input [ ], any:... )
{
	new count = 1, players [ 32 ]
	static msg [ 188 ]
	vformat ( msg, 187, input, 3 )
	
	replace_all ( msg, 187, "!g", "^4" )
	replace_all ( msg, 187, "!y", "^1" )
	replace_all ( msg, 187, "!t", "^3" )
	
	if ( id ) players [ 0 ] = id; else get_players ( players, count, "ch" )
	{
		for ( new i = 0; i < count; i++ )
		{
			if ( is_user_connected ( players [ i ] ) )
			{
				message_begin ( MSG_ONE_UNRELIABLE, get_user_msgid ( "SayText" ), _, players [ i ] )
				write_byte ( players [ i ] )
				write_string ( msg )
				message_end ( )
			}
		}
	}
}

stock get_server_name ( )
{
	new s_ServerName [ 255 ], s_ServerIp [ 33 ]
	get_user_ip ( 0, s_ServerIp, charsmax ( s_ServerIp ), 0 ) 
	
	if ( equal ( g_ServerIps[ 0 ], s_ServerIp ) )
		formatex ( s_ServerName, charsmax ( s_ServerName ), "Паблике" )
		
	else
		
	if ( equal ( g_ServerIps[ 1 ], s_ServerIp ) )
		formatex ( s_ServerName, charsmax ( s_ServerName ), "Дезране" )
		
	else
		
	if ( equal ( g_ServerIps[ 2 ], s_ServerIp ) )
		formatex ( s_ServerName, charsmax ( s_ServerName ), "Сёрфе" )
		
	else
		
	if ( equal ( g_ServerIps[ 3 ], s_ServerIp ) )
		formatex ( s_ServerName, charsmax ( s_ServerName ), "Джайле" )
		
	else
	
		formatex ( s_ServerName, charsmax ( s_ServerName ), "Неизвестно" )
		
	return s_ServerName
}