Замена модели джамп гранаты (Жабы) Для зомби класса Ведьмы

Всем привет! Кто нибудь знает как заменить модель бомбы для зомби класса ведьма? По статьям пробовал ничего не получается + я не шарю в скриптинге. Вам отправляю Исходник зомби класса, и модель жабы.

 Модель_бомбы.rar ( 257,9 килобайт ) Кол-во скачиваний: 10

 xman2030_witch.sma ( 11,58 килобайт ) Кол-во скачиваний: 10


Всем заранее спасибо!

Я никогда не занимался этими гранатами с руками,которые должны соответствовать пустым рукам,ибо не использую вовсе гранаты - только инфекционную ))) ...но
Сделал,правда не проверял
Закинь всё как полагается
С тебя пиво... + орехи )

 xman2030_witch.rar ( 263,37 килобайт ) Кол-во скачиваний: 16

$@NyA,
Спасибо Сань, Всё работает!
Пиво и орехи твои)

Хотя нет ничего не работает хотя модель скачалась, но не работает.
Кто знает что делать пишите!

TheArtemMaps,
Так ты же написал,что работает всё )))
А потом вдруг стало не робочим?
И тут думаем - что же там случилось то...

Поторопился, я же увидел что модель скачалась то подумал что робит, но модель стандартная почему-то..

TheArtemMaps,
Проверил теперь у себя - работает модель рук с гранатой
Ибо в коде же я поставил,что-бы любая граната принимала соответствующую модель
Код:

        new const GRENADES_ENTITY[][] = { "weapon_hegrenade", "weapon_flashbang", "weapon_smokegrenade" };
        for(new i = 0; i < sizeof GRENADES_ENTITY; i++)
	RegisterHam(Ham_Item_Deploy, GRENADES_ENTITY[i], "Grenade_DeployPost", true);

Также принтует в чат,что
Код:

client_printcolor(id, "!g[ZP] !yДанный класс !tBanchee !yдоступен с !g10 уровня!")

Проверяйте этот класс с 10 уровня

Либо вот версия без 10 уровня
 xman2030_witch.sma ( 11,96 килобайт ) Кол-во скачиваний: 4

$@NyA,
Проверял у меня там есть 10 уровень, всё равно нету.

Может всё таки забыл проверить?

TheArtemMaps,
У меня работает на инфекционной гранате твоя модель.
Значит нужен код ещё и Джамп гранаты - там править нужно
Скидуй сюда - только не в режиме скачать ( надоело уже ) - кодом крепи сынок )

Хорошо) вот код
Код:

- Создание плагинов на заказ:
- Контакты:
- Vk: http://vk.com/Opo4uMapy
- ICQ: 585552410
*/

#include < amxmodx >
#include < fakemeta >
#include < hamsandwich >
#include < zombieplague >

#define PLUGIN		"[ZP] Extra Item: Jump Bomb"
#define VERSION		"1.0"
#define AUTHOR		"Opo4uMapy"

native BlotterGetBombs(iPlayer);
native BlotterSetBombs(iPlayer, iAmount);
native BlotterRemoveBomb(iPlayer);

native cs_get_user_bpammo(index, weapon)
native cs_set_user_bpammo(index, weapon, amount)

#define JUMPBOMB_ID		55556

/////////////////////////////////////Cvars/////////////////////////////////////

#define ITEM_NAME		"JUMP" 	// Имя айтема
#define ITEM_COST		6 		// Стоимость за 1 бомбу
#define MAX_GRENADE			5 		// Лимит гранат
#define RADIUS			300.0 		// Радиус взрыва
#define JUMP_EXP		800.0		// Сила отдачи от гранаты	

#define BLOTTER_BOMB_W "models/xman2030/grenade/w_blotter_bomb_ability.mdl"

#define GRENADE_ICON				//Иконка с лева. Что бы отключить поставьте //


#define TRAIL		//Трайл за гранатой. Что бы отключить закоментируем ( //#define TRAIL )

/////////////////////////////////////WeaponList/////////////////////////////////////

//#define WEAPONLIST 	// WeaponList. Что бы отключить закоментируем ( //#define WEAPONLIST )

#define WEAPON_DEFAULT		"weapon_smokegrenade"	//Weapon под которую сделана граната
#define DEFAULT_CSW		CSW_SMOKEGRENADE	//CSW под которую сделана граната

#if defined WEAPONLIST
#define WEAPON_NEW		"weapon_zombj1_sisa"	//Название WeaponList'a новой гранаты

new const WeaponList_Sprite[][] =
{

}

enum
{
	prim_ammoid 		= 13,
	prim_ammomaxamount 	= 1,
	sec_ammoid 		= -1,
	sec_ammomaxamount 	= -1,
	slotid 			= 3,
	number_in_slot 		= 3,
	weaponid 		= 9,
	flags 			= 24
}
#endif

////////////////////////////////////////////////////////////////////////////////////

// Модели гранаты
new const BOMB_MODEL[][] = 
{
	"models/xman2030/grenade/v_zombibomb.mdl",
	"models/xman2030/grenade/p_zombibomb.mdl",
	"models/xman2030/grenade/w_zombibomb.mdl"
}

//Звуки покупки
#define	g_SoundGrenadeBuy	"items/gunpickup2.wav"
#define g_SoundAmmoPurchase	"items/9mmclip1.wav"
	
//Звук взрыва
#define g_SoundBombExplode	"xman2030/jump/zombi_bomb_exp.wav"

//Не изменять! Звуки прописаны в модели.
new const frogbomb_sound[][] = 
{
	"xman2030/jump/zombi_bomb_pull_1.wav", 
	"xman2030/jump/zombi_bomb_deploy.wav",
	"xman2030/jump/zombi_bomb_throw.wav"
}

new const frogbomb_sound_idle[][] = 
{ 
	"xman2030/jump/zombi_bomb_idle_1.wav", 
	"xman2030/jump/zombi_bomb_idle_2.wav", 
	"xman2030/jump/zombi_bomb_idle_3.wav", 
	"xman2030/jump/zombi_bomb_idle_4.wav"
}
new g_itemid

new g_JumpGrenadeCount[33], g_iExplo
#if defined TRAIL
new g_trailSpr
#endif
#if defined GRENADE_ICON
new grenade_icons[33][32]
#endif

