[Metamod] Semiclip 2.2

Цитата(Stimul1 @ 26.10.2014, 17:19)

#include <amxmodx>
#include <fakemeta>
#include <engine>

#define MAX_PLAYERS	32

enum _:_InfoStruct
{	
	bool:alive,
	bool:trans[33],
	teamId
};

new maxplayers;
new playerInfo[MAX_PLAYERS + 1][_InfoStruct];

const m_iTeam = 114;

public plugin_init()
{
	register_forward(FM_PlayerPreThink,"fw_PlayerPreThink",1);
	register_forward(FM_AddToFullPack,"fw_AddToFullPack_Post",1);
	register_forward(FM_PlayerPostThink,"fw_PlayerPostThink_Post");

	maxplayers = get_maxplayers();
}
public fw_PlayerPreThink(id)
{
	if(!(playerInfo[id][alive] = is_user_alive(id)))
		return FMRES_IGNORED;

	playerInfo[id][teamId] = get_pdata_int(id,m_iTeam);

	for(new j = 1; j <= maxplayers; j++)
	{
		if(id == j || !(playerInfo[j][alive] = is_user_alive(j)) || playerInfo[id][teamId] != (playerInfo[j][teamId] = get_pdata_int(j,m_iTeam)))
			continue;

		playerInfo[id][trans][j] = ((entity_range(id,j) < 128) ? true : false);

		set_pev(j,pev_solid,SOLID_NOT);
	}
	return FMRES_IGNORED;
}
public fw_PlayerPostThink_Post(id)
{
	if(!playerInfo[id][alive])
		return FMRES_IGNORED;

	for(new j = 1; j <= maxplayers; j++)
	{
		if(id == j || !playerInfo[j][alive] || playerInfo[id][teamId] != playerInfo[j][teamId])
			continue;

		set_pev(j,pev_solid,SOLID_BBOX);
	}
	return FMRES_IGNORED;
}
public fw_AddToFullPack_Post(es,e,ent,id,flags,player,set)
{
	if(!player || id == ent || !playerInfo[id][alive] || !playerInfo[ent][alive] || playerInfo[id][teamId] != playerInfo[ent][teamId])
		return FMRES_IGNORED;

	if(playerInfo[id][trans][ent])
	{
		set_es(es,ES_RenderAmt,180);
		set_es(es,ES_Solid,SOLID_NOT);
		set_es(es,ES_RenderMode,kRenderTransAlpha);
	}
	return FMRES_IGNORED;
}