Flash Sprite

#include <amxmodx>
#include <fakemeta>
#include <reapi>

#define SPRITE "sprites/flash_sprite/cultura_flash.spr"
#define SPRITE_CLASSNAME "func_flash"
#define SPRITE_IMPULSE 4563
#define SPRITE_SCALE 0.15

enum _:BLIND_DATA
{
    SPRITE_ID,
    Float:BLIND_TIME,
    Float:FINISH_FLASH
};

new g_ePlayerData[MAX_PLAYERS + 1][BLIND_DATA];

public plugin_precache()
{
    precache_model(SPRITE);
}

public plugin_init()
{
    register_plugin("Flash Sprite (frames)", "1.0", "Denzer");

    RegisterHookChain(RG_PlayerBlind, "PlayerBlind_Post", true);
}

public PlayerBlind_Post(const id, const inflictor, const attacker, const Float:fadeTime, const Float:fadeHold, const alpha, Float:color[3])
{
    if(alpha)
    {
        g_ePlayerData[id][BLIND_TIME] = get_gametime() + fadeHold;
        g_ePlayerData[id][FINISH_FLASH] = get_gametime() + (fadeTime-fadeHold);

        if(g_ePlayerData[id][SPRITE_ID])
            return;

        new Float:frame; frame = alpha == 255 ? 99.0 : alpha/255.0*100.0;
        new iEnt = rg_create_entity("info_target", true);

        if(iEnt)
        {
            set_entvar(iEnt, var_classname, SPRITE_CLASSNAME);
            set_entvar(iEnt, var_impulse, SPRITE_IMPULSE);
            set_entvar(iEnt, var_movetype, MOVETYPE_FOLLOW);
            set_entvar(iEnt, var_aiment, id);
            engfunc(EngFunc_SetModel, iEnt, SPRITE);
            set_entvar(iEnt, var_scale, SPRITE_SCALE);
            set_entvar(iEnt, var_frame, frame);

            SetThink(iEnt, "SpriteThink");
            set_entvar(iEnt, var_nextthink, 0.1);
        }
        g_ePlayerData[id][SPRITE_ID] = iEnt;
    }
}

public SpriteThink(iEnt)
{
    if(iEnt)
    {
        new blind_id = get_entvar(iEnt, var_aiment);
        // thx garey
        new Float:frame; frame = g_ePlayerData[blind_id][BLIND_TIME] > get_gametime() ? 99.0 : (1.0-((get_gametime()-g_ePlayerData[blind_id][BLIND_TIME])/(g_ePlayerData[blind_id][FINISH_FLASH]-g_ePlayerData[blind_id][BLIND_TIME])))*100.0;

        if(frame <= 0.0)
        {
            g_ePlayerData[blind_id][SPRITE_ID] = 0;
            set_entvar(iEnt, var_flags, FL_KILLME);
            return;
        }

        set_entvar(iEnt, var_frame, frame);
        set_entvar(iEnt, var_nextthink, 0.1);
    }
}