плагин запрет смены ника

Здрасте!
есть ли плагин запрещающий смену ника более стабильнее чем Block Change Name
так как сам пользуюсь данным плагином и он грузит сервер немного но висняки заметны
после его удаления все нормализуется
искал но не нашёл варианты в которых нет ничего лишнего а мне нужен только запрет смены ника полностью без всяких уведомлений и надписей
пс может есть такой кто знает помогите)
так вот есть ли плагин запрета смены ника который меньше грузит сервер?

Код:

#include <amxmodx>

new gAct[33]

public plugin_init()
{
    register_plugin("Block name change","1.0","grankee")
    register_message(get_user_msgid("SayText"), "message")
}

public client_putinserver(id)
    set_task(10.0, "changename", id)

public client_disconnect(id)
    gAct[id] = 0

public changename(id)
    gAct[id] = 1

public message()
{
    new arg[32], name[32]
    get_msg_arg_string(2, arg, 31)
    get_msg_arg_string(3, name, 31)
    
    new id = find_player("a", name)
    
    if(is_user_connected(id) && gAct[id] == 1 && containi(arg, "name")!= -1)
        return PLUGIN_HANDLED
    return PLUGIN_CONTINUE
}

public client_infochanged(id)
{
    if(is_user_connected(id) && !is_user_bot(id) && gAct[id] == 1)
    {
        new newname[32],oldname[32]
        
        get_user_info(id, "name", newname,31)
        get_user_name(id,oldname,31)
        
        if(!equali(newname, oldname))
        {
            set_user_info(id,"name",oldname)
            return PLUGIN_HANDLED
        }
    }
    return PLUGIN_CONTINUE
}

Как вариант можно попробовать этот

Код:

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.1.0"

public plugin_init()
{
	register_plugin("One Name", VERSION, "ConnorMcLeod") 
	register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged") 
}

public ClientUserInfoChanged(id)
{
	static const name[] = "name"
	static szOldName[32], szNewName[32]
	pev(id, pev_netname, szOldName, charsmax(szOldName))

	if (szOldName[0])
	{
		get_user_info(id, name, szNewName, charsmax(szNewName))

		if (!equal(szOldName, szNewName))
		{
//			log_to_file("test.txt","change nickname")
			set_user_info(id, name, szOldName)
			return FMRES_HANDLED
		}
	}

	return FMRES_IGNORED
}

Всем огромное спасибо!

а можно вариант с текстом