Склад маленьких плагинов

#include <amxmodx>
#include <cstrike>
#include <fun>

#define PLUGIN "Weapon Menu Hardcoded"
#define VERSION "0.4"
#define AUTHOR "Safety1st"

enum _:ItemTypes {
    MENUITEM[80],    // the longest possible menu string without escape tokens
    WPN_ID,
    BPAMMO
}

/*------------------ EDIT ME ------------------*/
#define ACCESS_FLAG ADMIN_LEVEL_H   // flag 't' by default
const giAllowedRound = 3            // round when ALL items become available

#define ITEMS_COUNT 4               // EXACTLY as rows quantity below, 9 items MAX
new const ITEMS[ITEMS_COUNT][ItemTypes] = {
    // format: menu item name, weapon id to give (see amxconst.inc for constants), backpack ammo amount
    {   "AK47",   CSW_AK47, 90 },
    {   "M4A1",   CSW_M4A1, 90 },
    {    "AWP",    CSW_AWP, 30 },
    { "Deagle", CSW_DEAGLE, 35 }
}

//#define CHECK_SHIELD              // uncomment this if you have shields on server
/*------ NOTHING TO EDIT BELOW THIS POINT ------*/

new giCounter    // round counter

new giIsUsed    // whether menu was used or not
#define CheckIsUsed(%1)  (giIsUsed &   (1 << (%1 & 31)))
#define SetIsUsed(%1)    (giIsUsed |=  (1 << (%1 & 31)))

#define CSW_SHIELD 2
new const gszWeaponName[][] = {
    "",     // dummy name to match weapon order
    "weapon_p228",
    "weapon_shield",    // just used an unassigned slot;)
    "weapon_scout",
    "weapon_hegrenade",
    "weapon_xm1014",
    "weapon_c4",
    "weapon_mac10",
    "weapon_aug",
    "weapon_smokegrenade",
    "weapon_elite",
    "weapon_fiveseven",
    "weapon_ump45",
    "weapon_sg550",
    "weapon_galil",
    "weapon_famas",
    "weapon_usp",
    "weapon_glock18",
    "weapon_awp",
    "weapon_mp5navy",
    "weapon_m249",
    "weapon_m3",
    "weapon_m4a1",
    "weapon_tmp",
    "weapon_g3sg1",
    "weapon_flashbang",
    "weapon_deagle",
    "weapon_sg552",
    "weapon_ak47",
    "weapon_knife",
    "weapon_p90"
}

const PRIMARY_WEAPONS_BIT_SUM = 1<<CSW_SCOUT|1<<CSW_XM1014|1<<CSW_MAC10|1<<CSW_AUG|1<<CSW_UMP45
    |1<<CSW_SG550|1<<CSW_GALIL|1<<CSW_FAMAS|1<<CSW_AWP|1<<CSW_MP5NAVY|1<<CSW_M249|1<<CSW_M3
    |1<<CSW_M4A1|1<<CSW_TMP|1<<CSW_G3SG1|1<<CSW_SG552|1<<CSW_AK47|1<<CSW_P90

const SECONDARY_WEAPONS_BIT_SUM = 1<<CSW_P228|1<<CSW_ELITE|1<<CSW_FIVESEVEN|1<<CSW_USP|1<<CSW_GLOCK18|1<<CSW_DEAGLE

const KEY_EXIT = 10

public plugin_init() {
    register_plugin( PLUGIN, VERSION, AUTHOR )

    register_clcmd( "admin_weapon", "MenuCommand" )

    register_event( "HLTV", "Event_NewRound", "a", "1=0", "2=0" )
    register_event( "TextMsg", "Event_NewGame", "a", "2=#Game_will_restart_in", "2=#Game_Commencing" )

    register_menucmd( register_menuid( "WeaponMenu" ), MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_7|MEN
U_KEY_8|MENU_KEY_9|MENU_KEY_0, "MenuHandler" )
}

public Event_NewRound() {
    giIsUsed = 0
    giCounter++
}

public Event_NewGame() {
    giCounter = 0
}

public MenuCommand( id, level, cid ) {
    new bool:bIsItemsDisabled = false
    if( !( get_user_flags(id) & ACCESS_FLAG ) || !is_user_alive(id) || CheckIsUsed(id) || giCounter < giAllowedRound )
        bIsItemsDisabled = true

    new szMenu[512]     // it is maximum allowed menu size
    new iKeys
    new iLen = formatex( szMenu, charsmax(szMenu), "\yВыбери оружие:^n^n" )

    for( new i; i < sizeof ITEMS; i++ ) {
        switch( bIsItemsDisabled ) {
            case false : {
                iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\r%d. \w%s^n", i + 1, ITEMS[i][MENUITEM] )
                iKeys |= ( 1 << i )
            }
            case true  : {
                iLen += formatex( szMenu[iLen], charsmax(szMenu) - iLen, "\r%d. \d%s \r[Недоступно]^n", i + 1, ITEMS[i][MENUITEM] )
            }
        }
    }

    formatex( szMenu[iLen], charsmax(szMenu) - iLen, "^n\r0. \wВыход" )
    iKeys |=  MENU_KEY_0
    show_menu( id, iKeys, szMenu, .title = "WeaponMenu" )

    return PLUGIN_HANDLED
}

public MenuHandler( id, key ) {
    if( key == KEY_EXIT - 1 /* keys are numbered starting from 0 */ || !is_user_alive(id) )
        return PLUGIN_HANDLED

    new iWeaponId = ITEMS[key][WPN_ID]

    if( 1<<iWeaponId & SECONDARY_WEAPONS_BIT_SUM )
        DropWeapon( id, SECONDARY_WEAPONS_BIT_SUM )
    else if( 1<<iWeaponId & PRIMARY_WEAPONS_BIT_SUM ) {
#if defined CHECK_SHIELD
        if( cs_get_user_shield(id) )
            engclient_cmd( id, "drop", gszWeaponName[CSW_SHIELD] )
        else
            DropWeapon( id, PRIMARY_WEAPONS_BIT_SUM )
#else
        DropWeapon( id, PRIMARY_WEAPONS_BIT_SUM )
#endif
    }

    give_item( id, gszWeaponName[iWeaponId] )
    cs_set_user_bpammo( id, iWeaponId, ITEMS[key][BPAMMO] )
    SetIsUsed(id)

    return PLUGIN_HANDLED
}

DropWeapon( id, weapons_bitsum ) {
    new iWeapons[32], iWeaponsNum, iWeaponId

    get_user_weapons( id, iWeapons, iWeaponsNum )

    for( new i = 0; i < iWeaponsNum; i++ ) {
        iWeaponId = iWeapons[i]

        if( 1<<iWeaponId & weapons_bitsum )
            engclient_cmd( id, "drop", gszWeaponName[iWeaponId] )
    }
}