public plugin_precache()
{
	static i

	for(i = 0; i < sizeof BOMB_MODEL; i++)
		precache_model(BOMB_MODEL[i])
	
	precache_model(BLOTTER_BOMB_W)

	for(i = 0; i < sizeof frogbomb_sound; i++)
		precache_sound(frogbomb_sound[i])

	for(i = 0; i < sizeof frogbomb_sound_idle; i++)
		precache_sound(frogbomb_sound_idle[i])

	precache_sound(g_SoundGrenadeBuy)
	precache_sound(g_SoundAmmoPurchase)
	precache_sound(g_SoundBombExplode)

	#if defined WEAPONLIST
	register_clcmd(WEAPON_NEW, "hook")

	for(i = 0; i < sizeof WeaponList_Sprite; i++)
		precache_generic(WeaponList_Sprite[i])

	#endif

	g_iExplo = precache_model("sprites/xman2030/zombiebomb_exp.spr")

	#if defined TRAIL
	g_trailSpr = precache_model("sprites/laserbeam.spr")
	#endif
}

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	//Ham
	RegisterHam(Ham_Think, "grenade", "fw_ThinkGrenade")
	RegisterHam(Ham_Item_Deploy, WEAPON_DEFAULT, "DeployPost", 1)

	//Forward
	register_forward(FM_SetModel, "fw_SetModel")

	//Event
	register_event("DeathMsg", "DeathMsg", "a")

	#if defined GRENADE_ICON
	register_event("CurWeapon", "grenade_icon", "be", "1=1")
	#endif

	//Extra Item
	g_itemid = zp_register_extra_item(ITEM_NAME, ITEM_COST, ZP_TEAM_ZOMBIE)
}

#if defined WEAPONLIST
public hook(id)
{ 
	if(!is_user_connected(id))
		return PLUGIN_CONTINUE
		
	engclient_cmd(id, WEAPON_DEFAULT)
	
	return PLUGIN_HANDLED
}
#endif

public plugin_natives() register_native("give_jump", "give_bomb", 1);

public zp_extra_item_selected(id, Item)
{
	if(Item == g_itemid)
		give_bomb(id, false);

	return PLUGIN_HANDLED
}

public give_bomb(id, bool:bBlotter) {
	
	if(!bBlotter && g_JumpGrenadeCount[id] >= MAX_GRENADE) {
	
		return ZP_PLUGIN_HANDLED
		
	}

	new Ammo = cs_get_user_bpammo(id, DEFAULT_CSW)
	new iBlotterBombs = BlotterGetBombs(id);
	
	if(!iBlotterBombs && g_JumpGrenadeCount[id] <= 0) {
	
		if(!bBlotter) g_JumpGrenadeCount[id] = 1
		else BlotterSetBombs(id, iBlotterBombs + 1);
		
		fm_give_item(id, WEAPON_DEFAULT)
		emit_sound(id, CHAN_ITEM, g_SoundGrenadeBuy, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
	
	} else {
	
		if(!bBlotter) g_JumpGrenadeCount[id]++
		else BlotterSetBombs(id, iBlotterBombs + 1);
		
		cs_set_user_bpammo(id, DEFAULT_CSW, Ammo + 1)
		emit_sound(id, CHAN_ITEM, g_SoundAmmoPurchase, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
		
	}

	AmmoPickup(id)
	#if defined WEAPONLIST
	WeaponList(id, 1)
	#endif

	return PLUGIN_HANDLED
}

public zp_user_infected_post(id, infector, nemesis)
{
	if(zp_get_user_nemesis(id) || zp_is_survivor_round() || zp_is_nemesis_round())
		return

	g_JumpGrenadeCount[id] = 0

	fm_give_item(id, WEAPON_DEFAULT)	
	cs_set_user_bpammo(id, DEFAULT_CSW, 1)
	emit_sound(id, CHAN_ITEM, g_SoundGrenadeBuy, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)	   

	AmmoPickup(id)

	g_JumpGrenadeCount[id] = 1
	#if defined WEAPONLIST
	WeaponList(id, 1)
	#endif
}

public zp_user_humanized_post(id, survivor)
{
	g_JumpGrenadeCount[id] = 0
	#if defined WEAPONLIST
	WeaponList(id, 0)
	#endif
}

public DeployPost(entity)
{
	static id
	id = get_pdata_cbase(entity, 41, 4)

	if(!is_user_alive(id) || !zp_get_user_zombie(id) || zp_get_user_nemesis(id) || zp_get_user_survivor(id))
		return PLUGIN_CONTINUE


	set_pev(id, pev_viewmodel2, BOMB_MODEL[0])
	set_pev(id, pev_weaponmodel2, BOMB_MODEL[1])

	return PLUGIN_CONTINUE
}

public grenade_throw(iPlayer, iGrenade, iWeapon) {

	if(iWeapon == CSW_SMOKEGRENADE) {

		if(BlotterGetBombs(iPlayer)) BlotterRemoveBomb(iPlayer);
		else if(g_JumpGrenadeCount[iPlayer] >= 1) g_JumpGrenadeCount[iPlayer]--;
		
		if(!BlotterGetBombs(iPlayer) && g_JumpGrenadeCount[iPlayer]) ExecuteHamB(Ham_Item_Deploy, get_pdata_cbase(iPlayer, 373, 5));
	
	}

}

public fw_SetModel(Entity, const Model[])
{
	if (Entity < 0)
		return FMRES_IGNORED

	if (pev(Entity, pev_dmgtime) == 0.0)
		return FMRES_IGNORED

	new iOwner = pev(Entity, pev_owner)
 
 	if(!(0 < iOwner < 33))
 		return FMRES_IGNORED
 		
	if(!zp_get_user_zombie(iOwner) || !BlotterGetBombs(iOwner) && g_JumpGrenadeCount[iOwner] <= 0)
		return FMRES_IGNORED
	
	if(equal(Model[7], "w_sm", 4)) {
		
		set_pev(Entity, pev_flTimeStepSound, JUMPBOMB_ID)
		set_pev(Entity, pev_body, 23)

		fm_set_rendering(Entity, kRenderFxGlowShell, 0, 255, 0, kRenderNormal, 16)

		#if defined TRAIL
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_BEAMFOLLOW)
		write_short(Entity) 		// entity
		write_short(g_trailSpr) 	// sprite
		write_byte(2) 			// life
		write_byte(5) 			// width
		write_byte(0) 			// r
		write_byte(200) 		// g
		write_byte(0) 			// b
		write_byte(200) 		// brightness
		message_end()
		#endif

		if(BlotterGetBombs(iOwner)) engfunc(EngFunc_SetModel, Entity, BLOTTER_BOMB_W)
		else engfunc(EngFunc_SetModel, Entity, BOMB_MODEL[2])

		return FMRES_SUPERCEDE
	
	}
	
	return FMRES_IGNORED
}

public fw_ThinkGrenade(Entity)
{
	if(!pev_valid(Entity))
		return HAM_IGNORED
	   
	static Float:dmg_time
	pev(Entity, pev_dmgtime, dmg_time)
	   
	if(dmg_time > get_gametime())
		return HAM_IGNORED
	   
	if(pev(Entity, pev_flTimeStepSound) == JUMPBOMB_ID)
	{
		JumpBombExplode(Entity)
		return HAM_SUPERCEDE
	}
	return HAM_IGNORED
}

public JumpBombExplode(Entity)
{
	if(Entity < 0)
		return
	   
	static Float:Origin[3]
	pev(Entity, pev_origin, Origin)

	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, Origin, 0)
	write_byte(TE_SPRITE)
	engfunc(EngFunc_WriteCoord, Origin[0])
	engfunc(EngFunc_WriteCoord, Origin[1])
	engfunc(EngFunc_WriteCoord, Origin[2] + 45.0)
	write_short(g_iExplo)
	write_byte(35)
	write_byte(186)
	message_end()
		   
	emit_sound(Entity, CHAN_WEAPON, g_SoundBombExplode, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
	  
	for(new victim = 1; victim <= get_maxplayers(); victim++)
	{
		if (!is_user_alive(victim))
			continue
				  
		new Float:VictimOrigin[3]
		pev(victim, pev_origin, VictimOrigin)
				   
		new Float:Distance = get_distance_f(Origin, VictimOrigin)   
				   
		if(Distance <= RADIUS)
		{
			static Float:NewSpeed

			NewSpeed = JUMP_EXP * (1.0 - (Distance / RADIUS))
						   
			static Float:Velocity[3]
			get_speed_vector(Origin, VictimOrigin, NewSpeed, Velocity)
						   
			set_pev(victim, pev_velocity, Velocity)
			
			message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("ScreenShake"), _, victim)
			write_short(1<<12 * 10)	   
			write_short(1<<12 * 10)
			write_short(1<<12 * 10)
			message_end()
		}
	}
	engfunc(EngFunc_RemoveEntity, Entity)
}	   
#if defined GRENADE_ICON
public grenade_icon(id)
{
	remove_grenade_icon(id)
		
	if(is_user_bot(id))
		return

	static igrenade, grenade_sprite[16], grenade_color[3]
	igrenade = get_user_weapon(id)
	
	switch(igrenade) 
	{
		case DEFAULT_CSW:
		{
			if(!is_user_alive(id) || zp_get_user_zombie(id)) 
			{
				grenade_sprite = "dmg_gas"
				grenade_color = {255, 165, 0} 
			}
			else
			{
				grenade_sprite = ""
				grenade_color = {0, 0, 0} 
			}
		}
		default: return
	}
	grenade_icons[id] = grenade_sprite
	
	message_begin(MSG_ONE, get_user_msgid("StatusIcon"),{0, 0, 0}, id)
	write_byte(1)
	write_string(grenade_icons[id]) 
	write_byte(grenade_color[0])
	write_byte(grenade_color[1])
	write_byte(grenade_color[2]) 
	message_end()

	return
}
#endif
public zp_round_ended() 
{
	for(new id = 1; id <= get_maxplayers(); id++) 
	{
		if(!is_user_alive(id) || !zp_get_user_zombie(id)) 
			continue

		ham_strip_weapon(id, WEAPON_DEFAULT)
		g_JumpGrenadeCount[id] = 0
	}
}

