Плагин /voteban

Ребят, помогите мне настроить плагин /voteban, что бы постоянный вотебан давался только админам с флагом d, сейчас постоянный вотебан дается всем у кого есть какой либо флаг, заранее спасибо.

попробуй
Код:

#include <amxmodx>
#include <amxmisc>

#define MAX_players 32
#define MAX_menudata 1024

new ga_PlayerName[MAX_players][32]
new ga_PlayerAuthID[MAX_players][35]
new ga_PlayerID[MAX_players]
new ga_PlayerIP[MAX_players][16]
new ga_MenuData[MAX_menudata]
new ga_Choice[2]
new gi_VoteStarter
new gi_MenuPosition
new gi_Sellection
new gi_TotalPlayers
new gi_SysTimeOffset = 0
new i
//pcvars
new gi_LastTime
new gi_DelayTime
new gf_MinVoters
new gf_Ratio
new gi_BanTime
new gi_Disable
new gi_BanType
new pCvarAdminOnline


public plugin_init()
{
	register_plugin("voteban menu","1.2","hjvl")
	register_clcmd("say /voteban","SayIt" )
	register_menucmd(register_menuid("ChoosePlayer"), 1023, "ChooseMenu")
	register_menucmd(register_menuid("VoteMenu"), 1023, "CountVotes")

	gi_LastTime=register_cvar("amx_voteban_lasttime","0")
	gi_DelayTime=register_cvar("amxx_voteban_delaytime","600")
	gf_Ratio=register_cvar("amxx_voteban_ratio","0.50")
	gf_MinVoters=register_cvar("amxx_voteban_minvoters","0.0")
	gi_BanTime=register_cvar("amxx_voteban_bantime","5")
	gi_Disable=register_cvar("amxx_voteban_disable","0")
	gi_BanType=register_cvar("amxx_voteban_type","1")
	pCvarAdminOnline = register_cvar("amxx_voteban_adminonline", "0")
}

public SayIt(id)
{
	if(!(get_user_flags(id) & ADMIN_BAN))
	{
		client_print(id,print_chat,"Вотебан только для админов")
		return 0
	}
	
	
	if(get_pcvar_num(gi_Disable))
	{
		client_print(id,print_chat,"Данная функция отключена")
		return 0
	}

	new Elapsed=get_systime(gi_SysTimeOffset) - get_pcvar_num(gi_LastTime)
	new Delay=get_pcvar_num(gi_DelayTime)

	if( (Delay > Elapsed) && !is_user_admin(id) )
	{
		new seconds = Delay - Elapsed
		client_print(id,print_chat,"Голосование будет доступно через %d сек.", seconds)
		return 0
	}

	get_players( ga_PlayerID, gi_TotalPlayers )
	for(i=0; i<gi_TotalPlayers; i++)
	{
		new TempID = ga_PlayerID[i]
		if( is_user_admin(TempID) && get_pcvar_num(pCvarAdminOnline))
		{
			if(!is_user_admin(id))
			{
				client_print(id,print_chat,"Голосования запрещены, т.к. Администрация на сервере")
				return 0
			}
		}

		if(TempID == id)
			gi_VoteStarter=i

		get_user_name( TempID, ga_PlayerName[i], 31 )
		get_user_authid( TempID, ga_PlayerAuthID[i], 34 )
		get_user_ip( TempID, ga_PlayerIP[i], 15, 1 )
	}

	gi_MenuPosition = 0
	ShowPlayerMenu(id)
	return 0
}

public ShowPlayerMenu(id)
{
	new arrayloc = 0
	new keys = (1<<9)
	
	arrayloc = format(ga_MenuData,(MAX_menudata-1),"\yКого банить будем?^n^n\w")
	
	for(i=0; i<8; i++)
	{   
		if( gi_TotalPlayers>(gi_MenuPosition+i) )
		{
			new pid = get_user_index(ga_PlayerName[gi_MenuPosition+i])
			
			if(get_user_flags(pid) & ADMIN_IMMUNITY)
			{
				arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"%d.\d %s \r[Админ]^n\w", i+1, ga_PlayerName[gi_MenuPosition+i])
				keys &= ~(1<<i)
			}else if(pid == id)
			{
				arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"%d.\d %s \r[Это Вы]^n\w", i+1, ga_PlayerName[gi_MenuPosition+i])
				keys &= ~(1<<i)
			}else{
				arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"%d. %s^n", i+1, ga_PlayerName[gi_MenuPosition+i])
				keys |= (1<<i)
			}
		}
	}	
	 
	if( gi_TotalPlayers>(gi_MenuPosition+8) )
	{
		arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"^n9. \wДальше...")
		keys |= (1<<8)
	}
	  
	arrayloc += format(ga_MenuData[arrayloc],(MAX_menudata-1-arrayloc),"^n0. \wНазад/выход")
	
	show_menu(id, keys, ga_MenuData, 20, "ChoosePlayer")
	return PLUGIN_HANDLED 
}

