voteban от Alka (Процентный вотебан - довёл до ума Safety1st)

/*
*    Vote Ban 2
*      Every player are able to vote for ban somebody.
*
*    Last update:
*      11/02/2012
*
*/

#include <amxmodx>

#define PLUGIN "Vote Ban 2"
#define VERSION "0.97beta"
#define AUTHOR "Safety1st/Alka"

// customizable parameters
#define MAX_PLAYERS 32
#define IMMUNITY_FLAG ( ADMIN_IMMUNITY | ADMIN_BAN )    /* flags 'a' & 'd', separate by '|' */
new gszPrefix[] = "[VOTEBAN]"    // set prefix for all chat messages; for example ">"
// end of customizable parameters

new giVotedPlayers[MAX_PLAYERS]    // player's voteban targets
new giVotes[MAX_PLAYERS]    // count of votes for ban that player
new giVoted[MAX_PLAYERS]    // count of votes for ban by that player

// macro; %1 - variable being modified, %2 - player id
#define CheckFlag(%1,%2)    ( %1 &   ( 1 << (%2-1) ) )
#define AddFlag(%1,%2)        ( %1 |=  ( 1 << (%2-1) ) )
#define RemoveFlag(%1,%2)    ( %1 &= ~( 1 << (%2-1) ) )

enum _:Labels {
    CVAR_PERCENT = 0,
    CVAR_BANTYPE,
    CVAR_BANTIME,
    CVAR_LIMIT,
    CVAR_REASON,
}
new pCvar[Labels]

enum _:Types {
    AUTO = 0,
    STEAMID,
    IP,
    AMXBAN,
    AMXBANS5,
    SUPERBAN
}

enum _:LogRecords {
    UNVOTE = 0,
    VOTE
}

new gszLogRecords[LogRecords][] = {
    "Player '%s' has canceled vote for banning '%s'",
    "Player '%s' has been voted for banning by '%s'"
}

public plugin_init() {
    register_plugin( PLUGIN, VERSION, AUTHOR )
    register_dictionary( "voteban.txt" )
    register_cvar( "voteban2", VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED )

    register_saycmd( "voteban", "VoteBanMenu" )

    pCvar[CVAR_PERCENT] = register_cvar( "voteban_percent", "60" )
    pCvar[CVAR_BANTYPE] = register_cvar( "voteban_type", "0" )
    pCvar[CVAR_BANTIME] = register_cvar( "voteban_time", "20" )
    pCvar[CVAR_LIMIT] = register_cvar( "voteban_limit", "3" )
    pCvar[CVAR_REASON] = register_cvar( "voteban_reason", " 3a6aHeH /voteban'om Ha %time% MuH.! Pa36aH TyT: http://example.ru" )
}

register_saycmd( saycommand[], function[] ) {
    new szTemp[64]
    formatex( szTemp, charsmax(szTemp) - 1, "say %s", saycommand )
    register_clcmd( szTemp, function )
    formatex( szTemp, charsmax(szTemp) - 1, "say_team %s", saycommand )
    register_clcmd( szTemp, function )
    formatex( szTemp, charsmax(szTemp) - 1, "say /%s", saycommand )
    register_clcmd( szTemp, function )
    formatex( szTemp, charsmax(szTemp) - 1, "say .%s", saycommand )
    register_clcmd( szTemp, function )
    formatex( szTemp, charsmax(szTemp) - 1, "say_team /%s", saycommand )
    register_clcmd( szTemp, function )
    formatex( szTemp, charsmax(szTemp) - 1, "say_team .%s", saycommand )
    register_clcmd( szTemp, function )
}

public client_disconnect(id) {
    static iPlayers[32], iPlayersNum, i, iPlayer

    // check whether there were votes for ban by that player
    if ( giVoted[id] ) {
        get_players( iPlayers, iPlayersNum, "ch" )    // skip bots and HLTV
        for ( i = 0; i < iPlayersNum; i++ ) {
            iPlayer = iPlayers[i]
            if ( CheckFlag( giVotedPlayers[id], iPlayer ) )
                giVotes[iPlayer]--
        }
        giVotedPlayers[id] = 0
        giVoted[id] = 0
    }

    // check whether there were votes for ban that player
    if ( giVotes[id] ) {
        get_players( iPlayers, iPlayersNum, "ch" )    // skip bots and HLTV
        for ( i = 0; i < iPlayersNum; i++ ) {
            iPlayer = iPlayers[i]
            if ( CheckFlag( giVotedPlayers[iPlayer], id ) ) {
                RemoveFlag( giVotedPlayers[iPlayer], id )
                giVotes[id]--
                giVoted[iPlayer]--
            }
            if ( !giVotes[id] )
                break
        }
        giVotes[id] = 0    // just in case
    }
}

