Женские модели ღ

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define FLAG_ACCESS "s"

new const MODEL_TT[] = "girl_tt";
new const MODEL_CT[] = "girl_ct";

new bool:gbAccess[33], gszPlayerModel[33][32];

public plugin_init()
{
    register_plugin("MODELS", "1.0", "http://c-s.net.ua");
    RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", 1);
    register_forward(FM_SetClientKeyValue, "FM_SetClientKeyValue_Pre", 0);
}

public plugin_precache()
{
    new szBuffer[128];
    formatex(szBuffer, charsmax(szBuffer), "models/player/%s/%s.mdl", MODEL_CT, MODEL_CT);
    precache_model(szBuffer);
    formatex(szBuffer, charsmax(szBuffer), "models/player/%s/%s.mdl", MODEL_TT, MODEL_TT);
    precache_model(szBuffer);
}

public client_putinserver(id)
    gbAccess[id] = (get_user_flags(id) & read_flags(FLAG_ACCESS)) ? true : false;

public Ham_PlayerSpawn_Post(id)
{
    if(gbAccess[id] && is_user_alive(id))
    {
        switch(get_pdata_int(id, 114))
        {
            case 1: fm_cs_set_user_model(id, MODEL_TT);
            case 2: fm_cs_set_user_model(id, MODEL_CT);
        }
    }
}

public FM_SetClientKeyValue_Pre(id, const szInfobuffer[], const szKey[])
{
    if(gbAccess[id] && equal(szKey, "model"))
    {
        static szCurrentModel[32];
        fm_cs_get_user_model(id, szCurrentModel, charsmax(szCurrentModel));
        if(!equal(szCurrentModel, gszPlayerModel[id])) fm_cs_set_user_model(id, gszPlayerModel[id]);
        return FMRES_SUPERCEDE;
    }
    return FMRES_IGNORED;
}

stock fm_cs_get_user_model(id, szModel[], szLen) engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", szModel, szLen);
stock fm_cs_set_user_model(id, const szModelName[])
{
    engfunc(EngFunc_SetClientKeyValue, id, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", szModelName);
    copy(gszPlayerModel[id], charsmax(gszPlayerModel[]), szModelName);
}