public DeathMsg()
{
	new attacker = read_data(1)
	new victim = read_data(2)

	if(!is_user_connected(attacker))
		return HAM_IGNORED

	if(victim == attacker || !victim)
		return HAM_IGNORED

	if(!zp_get_user_zombie(victim))
		return HAM_IGNORED

	#if defined GRENADE_ICON
	remove_grenade_icon(victim)
	#endif

	#if defined WEAPONLIST
	WeaponList(victim, 0)
	#endif

	g_JumpGrenadeCount[victim] = 0

		return HAM_HANDLED
}

public client_connect(id) g_JumpGrenadeCount[id] = 0

#if defined WEAPONLIST
WeaponList(index, mode = 0)
{
	if (!is_user_connected(index))
		return
	
	message_begin(MSG_ONE, get_user_msgid("WeaponList"), {0, 0, 0}, index)
	write_string(mode ? WEAPON_NEW : WEAPON_DEFAULT)
	write_byte(prim_ammoid)
	write_byte(prim_ammomaxamount)
	write_byte(sec_ammoid)
	write_byte(sec_ammomaxamount)
	write_byte(slotid)
	write_byte(number_in_slot)
	write_byte(weaponid)
	write_byte(flags)
	message_end()
}
#endif

#if defined GRENADE_ICON
static remove_grenade_icon(index) 
{
	message_begin(MSG_ONE, get_user_msgid("StatusIcon"), {0, 0, 0}, index)
	write_byte(0) 
	write_string(grenade_icons[index])
	message_end()
}
#endif

stock set_user_takedamage(index, damage)
{
	if(!is_user_alive(index))
		return

	new vec[3]
	FVecIVec(get_target_origin_f(index), vec)

	message_begin(MSG_ONE, get_user_msgid("Damage"), _, index)
	write_byte(0)
	write_byte(damage)
	write_long(DMG_CRUSH)
	write_coord(vec[0]) 
	write_coord(vec[1])
	write_coord(vec[2])
	message_end()

	if(pev(index, pev_health) - 20.0 <= 0)
		ExecuteHamB(Ham_Killed, index, index, 1)
	else ExecuteHamB(Ham_TakeDamage, index, 0, index, float(damage), DMG_BLAST)
}

stock AmmoPickup(index)
{
	message_begin(MSG_ONE, get_user_msgid("AmmoPickup"), _, index)
	write_byte(13)
	write_byte(1)
	message_end()
}

stock Float:get_target_origin_f(index)
{
	new Float:orig[3]
	pev(index, pev_origin, orig)

	if(index > get_maxplayers())
	{
		new Float:mins[3], Float:maxs[3]
		pev(index, pev_mins, mins)
		pev(index, pev_maxs, maxs)
		
		if(!mins[2]) orig[2] += maxs[2] / 2
	}
	return orig
}

stock get_speed_vector(const Float:origin1[3],const Float:origin2[3],Float:speed, Float:new_velocity[3])
{
	new_velocity[0] = origin2[0] - origin1[0]
	new_velocity[1] = origin2[1] - origin1[1]
	new_velocity[2] = origin2[2] - origin1[2]
	new Float:num = floatsqroot(speed*speed / (new_velocity[0]*new_velocity[0] + new_velocity[1]*new_velocity[1] + new_velocity[2]*new_velocity[2]))
	new_velocity[0] *= num
	new_velocity[1] *= num
	new_velocity[2] *= num

	return 1
}

stock fm_set_rendering(entity, fx = kRenderFxNone, r = 255, g = 255, b = 255, render = kRenderNormal, amount = 16) 
{
	new Float:RenderColor[3]
	RenderColor[0] = float®
	RenderColor[1] = float(g)
	RenderColor[2] = float(b)

	set_pev(entity, pev_renderfx, fx)
	set_pev(entity, pev_rendercolor, RenderColor)
	set_pev(entity, pev_rendermode, render)
	set_pev(entity, pev_renderamt, float(amount))

	return 1
}