public VoteBanMenu(id) {
    static iPlayers[32], iPlayersNum, i, iPlayer

    get_players( iPlayers, iPlayersNum, "ch" )    // skip bots and HLTV
    if ( iPlayersNum < 3 ) {
        ColorPrint( id, "^4%s %L", gszPrefix, id, "VOTEBAN_NEED3" )
        return PLUGIN_HANDLED
    }

    // create and show menu
    new szTempString[64], szName[32], szInfo[3]
    formatex( szTempString, charsmax(szTempString) - 1, "%L\y:", id, "VOTEBAN_MENU" )
    new iMenu = menu_create( szTempString, "MenuHandle", .ml = 1 )
    new iCallback = menu_makecallback( "CallbackMenu" )
    menu_setprop( iMenu, MPROP_NUMBER_COLOR, "\r" )
    menu_setprop( iMenu, MPROP_EXIT, MEXIT_ALL )
    formatex( szTempString, charsmax(szTempString) - 1, "%L", id, "VOTEBAN_EXIT" )
    menu_setprop( iMenu, MPROP_EXITNAME, szTempString )
    formatex( szTempString, charsmax(szTempString) - 1, "%L", id, "VOTEBAN_NEXT" )
    menu_setprop( iMenu, MPROP_NEXTNAME, szTempString )
    formatex( szTempString, charsmax(szTempString) - 1, "%L", id, "VOTEBAN_BACK" )
    menu_setprop( iMenu, MPROP_BACKNAME, szTempString )

    for ( i = 0; i < iPlayersNum; i++ ) {
        iPlayer = iPlayers[i]
        get_user_name( iPlayer, szName, 31 )
        num_to_str( iPlayer, szInfo, charsmax(szInfo) )
        if ( get_user_flags(iPlayer) & IMMUNITY_FLAG ) {
            formatex( szTempString, charsmax(szTempString) - 1, "%s", szName )
            // don't set info[] if player has immunity
            menu_additem( iMenu, szTempString, "", .callback = iCallback )
        }
        else {
            new iPercent = get_percent( giVotes[iPlayer], iPlayersNum )
            if ( giVotes[iPlayer] && CheckFlag( giVotedPlayers[id], iPlayer ) )
                formatex( szTempString, charsmax(szTempString) - 1, "%s \d(\r%d%%\d) \y%L", szName, iPercent, id, "VOTEBAN_VOTED" )
            else
                formatex( szTempString, charsmax(szTempString) - 1, "%s \d(\r%d%%\d)", szName, iPercent )
            num_to_str( iPlayer, szInfo, charsmax(szInfo) )
            menu_additem( iMenu, szTempString, szInfo, .callback = iCallback )
        }
    }

    menu_display( id, iMenu )

    return PLUGIN_CONTINUE
}

public CallbackMenu( id, menu, item ) {
    new access, info[3], callback, szTempString[64]
    menu_item_getinfo( menu, item, access, info, charsmax(info) - 1, szTempString, charsmax(szTempString) - 1, callback )

    if ( info[0] == 0 )
        // player has immunity
        return ITEM_DISABLED

    new iPlayer = str_to_num(info)
    if ( iPlayer == id )
        return ITEM_DISABLED

    return ITEM_ENABLED
}