public ChooseMenu(id, key)
{
	switch(key)
	{
		case 8:
		{
			gi_MenuPosition=gi_MenuPosition+8
			ShowPlayerMenu(id)
		}
		case 9:
		{
			if(gi_MenuPosition>=8)
			{
				gi_MenuPosition=gi_MenuPosition-8
				ShowPlayerMenu(id)
			}else
				return 0
		}
		default:
		{ 
			gi_Sellection=gi_MenuPosition+key
			new pid = get_user_index(ga_PlayerName[gi_Sellection])
			
			if(get_user_flags(pid) & ADMIN_IMMUNITY || id == pid)
			{
				ShowPlayerMenu(id)
				return 0
			}
			
			new Now=get_systime(gi_SysTimeOffset)
			set_pcvar_num(gi_LastTime, Now)
		
			run_vote()
			return 0
		}
	}
	return PLUGIN_HANDLED
}

public run_vote()
{
	log_amx("Vote ban started by %s for %s %s", ga_PlayerName[gi_VoteStarter], ga_PlayerName[gi_Sellection], ga_PlayerAuthID[gi_Sellection])
	format(ga_MenuData,(MAX_menudata-1),"Забанить \r%s\w на \r%d\w мин.?^n^n1. Да^n2. Нет^n^n^n^n^n^n^n0. Воздержаться",ga_PlayerName[gi_Sellection], get_pcvar_num(gi_BanTime))
	ga_Choice[0] = 0
	ga_Choice[1] = 0
	show_menu( 0, (1<<0)|(1<<1)|(1<<9), ga_MenuData, 15, "VoteMenu" )
	set_task(15.0,"outcom")
	return 0
}

public CountVotes(id, key)
{
	new szName[32]
	get_user_name(id, szName, 31)
	
	if(key == 9)
	{
		client_print(0, print_chat, "%s не принял участия в голосовании о бане %s", szName, ga_PlayerName[gi_Sellection])
		return PLUGIN_HANDLED
	}

	if(key == 0)
		client_print(0, print_chat, "%s проголосовал за бан %s", szName, ga_PlayerName[gi_Sellection])
	else if(key == 1)
		client_print(0, print_chat, "%s проголосовал против бана %s", szName, ga_PlayerName[gi_Sellection])
		
	++ga_Choice[key]
	return PLUGIN_HANDLED
}

public outcom()
{
	new TotalVotes = ga_Choice[0] + ga_Choice[1]
	new Float:result = (float(ga_Choice[0]) / float(TotalVotes))

	if( get_pcvar_float(gf_MinVoters) >= ( float(TotalVotes) / float(gi_TotalPlayers) ) )
	{
		client_print(0,print_chat,"Недостаточно голосов для бана %s", ga_PlayerName[gi_Sellection])
		return 0
	}else{
		if( result >= get_pcvar_float(gf_Ratio) )
		{
			client_print(0,print_chat,"Голосование окончено. Игрок %s был забанен на %d мин.", ga_PlayerName[gi_Sellection], get_pcvar_num(gi_BanTime))
			log_amx("The vote succeeded: %s is banned for %d minutes", ga_PlayerAuthID[gi_Sellection], get_pcvar_num(gi_BanTime))
			ActualBan(gi_Sellection)
		}else{
			client_print(0,print_chat,"Голосование не состоялось")
			log_amx("The voteban dit not sucseed.")
		}
	}
	client_print(0,print_chat,"Всего проголосовало %d игроков, %d - За", gi_TotalPlayers, ga_Choice[0])

	return 0
}

public ActualBan(Selected)
{
	new Type = get_pcvar_num(gi_BanType) 
	switch(Type)
	{
		case 1:server_cmd("addip %d %s;writeip", get_pcvar_num(gi_BanTime), ga_PlayerIP[Selected])
		case 2:server_cmd("amx_ban %d %s Voteban", get_pcvar_num(gi_BanTime), ga_PlayerAuthID[Selected])
		default:server_cmd("banid %d %s kick;writeid", get_pcvar_num(gi_BanTime), ga_PlayerAuthID[Selected])
	}
	
	return 0 
}

YrkinSon,
Теперь он постоянно работает только для тех у кого флаг д, а для обычных игроков не работает вообще, можно сделать, что бы он для обычных игроков раз в 400 сек работал?

Kili777, А для админов вотебан обязателен О_о , у них же есть своя команда для банов , или же нужно чтобы админ прописовал вотебан чтобы игроки проголосовали чит он или кемпер и т.д , впечатление что у вас админы на сервере даже поздароваться бояться без согласия игроков