stock fm_give_item(index, const item[])
{
	if (!equal(item, "weapon_", 7) && !equal(item, "ammo_", 5))
		return 0

	new ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, item))
	if (!pev_valid(ent))
		return 0

	new Float:origin[3]
	pev(index, pev_origin, origin)
	set_pev(ent, pev_origin, origin)
	set_pev(ent, pev_spawnflags, pev(ent, pev_spawnflags) | SF_NORESPAWN)
	dllfunc(DLLFunc_Spawn, ent)

	new save = pev(ent, pev_solid)
	dllfunc(DLLFunc_Touch, ent, index)
	if (pev(ent, pev_solid) != save)
		return ent

	engfunc(EngFunc_RemoveEntity, ent)

	return -1
}

stock ham_strip_weapon(index, weapon[])
{
	if(!equal(weapon, "weapon_", 7))
		return 0

		new wId = get_weaponid(weapon)
		if(!wId) return 0

		new wEnt
		while((wEnt = engfunc(EngFunc_FindEntityByString, wEnt, "classname", weapon)) && pev(wEnt,pev_owner) != index) {}

		if(!wEnt) 
		return 0

		if(get_user_weapon(index) == wId)
		ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt)

		if(!ExecuteHamB(Ham_RemovePlayerItem, index, wEnt))
		return 0

		ExecuteHamB(Ham_Item_Kill, wEnt)

		set_pev(index, pev_weapons, pev(index, pev_weapons) & ~(1<<wId))

		return 1
}

TheArtemMaps,
Пробуй этот вариант,также и попробуй с остальными классами - у их применяется своя / другая модель правильная ?
 zp_jump_grenade.sma ( 15,9 килобайт ) Кол-во скачиваний: 5

Да применяется щас попробую однако

Вообще ничего нету.

Зомби класс гробовщик:

Давай сюда исход класса Гробовщика - будем делать на ведьму также,как и гранату

Вот
Код:

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fakemeta_util>
#include <hamsandwich> 
#include <zombieplague> 
#include <xs> 

#define PLUGIN "Undertaker"
#define VERSION "1.0"
#define AUTHOR "DSHGFHDS"

#define SKILLMODEL "models/zombiepile.mdl"
#define SKILLNAME "zombiecoffin"
#define SKILL_COFFIN 15214
#define TASK_COOLDAWN 1234
#define TASK_SKILLUSEING 2345
#define TASK_SKILLOVER 3456
#define TASK_ENTTHINK 4567
#define TASK_SPEEDTIME 5678

new systimeend[33]
new skillcd = 8
new wait[33]

new const WEAPON_CLASSNAME[][] = { "", "weapon_p228", "", "weapon_scout", "weapon_hegrenade", "weapon_xm1014", "weapon_c4", "weapon_mac10",
	"weapon_aug", "weapon_smokegrenade", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_sg550",
	"weapon_galil", "weapon_famas", "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249",
	"weapon_m3", "weapon_m4a1", "weapon_tmp", "weapon_g3sg1", "weapon_flashbang", "weapon_deagle", "weapon_sg552",
"weapon_ak47", "weapon_knife", "weapon_p90" }

new const zclass_name[] = { "Гробовщик" }
new const zclass_info[] = { "Ставит гроб" }
new const zclass_model[] = { "zm_undertaker" }
new const zclass_clawmodel[] = { "v_zm_undertaker.mdl" }
new const zclass_hemodel[] = { "models/zombie_plague/v_he_undertaker.mdl" }
new KNOCKBOMB_STAMPER[] = "models/zombie_plague/v_he_undertaker.mdl"
new const zclass_health = 4500
new const zclass_speed = 260
new const Float:zclass_gravity = 0.8
new const Float:zclass_knockback = 1.5
new const setcoffinsound[] = "zombie_plague/zombi_stamper_iron_maiden_stamping.wav"
new const coffinexsound[] = "zombie_plague/zombi_stamper_iron_maiden_explosion.wav"
new g_zclass_undertaker, g_shokewaveSpr, humanspr, zm_zombiebomb
new skillcooldawn[33], skilluseing[33], setmaxspeed[33], sprremove[33], knifehit[33], removesdamage[33], removeknock[33]
new cvar_skillcooldawntime, cvar_skillhealth, cvar_coffintime, cvar_exrange, cvar_exknock, cvar_speedtime, cvar_maxspeed, cvar_bot_use_skill, cvar_exdamage, cvar_exhit
enum 
{
anim_idle,
anim_slash1,
anim_skill,
anim_daw,
anim_stab,
anim_stab_miss,
anim_midslash1,
anim_midslash2,
}
const DMG_HEGRENADE = (1<<24)
public plugin_init() 
{
        register_forward(FM_EmitSound, "fw_EmitSound")
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_clcmd("drop","skilluse")
	register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")
	register_event("CurWeapon", "Event_CurrentWeapon", "be", "1=1")
	RegisterHam(Ham_Killed, "player", "player_death",1)
	for (new i = 0; i < sizeof WEAPON_CLASSNAME; i++)
	{
	if (strlen(WEAPON_CLASSNAME[i]) <= 0)
	continue; 
	RegisterHam(Ham_Item_Deploy, WEAPON_CLASSNAME[i], "fwItemDeploy_Post", 1)
	}
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "fw_Weapon_SecondaryAttack")
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "fw_Weapon_SecondaryAttack_Post", 1)
	RegisterHam(Ham_TakeDamage, "info_target", "fw_TakeDamage")
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamageplayer")
	RegisterHam(Ham_TraceAttack, "info_target", "fw_TraceAttack")
	RegisterHam(Ham_TraceAttack, "player", "fw_TraceAttackplayer")
	register_forward(FM_CmdStart, "forward_CmdStart", 1)
	register_forward(FM_PlayerPreThink, "fw_PlayerPreThink")
	register_forward(FM_PlayerPostThink, "fw_PlayerPostThink" , 1)
	register_forward(FM_UpdateClientData, "UpdateClientData_Post", 1) 
	cvar_skillcooldawntime = register_cvar("zp_undertaker_cooldawn","8.0") //отсчет до способности(через сколько восстановиться) 
	cvar_skillhealth = register_cvar("zp_undertaker_skillhealth","800") // Жизнь гроба 
	cvar_coffintime = register_cvar("zp_undertaker_coffintime","10.0") //Время одурманивания  
	cvar_exrange = register_cvar("zp_undertaker_coffinexrange","150") // Iron Maiden взрыв отталкиваются 
	cvar_exknock = register_cvar("zp_undertaker_coffinexknock","1000") // сила отброса от гроба 
	cvar_speedtime = register_cvar("zp_undertaker_speedtime","5.0") // скорость отброса 
	cvar_maxspeed = register_cvar("zp_undertaker_maxspeed","0.5") //   скорость ходьбы пострадавших при
	cvar_exdamage = register_cvar("zp_undertaker_exdamage","0.35") // наносимый крон 
	cvar_bot_use_skill = register_cvar("zp_undertaker_bot_use_skill", "150") // скил для использования ботом 
	cvar_exhit = register_cvar("zp_undertaker_hit_ex", "5") // Максимальное количество нападений на Iron Maiden тяжелым ножом
}