public MenuHandle( id, menu, item ) {
    if ( item == MENU_EXIT ) {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }

    new access, info[3], callback
    menu_item_getinfo( menu, item, access, info, charsmax(info) - 1, .callback = callback )
    menu_destroy(menu)

    new iTarget = str_to_num(info)

    if ( !is_user_connected(iTarget) ) {
        VoteBanMenu(id)
        return PLUGIN_HANDLED
    }

    if ( CheckFlag( giVotedPlayers[id], iTarget ) ) {
        RemoveFlag( giVotedPlayers[id], iTarget )
        giVoted[id]--
        giVotes[iTarget]--

        new szName[32], szTargetName[32]
        get_user_name( id, szName, 31 )
        get_user_name( iTarget, szTargetName, 31 )
        MsgToLog( gszLogRecords[UNVOTE], szName, szTargetName )
        ColorPrint( 0, "^4%s %L", gszPrefix, LANG_SERVER, "VOTEBAN_UNVOTE", szName, szTargetName )
        client_print( id, print_center, "%L", id, "VOTEBAN_CLEAR" )
        return PLUGIN_HANDLED
    }

    new iLimit = get_pcvar_num( pCvar[CVAR_LIMIT] )
    if ( giVoted[id] >= iLimit ) {
        // don't let vote too much;)
        client_print( id, print_center, "%L", id, "VOTEBAN_LIMIT", iLimit )
        return PLUGIN_HANDLED
    }

    client_print( id, print_center, "%L", id, "VOTEBAN_SET" )
    giVoted[id]++
    giVotes[iTarget]++
    AddFlag( giVotedPlayers[id], iTarget )

    CheckVotes( iTarget, id )

    return PLUGIN_HANDLED
}

CheckVotes( target, voter ) {
    new szName[32], szTargetName[32]
    get_user_name( voter, szName, 31 )
    get_user_name( target, szTargetName, 31 )

    MsgToLog( gszLogRecords[VOTE], szTargetName, szName )
    ColorPrint( 0, "^4%s %L", gszPrefix, LANG_SERVER, "VOTEBAN_VOTE", szName, szTargetName )

    new iPlayers[32], iPlayersNum
    get_players( iPlayers, iPlayersNum, "ch" )    // skip bots and HLTV

    if ( get_percent( giVotes[target], iPlayersNum ) < get_pcvar_num( pCvar[CVAR_PERCENT] ) )
        return

    new iUserid = get_user_userid(target)
    new iType = get_pcvar_num( pCvar[CVAR_BANTYPE] )
    new iBanTime = get_pcvar_num( pCvar[CVAR_BANTIME] )
    new szReason[256]
    static szAuthid[32]
    get_pcvar_string( pCvar[CVAR_REASON], szReason, charsmax(szReason) - 1 )

    switch ( iType ) {
        case AMXBAN, AMXBANS5, SUPERBAN : {
            // clear unused template
            replace( szReason, 255, "%time%", " " )
        }
        default : {
            new szBanTime[4]
            num_to_str( iBanTime, szBanTime, 3 )
            // set actual ban time in the reason
            replace( szReason, 255, "%time%", szBanTime )
            static szHostname[64]
            if ( !szHostname[0] )
                get_cvar_string( "hostname", szHostname, 63 )
            get_user_authid( target, szAuthid, charsmax(szAuthid) - 1 )
            log_amx( "Ban: ^"%s<0><><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%d^") (reason ^"Voteban^")", szHostname, szTargetName, iUserid, szAuthid, iBanTime )
            ColorPrint( 0, "^4%s %L", gszPrefix, LANG_SERVER, "VOTEBAN_BAN", szTargetName, iBanTime )
        }
    }

    switch ( iType ) {
        case STEAMID :
            server_cmd( "kick #%d %s;wait;wait;wait;banid %d %s", iUserid, szReason, iBanTime, szAuthid )
        case IP : {
            new szIp[32]
            get_user_ip( target, szIp, charsmax(szIp) - 1, 1 /* without_port */ )
            server_cmd( "kick #%d %s;wait;wait;wait;addip %d %s", iUserid, szReason, iBanTime, szIp )
        }
        case AMXBAN :
            server_cmd( "amx_ban #%d %d ^"%s^"", iUserid, iBanTime, szReason )
        case AMXBANS5 :
            server_cmd( "amx_ban %d #%d ^"%s^"", iBanTime, iUserid, szReason )
        case SUPERBAN :
            server_cmd( "amx_superban #%d %d ^"%s^"", iUserid, iBanTime, szReason )
        default : {     // AUTO
            /* AMXX base plugin 'plmenu.amxx', code by MistaGee
            IF AUTHID STEAM_ID_LAN OR VALVE_ID_LAN OR HLTV, BAN PER IP TO DON'T BAN EVERYONE */
            if ( equal( "STEAM_ID_LAN", szAuthid ) || equal( "VALVE_ID_LAN", szAuthid ) || equal( "HLTV", szAuthid ) ) {
                new szIp[32]
                get_user_ip( target, szIp, charsmax(szIp) - 1, 1 /* without_port */ )
                server_cmd( "kick #%d %s;wait;wait;wait;addip %d %s", iUserid, szReason, iBanTime, szIp )
            }
            else
                server_cmd( "kick #%d %s;wait;wait;wait;banid %d %s", iUserid, szReason, iBanTime, szAuthid )
        }
    }
}

