Эффект "тряски экрана"

Всем привет, в HNS моде в начале раунда CT обездвижены 5 секунд (в моем случае), я хочу чтобы при отсчете времени экран у CT трясся. Надеюсь, что у вас получится:D.
Код:

/*	
	Formatright © 2009, Jon
	
	"Hide N Seek" is free software;
	you can redistribute it and/or modify it under the terms of the
	GNU General Public License as published by the Free Software Foundation.

	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	GNU General Public License for more details.

	You should have received a copy of the GNU General Public License
	along with "Hide N Seek"; if not, write to the
	Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <hamsandwich>
#include <cstrike>
#include <fun>
#include <dhudmessage>

#define PLUGIN "Hide N Seek"
#define VERSION "4.6"
#define AUTHOR "Jon"

#define InTeam(%1) ( CS_TEAM_UNASSIGNED < cs_get_user_team(%1) < CS_TEAM_SPECTATOR )
#define MAXPLAYERS 32

enum _:iTeams
{
	TERRORIST,
	CT
}

enum _:iScrimTeams
{
	FIRST_TEAM,
	SECOND_TEAM
}

const TASK_TIMER = 23019;
const OFFSET_PRIMARYWEAPON = 116; 
const g_iKeys = MENU_KEY_1 | MENU_KEY_2;
// const m_pPlayer = 41;

new const g_szDoor[] = "func_door";
new const g_szDoorRotating[] = "func_door_rotating";
new const g_szBreakable[] = "func_breakable";

new g_pTimer;
new g_pSound;
new g_pGameName;
new g_pFadeColor;
new g_pSwitch;
new g_pSlash;
new g_pRemoveBreakables;
new g_pRemoveDoors;
new g_pPickup;
new g_pNadesBeginning;
new g_pNewNades;
new g_pNoFlash;
new g_pFootSteps;
new g_pFlashbangs;
new g_pHidersHe;
new g_pSeekersHe;
new g_pHidersSmoke;
new g_pSeekersSmoke;
new g_pBlockKill;
new g_pChooseTeam;
new g_pNoSlowDown;
new g_pScrimRounds;

new Trie:g_tEntities;

new g_iTimer;
new g_iMaxPlayers;
new g_iMsgScreenFade;
new g_iMsgSayText;
new g_iRegisterSpawn;
new g_iRoundsLost;
new g_iSlash;
new g_iFlashbangs;
new g_iScrimRounds;
new g_iScrimPoints[ iScrimTeams ];
new g_iFadeColor[ 4 ];
new g_szNadeMenu[ 64 ];

new bool:g_bStarted;
new bool:g_bAllowSlash;
new bool:g_bNadesBeginning;
new bool:g_bNoFlash;
new bool:g_bTimerSounds;
new bool:g_bNoSlowDown;
new bool:g_bSecondRound;
new bool:g_bHeGrenade[ iTeams ];
new bool:g_bSmokeGrenade[ iTeams ];
new bool:g_bThrownGrenade[ MAXPLAYERS + 1 ];

public plugin_precache( )
{
	new iEnt = create_entity( "info_map_parameters" );
	DispatchKeyValue( iEnt, "buying", "3" );
	DispatchSpawn( iEnt );
	
	iEnt = create_entity( "hostage_entity" );
	entity_set_origin( iEnt, Float:{ 0.0, 0.0, -55000.0 } );
	entity_set_size( iEnt, Float:{ -1.0, -1.0, -1.0 }, Float:{ 1.0, 1.0, 1.0 } );
	DispatchSpawn( iEnt );
	
	new const szEntities[][] =
	{
		"func_hostage_rescue", 
		"info_hostage_rescue", 
		"func_bomb_target", 
		"info_bomb_target", 
		"hostage_entity",
		"info_vip_start", 
		"func_vip_safetyzone", 
		"func_escapezone",
		"func_buyzone",
		"armoury_entity"
	}
	
	g_tEntities = TrieCreate( );
	
	for( new i = 0; i < sizeof szEntities; i++ )
	{
		TrieSetCell( g_tEntities, szEntities[ i ], i );
	}
	
	g_pRemoveDoors = register_cvar( "hns_removedoors", "1" );
	g_pRemoveBreakables = register_cvar( "hns_removebreakables", "1" );
	g_iRegisterSpawn = register_forward( FM_Spawn, "FwdSpawnPost", 1 );
}

public plugin_init( )
{
	register_plugin( PLUGIN, VERSION, AUTHOR );
	register_cvar( "hns_version", VERSION, FCVAR_SERVER | FCVAR_SPONLY );
	
	g_pTimer =  register_cvar( "hns_timer", "5" );
	g_pGameName = register_cvar( "hns_gamename", "[vk.com/loveremake]" );
	g_pSound = register_cvar( "hns_sound", "1" );
	g_pSwitch = register_cvar( "hns_switch", "4" );
	g_pSlash = register_cvar( "hns_slash", "1337" );
	g_pFadeColor = register_cvar( "hns_fadecolor", "200 133 100 50" );
	g_pNadesBeginning = register_cvar( "hns_nadesbeginning", "1" );
	g_pFootSteps = register_cvar( "hns_footsteps", "1" );
	g_pPickup = register_cvar( "hns_pickup", "0" );
	g_pNewNades = register_cvar( "hns_newnades", "0" );
	g_pNoFlash = register_cvar( "hns_noflash", "1" );
	g_pFlashbangs = register_cvar( "hns_flashbangs", "1" );
	g_pHidersHe = register_cvar( "hns_hiders_hegrenade", "0" );
	g_pHidersSmoke = register_cvar( "hns_hiders_smokegrenade", "1" );
	g_pSeekersHe = register_cvar( "hns_seekers_hegrenade", "0" );
	g_pSeekersSmoke = register_cvar( "hns_seekers_smokegrenade", "0" );
	g_pChooseTeam = register_cvar( "hns_chooseteam", "0" );
	g_pBlockKill = register_cvar( "hns_blockkill", "1" );
	g_pNoSlowDown = register_cvar( "hns_noslowdown", "0" );
	g_pScrimRounds = register_cvar( "hns_scrimrounds", "0" );
	
	g_iMaxPlayers = get_maxplayers( );
	g_iMsgScreenFade = get_user_msgid( "ScreenFade" );
	g_iMsgSayText = get_user_msgid( "SayText" );
	
	register_event( "HLTV", "EventNewRound", "a", "1=0", "2=0" );
	register_event( "SendAudio", "EventTerroristsWin", "a", "2=%!MRAD_terwin" );
	register_event( "SendAudio", "EventCTsWin", "a", "2=%!MRAD_ctwin" );
	
	register_logevent( "EventRoundStart", 2, "1=Round_Start" );
	register_logevent( "EventRoundEnd", 2, "1=Round_End" );
	
	set_msg_block( get_user_msgid( "HostagePos" ), BLOCK_SET );
	register_message( g_iMsgScreenFade, "MsgScreenFade" );
	register_message( get_user_msgid( "TextMsg" ), "MsgTextMsg" );
	
	RegisterHam( Ham_Spawn, "player", "FwdPlayerSpawnPost", 1 );
	RegisterHam( Ham_Killed, "player", "FwdPlayerKilled" );
	RegisterHam( Ham_Touch, "weaponbox", "FwdTouchWeapon" );
	RegisterHam( Ham_Item_Deploy, "weapon_knife", "FwdKnifeDeployPost", 1 );
	RegisterHam( Ham_Weapon_PrimaryAttack, "weapon_knife", "FwdKnifePrimaryAttack" );
	RegisterHam( Ham_Weapon_SecondaryAttack, "weapon_knife", "FwdKnifeSecondaryAttack" );
	RegisterHam( Ham_Think, "grenade", "FwdGrenadeThink" );
	
	unregister_forward( FM_Spawn, g_iRegisterSpawn, 1 );
	register_forward( FM_GetGameDescription, "FwdGameDescription" );
	register_forward( FM_ClientKill, "FwdClientKill" );
	
	register_clcmd( "jointeam", "CmdTeamSelect" );
	register_clcmd( "chooseteam", "CmdTeamSelect" );
	
	// - - - - - 
	
	add( g_szNadeMenu, 63, "\yNew grenades?^n^n" );
	add( g_szNadeMenu, 63, "\r1. \wYes^n" );
	add( g_szNadeMenu, 63, "\r2. \wNo" );
	
	register_menucmd( register_menuid( "NadesMenu" ), g_iKeys, "HandleNadeMenu" );
	 
	// - - - - - 
	
	server_cmd( "sv_restart 1" );
}

public plugin_end( )
{
	TrieDestroy( g_tEntities );
}

public EventNewRound()
{
	remove_task( TASK_TIMER );
	
	new szColor[ 20 ], szRed[ 4 ], szGreen[ 4 ], szBlue[ 4 ], szAlpha[ 4 ];
	get_pcvar_string( g_pFadeColor, szColor, 19 );
	parse( szColor, szRed, 4, szGreen, 4, szBlue, 4, szAlpha, 4 );
	
	g_iFadeColor[ 0 ] = str_to_num( szRed );
	g_iFadeColor[ 1 ] = str_to_num( szGreen );
	g_iFadeColor[ 2 ] = str_to_num( szBlue );
	g_iFadeColor[ 3 ] = str_to_num( szAlpha );
	g_bNadesBeginning = bool:get_pcvar_num( g_pNadesBeginning );
	g_bNoFlash = bool:get_pcvar_num( g_pNoFlash );
	g_bNoSlowDown = bool:get_pcvar_num( g_pNoSlowDown );
	g_bHeGrenade[ TERRORIST ] = bool:get_pcvar_num( g_pHidersHe );
	g_bSmokeGrenade[ TERRORIST ] = bool:get_pcvar_num( g_pHidersSmoke );
	g_iFlashbangs = get_pcvar_num( g_pFlashbangs );
	g_bHeGrenade[ CT ] = bool:get_pcvar_num( g_pSeekersHe );
	g_bSmokeGrenade[ CT ] = bool:get_pcvar_num( g_pSeekersSmoke );
	g_bTimerSounds = bool:get_pcvar_num( g_pSound );
	g_iSlash = get_pcvar_num( g_pSlash );
	
	if( GetPlayers( ) )
	{
		g_bStarted = true;
		g_iTimer = get_pcvar_num( g_pTimer );
	}
}

public EventRoundStart()
{
	if( g_bStarted )
	{
		TaskTimer( );
	}
}


public EventRoundEnd( )
{
	if( !GetPlayers( ) || !g_bStarted )
	{
		return PLUGIN_CONTINUE;
	}
	
	if( get_pcvar_num( g_pScrimRounds ) )
	{
		new bool:bShouldSwitch = bool:( ++g_iScrimRounds == get_pcvar_num( g_pScrimRounds ) );
		
		if( bShouldSwitch && g_bSecondRound )
		{
			set_hudmessage( 0, 255, 0, -1.0, 0.82, 1, 0.0, 5.0, 0.1, 0.2, 1 );
			show_hudmessage( 0, "Scrim has ended." );
			
			PrintColor( 0, "Team 1 (CT): %i | Team 2 (Terrorist): %i", g_iScrimPoints[ FIRST_TEAM ], g_iScrimPoints[ SECOND_TEAM ] );
			
			g_iScrimRounds = 0;
			g_bSecondRound = false;
			g_iScrimPoints[ FIRST_TEAM ] = 0;
			g_iScrimPoints[ SECOND_TEAM ] = 0;
		}
		
		else if( bShouldSwitch )
		{
			SwapTeams( );
			
			set_hudmessage( 0, 255, 0, -1.0, 0.82, 1, 0.0, 5.0, 0.1, 0.2, 1 );
			show_hudmessage( 0, "%i rounds have passed^nSwitching teams..", g_iScrimRounds );
			
			g_iScrimRounds = 0;
			g_bSecondRound = true;
		}
	}
	
	else
	{
		if( !TerroristAlive( ) )
		{
			SwapTeams( );
			
			g_bAllowSlash = false;
			g_iRoundsLost = 0;
			
			set_hudmessage( 0, 128, 255, -1.0, 0.82, 1, 0.0, 5.0, 0.1, 0.2, 1 );
			show_hudmessage( 0, "Seekers Win^nSwitching Teams.." );
		}
		
		else if( g_iRoundsLost >= get_pcvar_num( g_pSwitch ) > 0 )
		{
			SwapTeams( );
			
			set_hudmessage( 0, 255, 0, -1.0, 0.82, 1, 0.0, 5.0, 0.1, 0.2, 1 );
			show_hudmessage( 0, "%i rounds have passed^nSwitching teams..", g_iRoundsLost );
			
			g_bAllowSlash = false;
			g_iRoundsLost = 0;
		}
		
		else
		{
			set_hudmessage( 255, 0, 0, -1.0, 0.82, 1, 0.0, 5.0, 0.1, 0.2, 1 );
			show_hudmessage( 0, "Hiders Win" );	
		}
	}
	
	return PLUGIN_CONTINUE;
}

public EventTerroristsWin( )
{
	if( !get_pcvar_num( g_pScrimRounds ) )
	{
		g_iRoundsLost++;
	}
	
	else if( !g_bSecondRound )
	{
		g_iScrimPoints[ FIRST_TEAM ]++;
	}
	
	else
	{
		g_iScrimPoints[ SECOND_TEAM ]++;
	}
}

public EventCTsWin( )
{
	if( get_pcvar_num( g_pScrimRounds ) )
	{
		if( !g_bSecondRound )
		{
			g_iScrimPoints[ SECOND_TEAM ]++;
		}
		
		else
		{
			g_iScrimPoints[ FIRST_TEAM ]++;
		}
	}
}

public MsgScreenFade( iId, iDest, iClient )
{
	if( get_msg_arg_int( 4 ) == 255 
	&& get_msg_arg_int( 5 ) == 255 
	&& get_msg_arg_int( 6 ) == 255 )
	{
		switch( cs_get_user_team( iClient ) )
		{
			case CS_TEAM_T:
			{
				if( g_bNoFlash )
				{
					return PLUGIN_HANDLED;
				}
			}
			
			case CS_TEAM_CT:
			{
				if( g_iTimer > 0 )
				{
					return PLUGIN_HANDLED;
				}
			}
		}
	}
	
	return PLUGIN_CONTINUE;
}

public MsgTextMsg( )
{
	static szMsg[ 32 ];
	get_msg_arg_string( 2, szMsg, 31 );
	
	switch( szMsg[ 1 ] )
	{
		case 'C', 'T', 'H': 
		{
			return PLUGIN_HANDLED;
		}
	}
	
	return PLUGIN_CONTINUE;
}

public client_PreThink( iClient )
{
	if( g_bNoSlowDown && is_user_alive( iClient ) )
	{
		entity_set_float( iClient, EV_FL_fuser2, 0.0 );
	}
}

public FwdPlayerSpawnPost( iClient )
{
	if( !is_user_alive( iClient ) )
	{
		return HAM_IGNORED;
	}
	
	g_bThrownGrenade[ iClient ] = false;
	
	new CsTeams:iTeam;
	iTeam = cs_get_user_team( iClient );
	
	cs_reset_user_model( iClient );
	set_user_footsteps( iClient, get_pcvar_num( g_pFootSteps ) == _:iTeam ? 1 : 0 );
	strip_user_weapons( iClient );
	set_pdata_int( iClient, OFFSET_PRIMARYWEAPON, 0 ) 
	give_item( iClient, "weapon_knife" );
	
	if( iTeam == CS_TEAM_T && g_bNadesBeginning )
	{
		GiveGrenades( iClient, iTeam );
	}
	
	return HAM_IGNORED;
}

public FwdPlayerKilled( iClient )
{
	switch( cs_get_user_team( iClient ) )
	{
		case CS_TEAM_T:
		{
			if( g_bStarted && get_pcvar_num( g_pNewNades ) )
			{
				new iPlayers[ MAXPLAYERS ], iNum;
				get_players( iPlayers, iNum, "ae", "TERRORIST" );
				
				if( iNum == 1 )
				{
					new iClient = iPlayers[ 0 ];
					
					if( g_bThrownGrenade[ iClient ] )
					{
						show_menu( iClient, g_iKeys, g_szNadeMenu, 10, "NadesMenu" );
					}
				}
			}
		}
		
		case CS_TEAM_CT:
		{
			if( g_iTimer > 0 )
			{
				entity_set_int( iClient, EV_INT_flags, entity_get_int( iClient, EV_INT_flags ) & ~FL_FROZEN );
				
				UTIL_ScreenFade( iClient, 0 );
			}
		}
	}
}

public FwdTouchWeapon( iEnt, iClient )
{
	if( ( 1 <= iClient <= g_iMaxPlayers ) && !get_pcvar_num( g_pPickup ) )
	{
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED;
}

public FwdKnifePrimaryAttack( iEnt )
{
	new iClient = entity_get_edict( iEnt, EV_ENT_owner )
	
	if( !iClient )
	{
		return HAM_IGNORED;
	}
	
	switch( cs_get_user_team( iClient ) )
	{
		case CS_TEAM_T:
		{
			return HAM_SUPERCEDE;
		}
		
		case CS_TEAM_CT:
		{
			if( !g_bAllowSlash )
			{
				ExecuteHamB( Ham_Weapon_SecondaryAttack, iEnt );
				
				return HAM_SUPERCEDE;
			}
		}
	}
	
	return HAM_IGNORED;
}

public FwdKnifeSecondaryAttack( iEnt )
{
	new iClient = entity_get_edict( iEnt, EV_ENT_owner )
	
	if( !iClient )
	{
		return HAM_IGNORED;
	}
	
	if( cs_get_user_team( iClient ) == CS_TEAM_T )
	{
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED;
}

public FwdKnifeDeployPost( iEnt )
{
	new iClient = entity_get_edict( iEnt, EV_ENT_owner )
	
	if( !iClient )
	{
		return HAM_IGNORED;
	}
	
	if( cs_get_user_team( iClient ) == CS_TEAM_T )
	{
		// entity_set_string( iClient, EV_SZ_viewmodel, "" );
		entity_set_string( iClient, EV_SZ_weaponmodel, "" );
	}
	
	return HAM_IGNORED;
}

public FwdGrenadeThink( iEnt )
{
	g_bThrownGrenade[ pev( iEnt, pev_owner ) ] = true;
}

public FwdGameDescription( )
{
	static szGameName[ 32 ];
	get_pcvar_string( g_pGameName, szGameName, 31 );
	
	if( szGameName[ 0 ] )
	{
		forward_return( FMV_STRING, szGameName );
		
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;
}

public FwdSpawnPost( iEnt )
{
	if( !is_valid_ent( iEnt ) )
	{
		return FMRES_IGNORED;
	}
	
	static szClass[ 32 ];
	entity_get_string( iEnt, EV_SZ_classname, szClass, 31 );
	
	if( TrieKeyExists( g_tEntities, szClass ) )
	{
		remove_entity( iEnt );
	}
	
	else if( get_pcvar_num( g_pRemoveBreakables ) 
	&& equal( szClass, g_szBreakable ) 
	&& entity_get_float( iEnt, EV_FL_takedamage ) )
	{
		remove_entity( iEnt );
	}
	
	else if( get_pcvar_num( g_pRemoveDoors ) )
	{
		if( equal( szClass, g_szDoor ) || equal( szClass, g_szDoorRotating ) ) 
		{
			remove_entity( iEnt );
		}	
	}
	
	return FMRES_IGNORED;
}

public FwdClientKill( iClient )
{
	if( get_pcvar_num( g_pBlockKill ) )
	{
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;
}

public CmdTeamSelect( iClient )
{
	if( InTeam( iClient ) && !get_pcvar_num( g_pChooseTeam ) )
	{
		return PLUGIN_HANDLED;
	}
	
	return PLUGIN_CONTINUE;
	
}

public TaskTimer( )
{
	if( g_iTimer > 0 )
	{
		for( new i = 1; i <= g_iMaxPlayers; i++ )
		{
			if( !is_user_alive( i ) )
			{
				continue;
			}
			
			if( cs_get_user_team( i ) == CS_TEAM_CT )
			{
				entity_set_int( i, EV_INT_flags, entity_get_int( i, EV_INT_flags ) | FL_FROZEN );
				
				UTIL_ScreenFade( i );
			}
			
			if( g_bTimerSounds )
			{
				static szSound[ 20 ];
				num_to_word( g_iTimer, szSound, 19 );
				client_cmd( i, "spk vox/%s", szSound );
			}
		}
		
		set_hudmessage( 0, 255, 0, -1.0, 0.82, 0, 0.0, 1.1, 0.0, 0.0, 1 );
		show_hudmessage( 0, "%i seconds to hide..", g_iTimer );
		
		g_iTimer--;
		set_task( 1.0, "TaskTimer", TASK_TIMER );
	}
	
	else
	{
		new CsTeams:iTeam;
		
		for( new i = 1; i <= g_iMaxPlayers; i++ )
		{
			if( !is_user_alive( i ) )
			{
				continue;
			}
			
			iTeam = cs_get_user_team( i );
			
			if( iTeam == CS_TEAM_T && g_bNadesBeginning )
			{
				continue;
			}
			
			else if( iTeam == CS_TEAM_CT )
			{
				entity_set_int( i, EV_INT_flags, entity_get_int( i, EV_INT_flags ) & ~FL_FROZEN );
				
				UTIL_ScreenFade( i, 0 );
			}
			
			GiveGrenades( i, iTeam );
		}
		
		if( g_iRoundsLost == g_iSlash )
		{
			g_bAllowSlash = true;
			
			PrintColor( 0, "CTs have lost %i rounds in a row, they can now use slash.", g_iSlash );
		}
		
		set_hudmessage( 0, 255, 0, -1.0, 0.82, 1, 0.0, 3.0, 0.0, 0.0, 1 );
		show_hudmessage( 0, "Ready or not, here we come!" );
	}
}

public HandleNadeMenu( iClient, iKey )
{
	if( !iKey )
	{
		GiveGrenades( iClient, CS_TEAM_T );
	}
}

GiveGrenades( const iClient, const CsTeams:iTeam )
{
	switch( iTeam )
	{
		case CS_TEAM_T:
		{
			if( g_bHeGrenade[ TERRORIST ] )
			{
				give_item( iClient, "weapon_hegrenade" );
			}
			
			if( g_bSmokeGrenade[ TERRORIST ] )
			{
				give_item( iClient, "weapon_smokegrenade" );
			}
			
			if( g_iFlashbangs )
			{
				give_item( iClient, "weapon_flashbang" );
				
				cs_set_user_bpammo( iClient, CSW_FLASHBANG, g_iFlashbangs );
			}
		}
		
		case CS_TEAM_CT:
		{
			if( g_bHeGrenade[ CT ] )
			{
				give_item( iClient, "weapon_hegrenade" );
			}
			
			if( g_bSmokeGrenade[ CT ] )
			{
				give_item( iClient, "weapon_smokegrenade" );
			}
		}
	}
}

SwapTeams( )
{
	for( new i = 1; i <= g_iMaxPlayers; i++ )
	{
		if( is_user_connected( i ) )
		{
			switch( cs_get_user_team( i ) )
			{
				case CS_TEAM_T:
				{
					cs_set_user_team( i, CS_TEAM_CT );
				}
					
				case CS_TEAM_CT:
				{
					cs_set_user_team( i, CS_TEAM_T );
				}
			}
		}
	}
}

PrintColor( iClient, szText[], any:... )
{
	new szMsg[ 191 ];
	formatex( szMsg, 190, "^x04[HNS]^x01 " );
	vformat( szMsg[ 8 ], 185, szText, 3 );

	message_begin( iClient ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, iClient );
	write_byte( 1 );
	write_string( szMsg );
	message_end();
}

UTIL_ScreenFade( const iClient, iFade = 1 )
{
	message_begin( MSG_ONE, g_iMsgScreenFade, _, iClient )
	write_short( 7500 * iFade );
	write_short( 7500 * iFade );
	write_short( 0x0000 );
	write_byte( g_iFadeColor[ 0 ] );
	write_byte( g_iFadeColor[ 1 ] );
	write_byte( g_iFadeColor[ 2 ] );
	write_byte( g_iFadeColor[ 3 ] );
	message_end();
}

bool:TerroristAlive( )
{
	for( new i = 1; i <= g_iMaxPlayers; i++ )
	{
		if( is_user_alive( i ) && cs_get_user_team( i ) == CS_TEAM_T )
		{
			return true;
		}
	}
	
	return false;
}

bool:GetPlayers( )
{	
	new iTerrorists, iCTs;
	
	for( new i = 1; i <= g_iMaxPlayers; i++ )
	{
		if( !is_user_connected( i ) )
		{
			continue;
		}
		
		switch( cs_get_user_team( i ) )
		{
			case CS_TEAM_T:
			{
				iTerrorists++;
			}
			
			case CS_TEAM_CT:
			{
				iCTs++;
			}
		}
		
		if( iTerrorists && iCTs )
		{
			return true;
		}
	}
	
	return false;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1044\\ f0\\ fs16 \n\\ par }
*/

отправляй мессагу client screen shake да и все

Можешь поподробнее объяснить?

Код:

if( cs_get_user_team( i ) == CS_TEAM_CT )
{
      entity_set_int( i, EV_INT_flags, entity_get_int( i, EV_INT_flags ) | FL_FROZEN );
          
      UTIL_ScreenFade( i );
}

на

Код:

if( cs_get_user_team( i ) == CS_TEAM_CT )
{
      entity_set_int( i, EV_INT_flags, entity_get_int( i, EV_INT_flags ) | FL_FROZEN );
      UTIL_ScreenShake( i , (1<<12), (1<<12), (1<<12) );
      UTIL_ScreenFade( i );
}

чуть ниже кинь

Код:

stock UTIL_ScreenShake(pPlayer, iAmplitude, iDuration, iFrequency, iReliable = 0)
{
	engfunc(EngFunc_MessageBegin, iReliable ? MSG_ONE : MSG_ONE_UNRELIABLE, 97, {0.0, 0.0, 0.0}, pPlayer);
	write_short(iAmplitude);
	write_short(iDuration);
	write_short(iFrequency);
	message_end();
}