public plugin_precache()
{
	g_zclass_undertaker = zp_register_zombie_class(zclass_name, zclass_info, zclass_model, zclass_clawmodel, zclass_health, zclass_speed, zclass_gravity, zclass_knockback)
	engfunc(EngFunc_PrecacheModel,zclass_hemodel)
	engfunc(EngFunc_PrecacheModel,SKILLMODEL)
	precache_model(KNOCKBOMB_STAMPER)
	g_shokewaveSpr = engfunc(EngFunc_PrecacheModel,"sprites/shockwave.spr")
	humanspr = engfunc(EngFunc_PrecacheModel,"sprites/un_trap.spr")
	zm_zombiebomb = engfunc(EngFunc_PrecacheModel,"sprites/zombiebomb.spr")
	engfunc(EngFunc_PrecacheSound,setcoffinsound)
	engfunc(EngFunc_PrecacheSound,coffinexsound)
        precache_sound("zombie_plague/zombi_hurt_stamper_1.wav") 
        precache_sound("zombie_plague/zombi_hurt_stamper_2.wav") 
        precache_sound("zombie_plague/knife_slash1.wav") 
        precache_sound("zombie_plague/knife_hitwall1.wav") 
        precache_sound("zombie_plague/knife_hit1.wav") 
        precache_sound("zombie_plague/knife_hit3.wav") 
        precache_sound("zombie_plague/zombi_death_stamper_1.wav") 
        precache_sound("zombie_plague/zombi_hurt_stamper_1.wav") 
}

public fw_Weapon_SecondaryAttack(iEntity)
{
	new owner = pev(iEntity, pev_owner)
	knifehit[owner] = true
}

public fw_Weapon_SecondaryAttack_Post(iEntity)
{
	new owner = pev(iEntity, pev_owner)
	knifehit[owner] = false
}
public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
	if(!is_user_connected(attacker))
	return HAM_IGNORED;
	
	if(damage_type & DMG_HEGRENADE)
	return HAM_IGNORED
	
	if(pev(victim, pev_iuser4) == SKILL_COFFIN)
	{
	if(get_user_weapon(attacker) == CSW_KNIFE && knifehit[attacker])
	{
	set_pev(victim, pev_iuser3, pev(victim, pev_iuser3)-1)
	return HAM_SUPERCEDE
	}
	removesdamage[attacker] = true
	}
	
	return HAM_IGNORED
}

public fw_TakeDamageplayer(victim, inflictor, attacker, Float:damage, damage_type)
{
	if(!is_user_connected(attacker))
	return HAM_IGNORED;
	
	if(damage_type & DMG_HEGRENADE)
	return HAM_IGNORED
	
	if(removesdamage[attacker])
	{
	removesdamage[attacker] = false
	return HAM_SUPERCEDE
	}
	
	return HAM_IGNORED
}

public fw_TraceAttack(victim, attacker, Float:damage, Float:dir[3], ptr, damagetype)
{
	if(!is_user_alive(attacker) || !is_user_connected(attacker))
	return HAM_IGNORED
	
	new iVictim = get_tr2(ptr, TR_pHit)

	if(pev(iVictim, pev_iuser4) == SKILL_COFFIN && get_user_weapon(attacker) != CSW_KNIFE)
	{
	removeknock[attacker] = true
	new Float:fHitOrigin[3]
	get_tr2(ptr, TR_vecEndPos, fHitOrigin)
	
	engfunc(EngFunc_MessageBegin,MSG_PVS, SVC_TEMPENTITY, fHitOrigin, 0)
	write_byte(TE_GUNSHOTDECAL)
	engfunc(EngFunc_WriteCoord,fHitOrigin[0])
	engfunc(EngFunc_WriteCoord,fHitOrigin[1])
	engfunc(EngFunc_WriteCoord,fHitOrigin[2])
	write_short(0)
	write_byte(45)
	message_end()
		
	engfunc(EngFunc_MessageBegin,MSG_PVS, SVC_TEMPENTITY, fHitOrigin, 0)
	write_byte(TE_SPARKS)
	engfunc(EngFunc_WriteCoord,fHitOrigin[0])
	engfunc(EngFunc_WriteCoord,fHitOrigin[1])
	engfunc(EngFunc_WriteCoord,fHitOrigin[2])
	message_end()
	}
	
	return HAM_IGNORED
}

public fw_TraceAttackplayer(victim, attacker, Float:damage, Float:dir[3], ptr, damagetype)
{
	if(!is_user_alive(attacker) || !is_user_connected(attacker))
	return HAM_IGNORED
	
	if(removeknock[attacker])
	{
	removeknock[attacker] = false
	return HAM_SUPERCEDE
	}
	
	return HAM_IGNORED
}

public fw_PlayerPreThink(id)
{
	if(!is_user_alive(id))
	return PLUGIN_HANDLED

	if(setmaxspeed[id]) set_speed_to_velocity(id, get_pcvar_float(cvar_maxspeed))//set_pev(id, pev_maxspeed, (pev(id, pev_maxspeed)*get_pcvar_float(cvar_maxspeed)))
	
	return PLUGIN_CONTINUE
}

public fw_PlayerPostThink(id)
{
	if(!is_user_alive(id) || !is_user_bot(id))
	return PLUGIN_HANDLED
	
	new enemy, body
	get_user_aiming(id, enemy, body)
	if ((1 <= enemy <= 32) && !zp_get_user_zombie(enemy))
	{
		new origin1[3] ,origin2[3],range
		get_user_origin(id,origin1)
		get_user_origin(enemy,origin2)
		range = get_distance(origin1, origin2)
		if(range <= get_pcvar_num(cvar_bot_use_skill)) skilluse(id)
	}
	return PLUGIN_CONTINUE
}

public UpdateClientData_Post(id, sendweapons, cd_handle) 
{ 
	if(!is_user_alive(id)) 
	return PLUGIN_HANDLED
	
	if(skilluseing[id] || sprremove[id])
	{
	set_cd(cd_handle, CD_ID, 0)
	sprremove[id] = false
	}
	
	return PLUGIN_CONTINUE
}
		
