Советы для улучшения работы сервера!

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>

new g_Actives
new g_iError[33]
new g_iTime[33]
new g_vOrigin[33][3]

public plugin_init()
{
    register_plugin("AFK Kisked", "1.5", "Sutar")
    
    RegisterHam(Ham_TakeDamage, "player", "cmdDamage", 0)
    
    register_logevent("round_end", 2, "0=World triggered", "1=Round_End")
    register_logevent("round_start", 2, "0=World triggered", "1=Round_Start")
    
    set_task(0.9, "cmdCheckPlayer", 24287, "", 0, "b")
}

public cmdDamage(victim, inflictor, attacker, Float:dmg, damagebits)
{
    if(victim != attacker && victim > 0 && attacker > 0 && victim < 33 && attacker < 33)
        get_user_origin(victim, g_vOrigin[victim])
    return HAM_IGNORED
}

public client_connect(id)
{
    g_vOrigin[id] = {0, 0, 0}
    g_iError[id] = 0
    g_iTime[id] = 15
}

public round_start()
{
    g_Actives = 1
    
    new iPlayers[32], pNum
    get_players(iPlayers, pNum)
    
    for(new i = 0; i < pNum; i++)
        get_user_origin(iPlayers[i], g_vOrigin[iPlayers[i]])
    return PLUGIN_CONTINUE
}

public round_end()
    g_Actives = 0

public cmdCheckPlayer()
{
    if(g_Actives == 0)
        return PLUGIN_CONTINUE
    
    new iPlayers[32], pNum
    get_players(iPlayers, pNum)
    
    for(new i = 0; i < pNum; i++)
    {
        new id = iPlayers[i]
        
        if(cs_get_user_team(id) == CS_TEAM_SPECTATOR)
        {
            new percent = (get_playersnum(1) * 100) / get_maxplayers()
            if(percent >= 80)
            {
                g_iError[id]++
                
                if(g_iError[id] >= 60)
                {
                    g_iTime[id]--
                    if(g_iTime[id] <= 0)
                    {
                        new name[32]
                        get_user_name(id, name, 31)
                        client_print(0, print_chat, "Игрок %s был отсоединен от сервера. Причина: AFK.", name)
                        server_cmd("kick #%d ^"Вы отсоиденены от сервера. Причина AFK.^"", get_user_userid(id))
                    }
                }
            }
        }
        else if(is_user_alive(id))
        {
            new vOrigin[3]
            get_user_origin(id, vOrigin)
            
            if(g_vOrigin[id][0] != vOrigin[0] || g_vOrigin[id][1] != vOrigin[1])
            {
                g_vOrigin[id][0] = vOrigin[0]
                g_vOrigin[id][1] = vOrigin[1]
                g_vOrigin[id][2] = vOrigin[2]
                g_iError[id] = 0
                g_iTime[id] = 15
            }
            else
            {
                g_iError[id]++
        
                if(g_iError[id] >= 10)
                {
                    if(pev(id, pev_weapons) & (1 << CSW_C4))
                        engclient_cmd(id, "drop", "weapon_c4")
                }
                
                if(g_iError[id] >= 15)
                {
                    if(g_iTime[id] <= 15 && g_iTime[id] >= 1)
                    {
                        client_print(id, print_chat, "* Вы будете перемещены за наблюдателей через %d сек.", g_iTime[id])
                        g_iTime[id]--
                        return PLUGIN_HANDLED
                    }
                    
                    if(is_user_alive(id))
                        user_silentkill(id)
                    
                    engclient_cmd(id, "jointeam", "6")
                    
                    g_vOrigin[id] = {0, 0, 0}
                    g_iError[id] = 0
                    g_iTime[id] = 15
                    
                    new name[32]
                    get_user_name(id, name, 31)
                    client_print(0, print_chat, "Игрок %s был перемещен за наблюдателей. Причина: AFK.", name)
                }
            }
        }
    }
    return PLUGIN_CONTINUE
}