get_percent( value, tvalue ) {
    return floatround( floatmul( float(value) / float(tvalue) , 100.0 ) )
}

MsgToLog( szRawMessage[], any:... ) {
    static szLogFile[192] = "", szTime[32], fp
    if ( !szLogFile[0] ) {
        new szLogsDir[64], szDate[16]
        get_time ( "%Y%m", szDate, charsmax(szDate) )
        get_localinfo( "amxx_logs", szLogsDir, 63 )
        formatex( szLogFile, charsmax(szLogFile), "%s/voteban_%s.log", szLogsDir, szDate )
    }

    new szMessage[192]
    vformat( szMessage, charsmax( szMessage ), szRawMessage, 2 )

    get_time( "%m/%d/%Y - %H:%M:%S", szTime, 31 )
    fp = fopen( szLogFile, "a" )
    fprintf( fp, "L %s: %s^n", szTime, szMessage )
    fclose(fp)
}

ColorPrint( iReceiver, const szRawMessage[ ], any:... ) {
    static iMsgSayText = 0
    if( !iMsgSayText )
        iMsgSayText = get_user_msgid( "SayText" )

    new szMessage[192], iPlayers[32], iPlayersNum = 1, iPlayer
    vformat( szMessage, charsmax(szMessage) - 1, szRawMessage, 3 )
    replace_all( szMessage, charsmax(szMessage) - 1, "!n", "^1" )
    replace_all( szMessage, charsmax(szMessage) - 1, "!t", "^3" )
    replace_all( szMessage, charsmax(szMessage) - 1, "!g", "^4" )
    if ( szMessage[0] != '^1' || szMessage[0] != '^3' || szMessage[0] != '^4' )
        format( szMessage, charsmax(szMessage) - 1, "^1%s", szMessage )    // we must set initial default color if it is not provided explicitly

    if ( iReceiver )
        iPlayers[0] = iReceiver
    else {
        get_players( iPlayers, iPlayersNum, "ch" )    // skip bots and HLTV
        if ( !iPlayersNum )
            return    // don't print useless message
    }

    for ( new i = 0; i < iPlayersNum; i++ ) {
        iPlayer = iPlayers[i]
        if ( !is_user_connected(iPlayer) )
            continue

        message_begin( MSG_ONE_UNRELIABLE, iMsgSayText, _, iPlayer )
        write_byte(iPlayer)    // use target player as sender to see colors at all (and his own team color for ^3)
        write_string(szMessage)
        message_end()
    }
}

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Vote Ban"
#define VERSION "1.0"
#define AUTHOR "Alka"

#define MAX_PLAYERS 33

#define MENU_KEYS (1<<0 | 1<<1 | 1<<2 | 1<<3 | 1<<4 | 1<<5 | 1<<6 | 1<<7 | 1<<8 | 1<<9)
#define MENU_SLOTS 8

new g_iMenuPage[MAX_PLAYERS];
new g_iVotedPlayers[MAX_PLAYERS];
new g_iVotes[MAX_PLAYERS];
new g_szVoteReason[MAX_PLAYERS][64];

new g_iPlayers[MAX_PLAYERS - 1];
new g_iNum;

new g_iMsgidSayText;

enum {
    CVAR_PERCENT = 0,
    CVAR_BANTYPE,
    CVAR_BANTIME
};
new g_szCvarName[][] = {
    "voteban_percent",
    "voteban_type",
    "voteban_time"
};
new g_szCvarValue[][] = {
    "20",
    "2",
    "20"
};
new g_iPcvar[3];
new g_szLogFile[64];