public forward_CmdStart(id, uc_handle, seed)
{
	if(!is_user_alive(id))
	return PLUGIN_HANDLED
	static button
	button = get_uc(uc_handle, UC_Buttons)
	
	if(skilluseing[id] && (button & IN_ATTACK))
	{
	button &= ~IN_ATTACK
	set_uc(uc_handle, UC_Buttons, button)
	}
	
	return PLUGIN_CONTINUE
}
	
public Event_CurWeapon(id) if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id) && get_user_weapon(id) == CSW_HEGRENADE) set_pev(id, pev_viewmodel2, zclass_hemodel)

public zp_user_infected_post(id, infector) 
{
	alloff(id)
	setmaxspeed[id] = false
	remove_task(id)
	remove_task(id+TASK_SPEEDTIME)
}

public zp_user_humanized_post(id)
{
	alloff(id)
	setmaxspeed[id] = false
	remove_task(id)
	remove_task(id+TASK_SPEEDTIME)
}

/* public makecoffin(id)
{
	if(is_user_alive(id) && zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id))
	{
		systimeend[id] = get_systime()+skillcd;
		skilluse(id)
	}
	if (!skilluseing[id] && zp_get_user_zombie_class(id) == g_zclass_undertaker)
	{
		wait[id] = systimeend[id]-get_systime();
		client_print(id,print_center,"Откат навыка через %d сек.",wait[id]);
		return PLUGIN_HANDLED
	}
	
	return PLUGIN_CONTINUE
} */

public skilluse(id)
{
	
	if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id) && !skillcooldawn[id] && !skilluseing[id] && get_user_weapon(id) == CSW_KNIFE)
	{
	if(pev(id, pev_flags) & FL_ONGROUND)
	{
	native_playanim(id,anim_skill)
	set_task(0.4, "settheent", id+TASK_SKILLUSEING)
	set_task(1.1, "skillover", id+TASK_SKILLOVER)
	systimeend[id] = get_systime()+skillcd;
	skilluseing[id] = true
	client_print(id,print_center," Вы использовали скилл")
	}
	else client_print(id,print_center," Нельзя использовать скилл!")
	}
	if (!skilluseing[id] && zp_get_user_zombie_class(id) == g_zclass_undertaker && is_user_alive(id) && zp_get_user_zombie(id))
	{
		wait[id] = systimeend[id]-get_systime();
		client_print(id,print_center,"Откат навыка через %d сек.",wait[id]);
		return PLUGIN_HANDLED
	}
}

public skillover(taskid)
{	
	new id = taskid - TASK_SKILLOVER
	native_playanim(id,anim_idle)
	skilluseing[id] = false
	remove_task(id+TASK_SKILLOVER)
	
	if(!zp_get_user_zombie(id) || zp_get_user_zombie_class(id) != g_zclass_undertaker || zp_get_user_nemesis(id))
	return
}

public skillcooldawnover(taskid)
{

	new id = taskid - TASK_COOLDAWN
	skillcooldawn[id] = false
	client_print(id,print_center,"Скилл перезаряжен")
	remove_task(id+TASK_COOLDAWN)
	
	if(!zp_get_user_zombie(id) || zp_get_user_zombie_class(id) != g_zclass_undertaker || zp_get_user_nemesis(id))
	return
}

public settheent(taskid)
{
	new id = taskid - TASK_SKILLUSEING
	remove_task(id+TASK_SKILLUSEING)
	
	if(!zp_get_user_zombie(id) || zp_get_user_zombie_class(id) != g_zclass_undertaker || zp_get_user_nemesis(id))
	return
	
	skillcooldawn[id] = true
	set_task(get_pcvar_float(cvar_skillcooldawntime), "skillcooldawnover", id+TASK_COOLDAWN)
	new Float:origin[3], Float:fAngle[3], Float:fAngle2[3], Float:vec[3]
	pev(id,pev_origin,origin)
	get_origin_distance(id, vec, 40.0) 
	vec[2] += 25.0
	pev(id,pev_angles,fAngle)
	new ent = fm_create_entity("info_target")
	if(!pev_valid(ent)) 
	return
	pev(ent,pev_angles,fAngle2)
	fAngle[0] = fAngle2[0]
	set_pev(ent, pev_classname, SKILLNAME)
	set_pev(ent, pev_iuser4, SKILL_COFFIN)
	set_pev(ent, pev_iuser3, get_pcvar_num(cvar_exhit))
	engfunc(EngFunc_SetModel,ent,SKILLMODEL)
	engfunc(EngFunc_SetSize, ent, {-14.0, -10.0, -36.0}, {14.0, 10.0, 36.0})
	set_pev(ent, pev_mins, {-14.0, -10.0, -36.0});
	set_pev(ent, pev_maxs, {14.0, 10.0, 36.0});
	set_pev(ent, pev_absmin, {-14.0, -10.0, -36.0})
	set_pev(ent, pev_absmax, {-14.0, -10.0, -36.0})
	set_pev(ent, pev_health, float(get_pcvar_num(cvar_skillhealth))+1000.0)
	set_pev(ent, pev_gravity, 2.0)
	set_pev(ent, pev_solid,SOLID_BBOX)
	set_pev(ent, pev_movetype,MOVETYPE_TOSS)
	set_pev(ent, pev_takedamage, DAMAGE_YES)
	set_pev(ent,pev_angles,fAngle)
	engfunc(EngFunc_SetOrigin,ent, vec)
	engfunc(EngFunc_DropToFloor, ent) 
	engfunc(EngFunc_EmitSound, ent, CHAN_AUTO, setcoffinsound, 1.0, ATTN_NORM, 0, PITCH_NORM)
	set_task(get_pcvar_float(cvar_coffintime), "removecoffin", ent, _, _, "b")
	set_task(0.1, "coffinthink", ent+TASK_ENTTHINK, _, _, "b")
	new Float:iorigin[3], Float:entorigin[3]
	pev(ent, pev_origin, entorigin)
	for(new i=1;i<33;i++)
	{
	pev(i, pev_origin, iorigin)
	new Float:range = get_distance_f(entorigin, iorigin)
	if(range <= float(get_pcvar_num(cvar_exrange)) && is_user_alive(i) && !zp_get_user_zombie(i) && !setmaxspeed[id])
	{
	setmaxspeed[i] = true
	makespr(i)
	set_task(get_pcvar_float(cvar_speedtime), "overspeedtime", i+TASK_SPEEDTIME)
	}
	}
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, entorigin, 0)
	write_byte(TE_BEAMCYLINDER)
	engfunc(EngFunc_WriteCoord, entorigin[0])
	engfunc(EngFunc_WriteCoord, entorigin[1])
	engfunc(EngFunc_WriteCoord, entorigin[2]-10)
	engfunc(EngFunc_WriteCoord, entorigin[0]-150)
	engfunc(EngFunc_WriteCoord, entorigin[1])
	engfunc(EngFunc_WriteCoord, entorigin[2]+300)
	write_short(g_shokewaveSpr)
	write_byte(0)
	write_byte(0)
	write_byte(2)
	write_byte(20)
	write_byte(0)
	write_byte(255)
	write_byte(255)
	write_byte(255)
	write_byte(100)
	write_byte(2)
	message_end()
	gettheent(ent)
}

