Как убрать убрать предмет шапка при включение инвиза

Подскажите, какую функцию и где использовать, чтоб если игроку выдали инвиз, то шапка исчезает и при респавне чтоб шапка автоматически выдавалась та, которая была надета прежде до инвиза

а не проще шапку делать прозрачной?

Как?

в код шапки добавить форвард, по этому форварду определить когда вызывается инвиз и делать шапку прозрачной

А можно пример? Не понимаю как это сделать

примерно так
Код:

// Copyright 2015 Vaqtincha

/** Santa Hats Rewrite (fakemata)
*
*	It is modified plugin not the original.
*	  See https://forums.alliedmods.net/showthread.php?t=81172
*
*	Last update:
*	  04/11/2015
*
*	Credits:
*	- KaLoSZyFeR (for plugin "Admin Mark"
*	- Safety1st
*
*/

/*--------------------------- CONFIG START -----------------------------*/

// #define ACCESS_FLAG ADMIN_LEVEL_B  		// flag 'n' by default uncomment to enable
new MODEL_T[] = "models/had_red.mdl"	// model
new MODEL_CT[] = "models/had_blue.mdl"	// model
// #define CZBOT_SUPPORT						// register CZ bots with ham

/*---------------------------- CONFIG END ------------------------------*/


#include <amxmodx> 
#include <hamsandwich> 
#include <fakemeta> 
#include <cstrike> 
#include < engine >

forward Cs_Shop_ItemInvisible(id, iValue);


new giCachedStringInfoTarget
new g_iEnt[33]
new modelname[9][] ={"gign","gsg9","sas","urban","vip",
"arctic","guerilla","leet","terror"}

new bool:g_bInvisibleHat[33];

new CsTeams:my_team ;

public plugin_init()
{
	register_plugin( "Santa Hats Rewrite", "0.0.2", "Vaqtincha" )
	register_event( "TeamInfo", "EventTeamInfo", "a" );
	RegisterHam(Ham_Spawn, "player", "PlayerMark", .Post = 1 )

	giCachedStringInfoTarget = engfunc( EngFunc_AllocString, "info_target" )
}

public EventTeamInfo( ) {
	new id = read_data( 1 ), iEntity = g_iEnt[id];
    
	if( !is_valid_ent( iEntity ) ) {
		if( iEntity > 0 )
			g_iEnt[id] = 0;
        
		return;
	}
    
	new szTeam[ 2 ];
	read_data( 2, szTeam, 1 );
    
	if( szTeam[ 0 ] == 'C' )
		entity_set_model( iEntity, MODEL_CT );
	else
		entity_set_model( iEntity, MODEL_T );
}


public plugin_precache()
{
	precache_model(MODEL_T)
	precache_model(MODEL_CT)
}
#if defined CZBOT_SUPPORT
new bool: g_BotsRegistered
public client_authorized(id)
{
	if(!g_BotsRegistered && is_user_bot(id))
	{
		set_task(0.1, "register_bots", id)
	}
}

public register_bots(id)
{
	if(!g_BotsRegistered && is_user_connected(id))
	{
		RegisterHamFromEntity(Ham_TakeDamage, id, "PlayerMark")
		g_BotsRegistered = true
	}
}
#endif

public PlayerMark(id)
{
	if(!is_user_alive(id))
		return
#if defined ACCESS_FLAG		
	if(!(get_user_flags(id) & ACCESS_FLAG))
		return
#endif

	my_team = cs_get_user_team(id)

	if(g_iEnt[id] < 1)
	{
		g_iEnt[id] = engfunc(EngFunc_CreateNamedEntity, giCachedStringInfoTarget)
		if(g_iEnt[id] > 0)
		{
			set_pev( g_iEnt[id], pev_movetype, MOVETYPE_FOLLOW)
			set_pev( g_iEnt[id], pev_aiment, id)

			switch (my_team)
			{
				case (CS_TEAM_CT): engfunc( EngFunc_SetModel, g_iEnt[id], MODEL_CT) 
        			case (CS_TEAM_T):engfunc( EngFunc_SetModel, g_iEnt[id], MODEL_T) 
			}
		}
	}
	if (g_iEnt[id] > 0)
	{
		new modelID = get_model_id(id)
		set_pev(g_iEnt[id], pev_body, modelID)
		
		if(g_bInvisibleHat[id] && pev_valid(g_iEnt[id]))
		{
			g_bInvisibleHat[id] = false;
			
			fm_set_user_rendering(g_iEnt[id]);
		}
	}
}

public client_disconnect(id)
{
	if(g_iEnt[id] > 0 && pev_valid(g_iEnt[id]))
		engfunc(EngFunc_RemoveEntity, g_iEnt[id])
	g_iEnt[id] = 0
	
	g_bInvisibleHat[id] = false;
}

public Cs_Shop_ItemInvisible(id, iValue)
{
	if(g_iEnt[id] > 0 && pev_valid(g_iEnt[id]))
	{
		g_bInvisibleHat[id] = true;
		
		fm_set_user_rendering(g_iEnt[id], kRenderFxGlowShell, 0, 0, 0, kRenderTransAlpha, iValue);
	}
}

public get_model_id(id)
{
	new modelStr[32], iNum=32, modelID
	get_user_info(id,"model",modelStr,iNum)
	
	for(new i = 0; i < 9; i++)
	{
		if (equali (modelStr, modelname[i]) )
		{
			modelID = i
		}
	}	
	return modelID
}

stock fm_set_user_rendering(id, fx = kRenderFxNone, r = 255, g = 255, b = 255, render = kRenderNormal, amount = 16)
{
	new CountAmount = amount * 255 / 100;
	new Float:RenderColor[3];
	RenderColor[0] = float®;
	RenderColor[1] = float(g);
	RenderColor[2] = float(b);

	set_pev(id, pev_renderfx, fx);
	set_pev(id, pev_rendercolor, RenderColor);
	set_pev(id, pev_rendermode, render);
	set_pev(id, pev_renderamt, float(CountAmount));

	return 1;
}