public plugin_init() {
    
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_saycmd("voteban", "Cmd_VoteBan", -1, "");
    register_clcmd("_voteban_reason", "Cmd_VoteBanReason", -1, "");
    
    register_menucmd(register_menuid("\rVOTEBAN \yMenu:"), MENU_KEYS, "Menu_VoteBan");
    
    for(new i = 0; i < 3; i++)
    {
        g_iPcvar[i] = register_cvar(g_szCvarName[i], g_szCvarValue[i]);
    }
    g_iMsgidSayText = get_user_msgid("SayText");
    
    new szLogInfo[] = "amx_logdir";
    get_localinfo(szLogInfo, g_szLogFile, charsmax(g_szLogFile));
    add(g_szLogFile, charsmax(g_szLogFile), "/voteban");
    
    if(!dir_exists(g_szLogFile))
        mkdir(g_szLogFile);
        
    new szTime[32];
    get_time("%d-%m-%Y", szTime, charsmax(szTime));
    format(g_szLogFile, charsmax(g_szLogFile), "%s/%s.log", g_szLogFile, szTime);
}

public client_disconnect(id)
{
    if(g_iVotedPlayers[id])
    {
        get_players(g_iPlayers, g_iNum, "h");
        
        for(new i = 0; i < g_iNum; i++)
        {
            if(g_iVotedPlayers[id] & (1 << g_iPlayers[i]))
            {
                g_iVotes[g_iPlayers[i]]--;
            }
        }
        g_iVotedPlayers[id] = 0;
    }
}

public Cmd_VoteBan(id)
{
    get_players(g_iPlayers, g_iNum, "h");
    
    if(g_iNum < 3)
    {
        client_printc(id, "\g> \dThis command is unavailable! Need at least 3 players.");
        return PLUGIN_HANDLED;
    }
    ShowBanMenu(id, g_iMenuPage[id] = 0);
    return PLUGIN_CONTINUE;
}

public ShowBanMenu(id, iPos)
{
    static i, iPlayer, szName[32];
    static szMenu[256], iCurrPos; iCurrPos = 0;
    static iStart, iEnd; iStart = iPos * MENU_SLOTS;
    static iKeys;
    
    get_players(g_iPlayers, g_iNum, "h");
    
    if(iStart >= g_iNum)
    {
        iStart = iPos = g_iMenuPage[id] = 0;
    }
    
    static iLen;
    iLen = formatex(szMenu, charsmax(szMenu), "\rVOTEBAN \yMenu:^n^n");
    
    iEnd = iStart + MENU_SLOTS;
    iKeys = MENU_KEY_0;
    
    if(iEnd > g_iNum)
    {
        iEnd = g_iNum;
    }
    
    for(i = iStart; i < iEnd; i++)
    {
        iPlayer = g_iPlayers[i];
        get_user_name(iPlayer, szName, charsmax(szName));
        
        iKeys |= (1 << iCurrPos++);
        iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\r%d\w.%s \d(\r%d%%\d)^n", iCurrPos, szName, get_percent(g_iVotes[iPlayer], g_iNum));
    }
    
    if(iEnd != g_iNum)
    {
        formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n\r9\w.Next ^n\r0\w.%s", iPos ? "Back" : "Exit");
        iKeys |= MENU_KEY_9;
    }
    else
    {
        formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n\r0\w.%s", iPos ? "Back" : "Exit");
    }
    show_menu(id, iKeys, szMenu, -1, "");
    return PLUGIN_HANDLED;
}