public gettheent(ent)
{
	if(!pev_valid(ent)) 
	return
	
	if(!is_player_stuck(ent) || pev(ent, pev_movetype) == MOVETYPE_NOCLIP || pev(ent,pev_solid) == SOLID_NOT)
	return
	
	removecoffin(ent)
}

public makespr(id)
{
	if(zp_get_user_zombie(id) || !is_user_alive(id))
	return
	
	new Float:hm_origin[3]
	pev(id, pev_origin, hm_origin)
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, hm_origin, 0)
	write_byte(TE_SPRITE)
	engfunc(EngFunc_WriteCoord,hm_origin[0])
	engfunc(EngFunc_WriteCoord,hm_origin[1])
	engfunc(EngFunc_WriteCoord,hm_origin[2]+10.0)
	write_short(humanspr)
	write_byte(8)
	write_byte(255)
	message_end()
	
	set_task(0.1,"makespr",id)
	client_print(id, print_center, "Вас замедляет гроб!")
}

public overspeedtime(taskid)
{
	new id = taskid - TASK_SPEEDTIME
	setmaxspeed[id] = false
	remove_task(id)
	remove_task(id+TASK_SPEEDTIME)
	client_print(id, print_center, "Вас больше не замедляет гроб!")
}

public coffinthink(taskent)
{
	new ent = taskent - TASK_ENTTHINK
	if(!pev_valid(ent)) 
	return
	
	if(pev(ent, pev_health) <= 1000.0 || pev(ent, pev_iuser3) <= 0) removecoffin(ent)
}

public removecoffin(ent)
{
	new Float:iorigin[3], Float:entorigin[3], maxdamage, health
	pev(ent, pev_origin, entorigin)
	for(new i=1;i<33;i++)
	{
	pev(i, pev_origin, iorigin)
	new Float:range = get_distance_f(entorigin, iorigin)
	if(range <= float(get_pcvar_num(cvar_exrange)) && is_user_alive(i))
	{
	health = pev(i, pev_health)
	maxdamage = floatround(health*get_pcvar_float(cvar_exdamage))
	if(health > maxdamage)
	fm_fakedamage(i, "coffindamge", float(maxdamage), DMG_BLAST)
	set_velocity_from_origin(i, entorigin, float(get_pcvar_num(cvar_exknock)))
	if(!setmaxspeed[i] && !zp_get_user_zombie(i))
	{
	setmaxspeed[i] = true
	makespr(i)
	set_task(get_pcvar_float(cvar_speedtime), "overspeedtime", i+TASK_SPEEDTIME)
	}
	}
	}
	engfunc(EngFunc_EmitSound, ent, CHAN_AUTO, coffinexsound, 1.0, ATTN_NORM, 0, PITCH_NORM)
	engfunc(EngFunc_MessageBegin, MSG_ALL, SVC_TEMPENTITY, entorigin, 0)
	write_byte(TE_SPRITE)
	engfunc(EngFunc_WriteCoord, entorigin[0])
	engfunc(EngFunc_WriteCoord, entorigin[1])
	engfunc(EngFunc_WriteCoord, entorigin[2]+38.0)
	write_short(zm_zombiebomb)
	write_byte(20)
	write_byte(255)
	message_end()

	remove_task(ent)
	remove_task(ent+TASK_ENTTHINK)
	engfunc(EngFunc_RemoveEntity, ent)
}

public alloff(id)
{
	skillcooldawn[id] = false
	skilluseing[id] = false
	remove_task(id+TASK_SKILLUSEING)
	remove_task(id+TASK_COOLDAWN)
	remove_task(id+TASK_SKILLOVER)
}

public fwItemDeploy_Post(ent)
{
	new id = get_pdata_cbase(ent, 41, 4)
	if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id))
	{
	remove_task(id+TASK_SKILLUSEING)
	remove_task(id+TASK_SKILLOVER)
	skilluseing[id] = false
	}
}

public player_death(id) 
{
	if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id))
	{
	alloff(id)
	setmaxspeed[id] = false
	remove_task(id)
	remove_task(id+TASK_SPEEDTIME)
	}
}

new Debug
public client_putinserver(id)
{
	if(Debug == 1)return
	new classname[32]
	pev(id,pev_classname,classname,31)
	if(!equal(classname,"player"))
	{
		Debug=1
		set_task(1.0,"_Debug",id)
	}
}

public _Debug(id)
{
	RegisterHamFromEntity(Ham_TakeDamage, id, "fw_TakeDamageplayer")
	RegisterHamFromEntity(Ham_Killed,id,"player_death", 1)
	RegisterHamFromEntity(Ham_TraceAttack, id, "fw_TraceAttackplayer")
}

stock native_playanim(player,anim)
{
	set_pev(player, pev_weaponanim, anim)
	message_begin(MSG_ONE, SVC_WEAPONANIM, {0, 0, 0}, player)
	write_byte(anim)
	write_byte(pev(player, pev_body))
	message_end()
}

stock get_origin_distance( index, Float:origin[3], Float:dist ) 
{
	new Float:start[ 3 ];
	new Float:view_ofs[ 3 ];
	
	pev( index, pev_origin, start );
	pev( index, pev_view_ofs, view_ofs );
	xs_vec_add( start, view_ofs, start );
	
	new Float:dest[3];
	pev(index, pev_angles, dest );
	
	engfunc( EngFunc_MakeVectors, dest );
	global_get( glb_v_forward, dest );
	
	xs_vec_mul_scalar( dest, dist, dest );
	xs_vec_add( start, dest, dest );
	
	engfunc( EngFunc_TraceLine, start, dest, 0, index, 0 );
	get_tr2( 0, TR_vecEndPos, origin );
	
	return 1;
} 

stock set_velocity_from_origin( ent, Float:fOrigin[3], Float:fSpeed )
{
	new Float:fVelocity[3]
	
	get_velocity_from_origin( ent, fOrigin, fSpeed, fVelocity )
	set_pev( ent, pev_velocity, fVelocity )
	
	return 1
} 