public Menu_VoteBan(id, key)
{
    switch(key)
    {
        case 8:
        {
            ShowBanMenu(id, ++g_iMenuPage[id]);
        }
        case 9:
        {
            if(!g_iMenuPage[id])
                return PLUGIN_HANDLED;
            
            ShowBanMenu(id, --g_iMenuPage[id]);
        }
        default: {
            static iPlayer;
            iPlayer = g_iPlayers[g_iMenuPage[id] * MENU_SLOTS + key];
            
            if(!is_user_connected(iPlayer))
            {
                ShowBanMenu(id, g_iMenuPage[id]);
                return PLUGIN_HANDLED;
            }
            if(iPlayer == id)
            {
                client_print(id, print_center, "*You cannot voteban yourself!*");
                ShowBanMenu(id, g_iMenuPage[id]);
                
                return PLUGIN_HANDLED;
            }
            if(g_iVotedPlayers[id] & (1 << iPlayer))
            {
                client_print(id, print_center, "*You already votebanned this player!*");
                ShowBanMenu(id, g_iMenuPage[id]);
                
                return PLUGIN_HANDLED;
            }
            g_iVotes[iPlayer]++;
            g_iVotedPlayers[id] |= (1 << iPlayer);
            
            static szName[2][32];
            get_user_name(id, szName[0], charsmax(szName[]));
            get_user_name(iPlayer, szName[1], charsmax(szName[]));
            
            client_printc(0, "\g> \dPlayer \t%s \dvotebanned \t%s\d!", szName[0], szName[1]);
            
            CheckVotes(iPlayer, id);
            client_cmd(id, "messagemode _voteban_reason");
            
            ShowBanMenu(id, g_iMenuPage[id]);
        }
    }
    return PLUGIN_HANDLED;
}

public Cmd_VoteBanReason(id)
{
    if(!g_iVotedPlayers[id])
        return PLUGIN_HANDLED;
    
    new szArgs[64];
    read_argv(1, szArgs, charsmax(szArgs));
    
    if(szArgs[0])
    {
        formatex(g_szVoteReason[id], charsmax(g_szVoteReason[]), szArgs);
    }
    return PLUGIN_HANDLED;
}

public CheckVotes(id, voter)
{
    get_players(g_iPlayers, g_iNum, "h");
    new iPercent = get_percent(g_iVotes[id], g_iNum);
    
    if(iPercent >= get_pcvar_num(g_iPcvar[CVAR_PERCENT]))
    {
        switch(get_pcvar_num(g_iPcvar[CVAR_BANTYPE]))
        {
            case 1:
            {
                new szAuthid[32];
                get_user_authid(id, szAuthid, charsmax(szAuthid));
                server_cmd("kick #%d;wait;wait;wait;banid %d ^"%s^";wait;wait;wait;writeid", get_user_userid(id), get_pcvar_num(g_iPcvar[CVAR_BANTIME]), szAuthid);
            }
            case 2:
            {
                new szIp[32];
                get_user_ip(id, szIp, charsmax(szIp), 1);
                server_cmd("kick #%d;wait;wait;wait;addip %d ^"%s^";wait;wait;wait;writeip", get_user_userid(id), get_pcvar_num(g_iPcvar[CVAR_BANTIME]), szIp);
            }
        }
        g_iVotes[id] = 0;
        
        new szName[2][32];
        get_user_name(id, szName[0], charsmax(szName[]));
        get_user_name(id, szName[1], charsmax(szName[]));
        client_printc(0, "\g> \dPlayer \t%s \dhas been banned for \g%d\dmin. due voteban!", szName[0], get_pcvar_num(g_iPcvar[CVAR_BANTIME]));
        
        log_to_file(g_szLogFile, "Player '%s' voted for banning '%s' for: %s", szName[1], szName[0], g_szVoteReason[voter]);
    }
}

stock get_percent(value, tvalue)
{    
    return floatround(floatmul(float(value) / float(tvalue) , 100.0));
}

stock register_saycmd(saycommand[], function[], flags = -1, info[])
{
    static szTemp[64];
    formatex(szTemp, charsmax(szTemp), "say %s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team %s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say /%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say .%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team /%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team .%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
}

stock client_printc(id, const text[], any:...)
{
    
    new szMsg[191], iPlayers[32], iCount = 1;
    vformat(szMsg, charsmax(szMsg), text, 3);
    
    replace_all(szMsg, charsmax(szMsg), "\g","^x04");
    replace_all(szMsg, charsmax(szMsg), "\d","^x01");
    replace_all(szMsg, charsmax(szMsg), "\t","^x03");
    
    if(id)
        iPlayers[0] = id;
    else
        get_players(iPlayers, iCount, "ch");
    
    for(new i = 0; i < iCount; i++)
    {
        if(!is_user_connected(iPlayers[i]))
            continue;
        
        message_begin(MSG_ONE_UNRELIABLE, g_iMsgidSayText, _, iPlayers[i]);
        write_byte(iPlayers[i]);
        write_string(szMsg);
        message_end();
    }
}