stock get_velocity_from_origin( ent, Float:fOrigin[3], Float:fSpeed, Float:fVelocity[3] )
{
	new Float:fEntOrigin[3];
	pev( ent, pev_origin, fEntOrigin );
	
	new Float:fDistance[3];
	fDistance[0] = fEntOrigin[0] - fOrigin[0]
	fDistance[1] = fEntOrigin[1] - fOrigin[1]
	fDistance[2] = fEntOrigin[2] - fOrigin[2]
	
	new Float:fTime = ( vector_distance( fEntOrigin,fOrigin ) / fSpeed )
	
	fVelocity[0] = fDistance[0] / fTime
	fVelocity[1] = fDistance[1] / fTime
	fVelocity[2] = fDistance[2] / fTime
	
	return ( fVelocity[0] && fVelocity[1] && fVelocity[2] )
}

stock is_player_stuck(id)
{
	static Float:originF[3]
	pev(id, pev_origin, originF)
	
	engfunc(EngFunc_TraceHull, originF, originF, 0, (pev(id, pev_flags) & FL_DUCKING) ? HULL_HEAD : HULL_HUMAN, id, 0)
	
	if (get_tr2(0, TR_StartSolid) || get_tr2(0, TR_AllSolid) || !get_tr2(0, TR_InOpen))
	return true
	
	return false
}

stock set_speed_to_velocity(id, Float:scalar = 1.0)
{
	new Float:velocity[3]
	pev(id, pev_velocity, velocity)
	xs_vec_mul_scalar(velocity, scalar, velocity)
	velocity[2] = velocity[2]/scalar
	set_pev(id, pev_velocity, velocity)
	
	return 1
}

// Emit Sound Forward
public fw_EmitSound(id, channel, const sample[], Float:volume, Float:attn, flags, pitch) 
{
     // 内容限定只对僵尸作用
     if (!is_user_connected(id) || !zp_get_user_zombie(id) || zp_get_user_zombie_class(id) != g_zclass_undertaker)
           return FMRES_IGNORED;
     
     // 僵尸被攻击的叫声
     if (equal(sample[7], "bhit", 4))
     {
           if (zp_get_user_nemesis(id)) 
                 engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/zombi_hurt_stamper_1.wav", volume, attn, flags, pitch)
           else 
                 engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/zombi_hurt_stamper_2.wav", volume, attn, flags, pitch)
           return FMRES_SUPERCEDE;
     }
     
     // 僵尸用爪子攻击的声音
     if (equal(sample[8], "kni", 3))
     {
           if (equal(sample[14], "sla", 3)) // 爪子空挥的音效
           { 
                 engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/knife_slash1.wav", volume, attn, flags, pitch)
                 return FMRES_SUPERCEDE;
           }
           if (equal(sample[14], "hit", 3)) // 爪子命中物体的音效
           {
                 if (sample[17] == 'w') // 爪子命中的是墙壁
                 {
                       engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/knife_hitwall1.wav", volume, attn, flags, pitch) 
                       return FMRES_SUPERCEDE;
                 }
                 else // 爪子命中的是人物
                 { 
                       engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/knife_hit1.wav", volume, attn, flags, pitch) 
                       return FMRES_SUPERCEDE;
                 }
           }
           if (equal(sample[14], "sta", 3)) // 爪子重砍命中人物
           {
                 engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/knife_hit3.wav", volume, attn, flags, pitch)
                 return FMRES_SUPERCEDE; 
           }
     }
     
     // 僵尸死亡的声音
     if (equal(sample[7], "die", 3) || equal(sample[7], "dea", 3))
     {
           engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/zombi_death_stamper_1.wav", volume, attn, flags, pitch)
           return FMRES_SUPERCEDE;
     }
     
     // 僵尸摔伤的声音
     if (equal(sample[10], "fall", 4))
     {
           engfunc(EngFunc_EmitSound, id, channel, "zombie_plague/zombi_hurt_stamper_1.wav", volume, attn, flags, pitch)
           return FMRES_SUPERCEDE;
     }
     
     return FMRES_IGNORED;
}
public Event_CurrentWeapon(id)
{
	new weaponID = read_data(2)

	if(weaponID == CSW_SMOKEGRENADE) 
	{
	if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id)) 
		{
		entity_set_string(id, EV_SZ_viewmodel, KNOCKBOMB_STAMPER)
		}
	}

	if (weaponID == CSW_FLASHBANG) {
	if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id))
		{
		entity_set_string(id, EV_SZ_viewmodel, KNOCKBOMB_STAMPER)
		}
	}
}

TheArtemMaps,
Сделал
И не забудь свой джамповый плагин оригинал заменить вместо того,что я скидывал,а то опять будем салат розгребать
Пути к моделям вроде правильные поставил,ну ты там пересмотри уже на всякий случай,где там у тебя модели лежат

 xman2030_witch.sma ( 12,72 килобайт ) Кол-во скачиваний: 6

Оо, спасибо всё работает)

$@NyA,
И ещё.
Какие коды ты брал из гробовщика? Просто тоже хотел бы попробовать заменит ьмодель.

В любое пустое место добавить ( и здесь же укажешь свой другой путь к модели )
Код:

new const zclass_hemodel[] = { "models/zombie_plague/v_he_undertaker.mdl" }
new KNOCKBOMB_STAMPER[] = "models/zombie_plague/v_he_undertaker.mdl"

в public plugin_init() добавить
Код:

register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")
register_event("CurWeapon", "Event_CurrentWeapon", "be", "1=1")

в public plugin_precache() добавить
Код:

engfunc(EngFunc_PrecacheModel,zclass_hemodel)
precache_model(KNOCKBOMB_STAMPER)

В любое пустое место добавить
Код:

public Event_CurWeapon(id) if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id) && get_user_weapon(id) == CSW_HEGRENADE) set_pev(id, pev_viewmodel2, zclass_hemodel)

public Event_CurrentWeapon(id)
{
   new weaponID = read_data(2)
 
   if(weaponID == CSW_SMOKEGRENADE) 
   {
   if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id)) 
      {
      entity_set_string(id, EV_SZ_viewmodel, KNOCKBOMB_STAMPER)
      }
   }
 
   if (weaponID == CSW_FLASHBANG) {
   if(zp_get_user_zombie(id) && zp_get_user_zombie_class(id) == g_zclass_undertaker && !zp_get_user_nemesis(id))
      {
      entity_set_string(id, EV_SZ_viewmodel, KNOCKBOMB_STAMPER)
      }
   }
}

И там где g_zclass_undertaker это сам класс и у каждого класса зомби он разный
К примеру у Ведьмы он idclass_banchee - тоесть zp_get_user_zombie_class(id) == idclass_banchee

Думаю поймёшь

P.S.
Я сначала делал более хорошим способом,но вижу что "Новый Автор" дорабатывал ту ещё инвалидную коляску в плагине...
Поэтому,так как это за Бесплатно и для тебя главное,что-бы работало - не хотел особо опять заморачиватся и сделал "почти" копипаст